UDF > GUI > GuiListView >

_GUICtrlListView_SetItemSelected

Définit si un élément est sélectionné

#include <GuiListView.au3>
_GUICtrlListView_SetItemSelected ( $hWnd, $iIndex [, $bSelected = True [, $bFocused = False]] )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index de l'élément, de base 0, -1 pour définir l'état de tous les éléments sélectionnés
$bSelected [optionnel] Si True, l'élément est sélectionné, sinon non.
$bFocused [optionnel] Si True, l'élément a le focus, sinon non.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Si la ListView utilise le style $LVS_SINGLESEL, le fait de mettre $iIndex à -1 ne sélectionnera pas tous les éléments.

En relation

_GUICtrlListView_GetItemSelected

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Set Item Selected", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Item 1")
    _GUICtrlListView_AddItem($idListview, "Item 2")
    _GUICtrlListView_AddItem($idListview, "Item 3")

    ; Sélectionne l'élément 2
    _GUICtrlListView_SetItemSelected($idListview, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 2 Selected: " & _GUICtrlListView_GetItemSelected($idListview, 1))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example