UDF > GUI > GuiListView >

_GUICtrlListView_GetNextItem

Recherche un élément qui a des propriétés spécifiées

#include <GuiListView.au3>
_GUICtrlListView_GetNextItem ( $hWnd [, $iStart = -1 [, $iSearch = 0 [, $iState = 8]]] )

Paramètres

$hWnd ID/handle du contrôle
$iStart [optionnel] Index de l'élément à partir duquel la recherche commencera, ou -1 pour trouver le premier élément qui correspond aux commutateurs spécifiés.
L'élément spécifié est lui-même exclu de la recherche.
$iSearch [optionnel] Interprétaion de $iStart:
    0 - Recherche un élément d'index supérieur
    1 - Recherche un élément qui est au-dessus de l'élément spécifié
    2 - Recherche un élément qui est en dessous de l'élément spécifié
    3 - Recherche un élément à gauche de l'élément spécifié
    4 - Recherche un élément à droite de l'élément spécifié
$iState [optionnel] État de l'élément à trouver. Peut être une combinaison des valeurs suivantes:
    1 - L'élément est coupé
    2 - L'élément est mis en surbrillance
    4 - L'élément a le focus
    8 - L'élément est sélectionné

Valeur de retour

Succès: Retourne l'index de l'élément suivant, de base 0.
Échec: Retourne -1.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Get Next Item", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Item 1")
    _GUICtrlListView_AddItem($idListview, "Item 2")
    _GUICtrlListView_AddItem($idListview, "Item 3")

    ; Sélectionne l'élément 2
    _GUICtrlListView_SetItemSelected($idListview, 1)

    ; Trouve l'élément sélectionné
    MsgBox($MB_SYSTEMMODAL, "Information", "Selected Item: " & _GUICtrlListView_GetNextItem($idListview))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example