UDF > GUI > GuiListBox >

_GUICtrlListBox_Dir

Ajoute des noms de répertoires et de fichiers

#include <GuiListBox.au3>
_GUICtrlListBox_Dir ( $hWnd, $sFilePath [, $iAttributes = 0 [, $bBrackets = True]] )

Paramètres

$hWnd ID/handle du contrôle
$sFilePath Indique un chemin absolu, un chemin relatif ou un nom de fichier
$iAttributes [optionnel] Spécifie les attributs des fichiers ou des répertoires à ajouter :
    $DDL_READWRITE - Inclut les fichiers en lecture-écriture avec aucun autre attribut
    $DDL_READONLY - Inclut les fichiers en lecture seule
    $DDL_HIDDEN - Inclut les fichiers cachés
    $DDL_SYSTEM - Inclut les fichiers système
    $DDL_DIRECTORY - Inclut les sous-répertoires
    $DDL_ARCHIVE - Inclut les fichiers archivés
    $DDL_DRIVES - Tous les lecteurs mappés sont ajoutés à la liste
    $DDL_EXCLUSIVE - Inclut uniquement les fichiers avec les attributs spécifiés
$bBrackets [optionnel] Inclure/Exclut les crochets quand $DDL_DRIVES est utilisé

Valeur de retour

Succès: Retourne l'index, compté à partir de 0, du dernier nom ajouté.
Échec: Retourne -1.

Remarque

Si l'espace est insuffisant pour stocker les nouvelles chaînes, la valeur retournée est $LB_ERRSPACE.

En relation

_GUICtrlListBox_InitStorage

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListBox

    ; Crée une GUI
    GUICreate("List Box Dir", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlListBox_BeginUpdate($idListBox)
    _GUICtrlListBox_ResetContent($idListBox)
    _GUICtrlListBox_InitStorage($idListBox, 100, 4096)
    _GUICtrlListBox_Dir($idListBox, @WindowsDir & "\win*.exe")
    _GUICtrlListBox_AddFile($idListBox, @WindowsDir & "\notepad.exe")
    _GUICtrlListBox_Dir($idListBox, "", $DDL_DRIVES)
    _GUICtrlListBox_Dir($idListBox, "", $DDL_DRIVES, False)
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example