UDF > GDIPlus > Activation >

_GDIPlus_Startup

Initialise Microsoft Windows GDI+

#include <GDIPlus.au3>
_GDIPlus_Startup ( [$sGDIPDLL = Default [, $bRetDllHandle = False]] )

Paramètres

$sGDIPDLL [optionnel] Le nom du fichier de la DLL à utiliser. Par défaut, la DLL GDI installée.
$bRetDllHandle [optionnel] True si le handle pour ouvrir la DLL GDI doit être retourné. Par défaut, False.

Valeur de retour

Succès: Retourne True ou le handle de la DLL GDI ouvert si $bRetDllHandle = True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarques

Appelez _GDIPlus_Startup() avant de créer tout objet GDI+.
Si les fonctions GDI+ V1.1 sont disponibles, @extended sera défini à une valeur supérieure à 5.
Pour Vista ou Server 2008, $sGDIPDLL doit être défini. Gdiplus.dll peut être trouvé dans @WindowsDir & "\winsxs\*.gdiplus*\gdiplus.dll"

En relation

_GDIPlus_Shutdown

Voir aussi

Consultez GdiplusStartup dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    Local $hGUI, $hBMP, $hBitmap, $hGraphic

    ; Capturez le coin supérieur gauche de l'écran
    $hBMP = _ScreenCapture_Capture("", 0, 0, 400, 300)

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Initialise la bibliothèque GDI+
    _GDIPlus_Startup()

    ; Dessine le bitmap dans la GUI
    $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBMP)
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, 0, 0)

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_ImageDispose($hBitmap)
    _WinAPI_DeleteObject($hBMP)

    ; Arrête la bibliothèque GDI+
    _GDIPlus_Shutdown()

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example