UDF > GDIPlus > Bitmap >

_GDIPlus_BitmapCreateFromHBITMAP

Crée un objet Bitmap à partir du handle d'une interface graphique Windows (GDI) et du handle d'une palette GDI.

#include <GDIPlus.au3>
_GDIPlus_BitmapCreateFromHBITMAP ( $hBitmap [, $hPal = 0] )

Paramètres

$hBitmap Handle du HBITMAP
$hPal [optionnel] Handle du HPALETTE

Valeur de retour

Succès: Retourne le handle de l'objet Bitmap
Échec: Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarque

Lorsque vous en avez terminé avec l'objet bitmap, appelez _GDIPlus_BitmapDispose() pour libérer les ressources

En relation

_GDIPlus_BitmapDispose

Voir aussi

Consultez GdipCreateBitmapFromHBITMAP dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    Local $hGUI, $hBMP, $hBitmap, $hGraphic

    ; Capture le coin supérieur gauche de l'écran
    $hBMP = _ScreenCapture_Capture("", 0, 0, 400, 300)

    ; Crée GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Initialise la bibliothèque GDI+
    _GDIPlus_Startup()

    ; Dessine le bitmap dans la gui
    $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBMP)
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, 0, 0)

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_BitmapDispose($hBitmap)
    _WinAPI_DeleteObject($hBMP)

    ; Arrête la bibliothèque GDI +
    _GDIPlus_Shutdown()

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example