UDF > GDIPlus > GraphicsCoders >


_GDIPlus_ParamAdd

Ajouter une valeur à la liste des paramètres d'un encodeur

#include <GDIPlus.au3>
_GDIPlus_ParamAdd ( ByRef $tParams, $sGUID, $iNbOfValues, $iType, $pValues )

Paramètres

$tParams Structure $tagGDIPENCODERPARAMS retournée par _GDIPlus_ParamInit()
$sGUID Paramètre GUID de l'encoder. Peut être l'un des suivants:
    $GDIP_EPGCHROMINANCETABLE - paramètres de la table de chrominance
    $GDIP_EPGCOLORDEPTH - paramètres de profondeur de couleur
    $GDIP_EPGCOMPRESSION - paramètres de compression
    $GDIP_EPGLUMINANCETABLE - paramètres de la table de luminance
    $GDIP_EPGQUALITY - paramètres de qualité
    $GDIP_EPGRENDERMETHOD - paramètres de la méthode Render
    $GDIP_EPGSAVEFLAG - paramètres d'enregistrement de flag
    $GDIP_EPGSCANMETHOD - paramètres du mode numérisation
    $GDIP_EPGTRANSFORMATION - paramètres de transformation
    $GDIP_EPGVERSION - paramètres de version du logiciel
$iNbOfValues Nombre d'éléments du tableau $pValues
$iType Type de valeur des paramètres de l'encodeur. Peut être l'un des suivants:
    $GDIP_EPTBYTE - Integer 8 bits non signé
    $GDIP_EPTASCII - Chaîne de caractères terminée par Null
    $GDIP_EPTSHORT - Integer 16 bits non signé
    $GDIP_EPTLONG - Integer 32 bits non signé
    $GDIP_EPTRATIONAL - Deux 'longs' (numérateur, dénominateur)
    $GDIP_EPTLONGRANGE - Deux 'longs' (inférieur, supérieur)
    $GDIP_EPTUNDEFINED - Tableau d'octets de n'importe quel type
    $GDIP_EPTRATIONALRANGE - Deux 'longs' (inférieur, supérieur)
$pValues Pointeur sur le tableau de valeurs. Chaque valeur a le type spécifié par le membre de données $iType.

Valeur de retour

Aucune.

En relation

$tagGDIPENCODERPARAMS, _GDIPlus_ParamInit

Exemple

#include <GDIPlus.au3>
#include <ScreenCapture.au3>

Example()

Func Example()
    Local $hImage, $sCLSID, $tData, $tParams

    ; Capture l'écran
    _ScreenCapture_Capture(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Initialise la bibliothèque GDI+
    _GDIPlus_Startup()

    ; Charge l'image
    $hImage = _GDIPlus_ImageLoadFromFile(@MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; Obtient le CLSID de l'encodeur JPEG
    $sCLSID = _GDIPlus_EncodersGetCLSID("JPG")

    ; Met en place des paramètres pour la rotation de 90 degrés
    $tData = DllStructCreate("int Data")
    DllStructSetData($tData, "Data", $GDIP_EVTTRANSFORMROTATE90)
    $tParams = _GDIPlus_ParamInit(1)
    _GDIPlus_ParamAdd($tParams, $GDIP_EPGTRANSFORMATION, 1, $GDIP_EPTLONG, DllStructGetPtr($tData, "Data"))

    ; Enregistre l'image pivotée
    _GDIPlus_ImageSaveToFileEx($hImage, @MyDocumentsDir & "\GDIPlus_Image2.jpg", $sCLSID, DllStructGetPtr($tParams))

    ; Arrête bibliothèque GDI+
    _GDIPlus_Shutdown()

    ShellExecute(@MyDocumentsDir & "\GDIPlus_Image2.jpg")
EndFunc   ;==>Example