Fonction _GDIPlus_LineBrushCreate

Crée un pinceau à dégradé linéaire à partir de deux points frontières et de deux couleurs limites

#include <GDIPlus.au3>
_GDIPlus_LineBrushCreate ( $nX1, $nY1, $nX2, $nY2, $iARGBClr1, $iARGBClr2 [, $iWrapMode = 0] )

Paramètres

Valeur de retour

Remarque

Lorsque vous en avez terminé avec l'objet, appelez _GDIPlus_BrushDispose() pour libérer les ressources de l'objet.

En relation

Voir aussi

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    _GDIPlus_Startup() ; Initialise GDI+
    Local Const $iWidth = 600, $iHeight = 600, $iBgColor = 0x303030 ; $iBGColor est au format RRGGBB

    Local $hGUI = GUICreate("GDI+ example", $iWidth, $iHeight) ; Crée une fenêtre de test
    GUISetBkColor($iBgColor, $hGUI) ; Définit la couleur de fond de la GUI
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet Graphics à partir du handle de la fenêtre
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Définit pour l'objet graphique la qualité de rendu antialiasing
    Local $hBrush = _GDIPlus_LineBrushCreate(0, 0, 280, 500, 0xFFFF0000, 0xFF4020FF, 1) ; Crée un pinceau à dégradé linéaire

    _GDIPlus_GraphicsFillEllipse($hGraphics, 100, 50, 380, 500, $hBrush) ; Dessine l'oeuf

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources GDI+
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example

Succès:	Retourne le handle du nouvel objet LinearGradientBrush.
Échec:	Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

$nX1	Coordonnée X du point de début du dégradé. La ligne frontière démarre en passant par ce point
$nY1	Coordonnée Y du point de début du dégradé. La ligne frontière démarre en passant par ce point
$nX2	Coordonnée X du point de fin du dégradé. La ligne frontière termine en passant par ce point
$nY2	Coordonnée Y du point de fin du dégradé. La ligne frontière termine en passant par ce point
$iARGBClr1	Composantes Alpha, Rouge, Vert et Bleu de la couleur de la ligne de début
$iARGBClr2	Composantes Alpha, Rouge, Vert et Bleu de la couleur de la ligne de fin
$iWrapMode	[optionnel] Indique comment un dégradé est disposé en mosaïque lorsqu'il est plus petit que la zone à remplir: 0 - Dispose le dégradé en mosaïque, sans symétrie 1 - Retourne le dégradé horizontalement, puis le dispose en mosaïque 2 - Retourne le dégradé verticalement, puis le dispose en mosaïque 3 - Retourne le dégradé horizontalement et verticalement, puis le dispose en mosaïque 4 - Le dégradé n'est pas disposé en mosaïque