UDF > GDIPlus > Text >

_GDIPlus_GraphicsDrawString

Dessine une chaîne

#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawString ( $hGraphics, $sString, $nX, $nY [, $sFont = "Arial" [, $fSize = 10 [, $iFormat = 0]]] )

Paramètres

$hGraphics Handle de l'objet Graphics
$sString Chaîne à dessiner
$nX Coordonnée X où la chaîne sera dessinée
$nY Coordonnée Y où la chaîne sera dessinée
$sFont [optionnel] Nom de la police à utiliser pour le dessin
$fSize [optionnel] Taille de police à utiliser pour le dessin
$iFormat [optionnel] Indicateurs de formatage. Un ou plusieurs des éléments suivants:
    0x0001 - Indique que l'ordre de lecture est de droite à gauche
    0x0002 - Indique que les lignes individuelles de texte sont dessinées verticalement sur le dispositif d'affichage
    0x0004 - Indique que des caractères sont autorisés à sortir du rectangle de la chaîne
    0x0020 - Indique que les caractères de contrôle Unicode sont affichées avec un caractère représentatif
    0x0400 - Indique qu'une autre police peut être utilisée pour les caractères qui ne sont pas pris en charge dans la police demandée
    0x0800 - Indique que l'espace à la fin de chaque ligne est inclus dans la mesure de la chaîne
    0x1000 - Indique que le passage du texte à la ligne suivante est désactivé
    0x2000 - Indique que seules des lignes entières sont affichées dans le rectangle de mise en page
    0x4000 - Indique que les caractères sur le cadre du rectangle de mise en page et le texte s'étendant à l'extérieur du rectangle de mise en page sont affichés

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

En relation

_GDIPlus_GraphicsDrawStringEx

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic

    ; Crée GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Dessine une chaîne
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsDrawString($hGraphic, "Hello world", 140, 110)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example