UDF > GDIPlus > Bitmap >


_GDIPlus_BitmapCreateFromHICON32

Crée un objet Bitmap à partir d'une icône 32 bits

#include <GDIPlus.au3>
_GDIPlus_BitmapCreateFromHICON32 ( $hIcon )

Paramètre

$hIcon Handle de l'icône

Valeur de retour

Succès: Retourne le handle du nouvel objet Bitmap.
Échec: Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarque

Lorsque vous en avez terminé avec l'objet Bitmap, appelez _GDIPlus_ImageDispose() pour libérer les ressources.

En relation

_GDIPlus_ImageDispose, _WinAPI_LoadIcon, _WinAPI_LoadImage

Voir aussi

Consultez GdipCreateBitmapFromHICON dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIIcons.au3>
#include <WinAPIShellEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hIcon, $hBitmap

    ; Crée GUI
    $hGUI = GUICreate("GDI+", 168, 168)
    GUISetState()

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Crée un objet graphique à partir d'un handle fenêtre
    _GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)

    $hIcon = _WinAPI_ShellExtractIcon(@SystemDir & '\shell32.dll', 32, 48, 48)

    $hBitmap = _GDIPlus_BitmapCreateFromHICON32($hIcon)

    _GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, 60, 60)

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _WinAPI_DestroyIcon($hIcon)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example