Functions > FileDirDisk >

IniRead

Lit une valeur dans un fichier .ini au format standard.

IniRead ( "filename", "section", "key", "default" )

Paramètres

filename Le nom complet du fichier .ini
section Le nom de la section dans le fichier .ini
key Le nom de la clé dans le fichier .ini
default La valeur de retour par défaut si la clé demandée n'est pas trouvée.

Valeur de retour

Succès: Retourne la valeur de la clé demandée dans une chaîne.
Échec: Retourne la valeur par défaut si la clé demandée n'est pas trouvée.

Remarque

Un fichier .ini standard ressemble à :

[Nom_Section]
Clé=Valeur



Toutes les valeurs retournées sont convertis sous forme de chaîne. Par conséquent, si vous souhaitez qu'un 'integer', par exemple 1000, soit un nombre, utilisez Int() ou Number(), tout comme si vous voulez qu'un hwnd soit un ptr, utilisez Ptr() ou HWnd().

En relation

FileReadLine, IniDelete, IniReadSection, IniReadSectionNames, IniRenameSection, IniWrite, IniWriteSection

Exemple

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

Example()

Func Example()
    ; Crée une constante locale avec le nom complet du fichier qui sera lu/écrit
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)

    ; Ecrit la valeur de 'AutoIt' à la clé "Title" et dans la section "General".
    IniWrite($sFilePath, "General", "Title", "AutoIt")

    ; Lit la valeur correspondante à la clé 'Title' dans la section 'General'.
    Local $sRead = IniRead($sFilePath, "General", "Title", "Default Value")

    ; Affiche la valeur retournée par IniRead.
    MsgBox($MB_SYSTEMMODAL, "", "La valeur correspondante à la clé 'Title' dans la section  'General' est: " & $sRead)

    ; Supprime la clé 'Title'.
    IniDelete($sFilePath, "General", "Title")

    ; Lit le fichier INI pour la valeur de 'Title' dans la section 'General'.
    $sRead = IniRead($sFilePath, "General", "Title", "Default Value")

    ; Affiche la valeur retournée par IniRead. Comme il n'y a pas de clé stocké la valeur sera la 'Valeur par défaut' passée à IniRead.
    MsgBox($MB_SYSTEMMODAL, "", "La valeur correspondante à la clé 'Title' dans la section  'General' est: : " & $sRead)

    ; Supprime le fichier INI.
    FileDelete($sFilePath)
EndFunc   ;==>Example