Functions > VarConv >

HWnd

Convertit une expression en un handle HWND.

HWnd ( expression )

Paramètre

expression L'expression à convertir en un handle HWND.

Valeur de retour

Succès: Si la valeur peut être convertie en un HWND, la représentation HWND sera retournée.
Échec: Si le HWND n'indique pas une fenêtre valide, un HWND égal à 0 (NULL) sera retourné ainsi que @error = 1.

Remarque

Les nombres 'double' ne peuvent pas être convertis en HWND.
Aucune chaîne littérale ne devrait être convertie en HWND parce qu'il n'y a aucune garantie qu'une fenêtre donnée aura le même HWND à chaque fois. Ceci n'est pas interdit, mais c'est une erreur de programmation qui doit être évitée.

En relation

Int, Number, Ptr, String

Exemple

Example()

Func Example()
    ; Exécute le Bloc-notes
    Run("notepad.exe")

    ; Attend 10 secondes pour que la fenêtre du bloc-notes apparaisse.
    Local $hWnd = WinWait("[CLASS:Notepad]", "", 10)

    ; Convertit le handle en une chaîne.
    Local $sHWnd = String($hWnd)

    ; Réduit la fenêtre du Bloc-notes et attend 2 secondes.
    WinSetState(HWnd($sHWnd), "", @SW_MINIMIZE)
    Sleep(2000)

    ; Restaure la fenêtre du Bloc-notes et attend 2 secondes.
    WinSetState(HWnd($sHWnd), "", @SW_RESTORE)
    Sleep(2000)

    ; Ferme la fenêtre du Bloc-notes.
    WinClose(HWnd($sHWnd))
EndFunc   ;==>Example