AutoIt Français

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=..\..\..\WN.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
$wbemFlagReturnImmediately = 0x10
$wbemFlagForwardOnly = 0x20
$colItems = ""
$strComputer = "localhost"
Local $objWMIServices = ObjGet("winmgmts:" & "{impersonationLevel=impersonate}!\\" & $strComputer & "\root\cimv2")
Local $sink = ObjCreate("WbemScripting.SWbemSink")
ObjEvent($sink, "SINK_")

Local $model, $size

$objWMIServices.ExecNotificationQueryAsync($sink, "SELECT * FROM __InstanceOperationEvent WITHIN 5 WHERE TargetInstance ISA 'Win32_DiskDrive'")

local $output

$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\CIMV2")
$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_LogicalDiskToPartition", "WQL", _
        $wbemFlagReturnImmediately + $wbemFlagForwardOnly)

While 1
    Sleep(250)
WEnd

Func SINK_OnObjectReady($objObject, $objAsyncContext)
    If $objObject.TargetInstance.InterfaceType = "USB" Then
        Select
            Case $objObject.Path_.Class() = "__InstanceCreationEvent"
                $model = $objObject.TargetInstance.model
                $size = $objObject.TargetInstance.size
                $id = $objObject.TargetInstance.DeviceId
                $sn = $objObject.TargetInstance.SerialNumber
                ConsoleWrite("Lecteur " & $model & " ajouté : taille = " & $size & ", Lettre(s) : " & _GetDriveLetterFromDisk($id) &" "& $sn &@CRLF)
                MsgBox(0,"","Type HDD : "&$model & @CRLF & "Taille : "& $size / 1024 /1024 &" Mo" & @CRLF & "Lettre(s) lecteur : "&_GetDriveLetterFromDisk($id) &@CRLF&"N° de série : "& $sn)

            Case $objObject.Path_.Class() = "__InstanceDeletionEvent"
                $model = $objObject.TargetInstance.model
                ConsoleWrite("Lecteur " & $model & " supprimé" & @CRLF)
                MsgBox(0,"","Lecteur "&$model&" déconnecté.")
        EndSelect
    EndIf
EndFunc   ;==>SINK_OnObjectReady

Func _GetDriveLetterFromDisk($sName)
    Local $iFlags = 0x10 + 0x20 ;  $wbemFlagReturnImmediately + $wbemFlagForwardOnly
    $sDrive = ""
    $sName = StringReplace($sName, "\", "\\")
    $oq_part = $objWMIService.ExecQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & $sName & """} WHERE AssocClass = Win32_DiskDriveToDiskPartition", "WQL", $iFlags)
    If IsObj($oq_part) Then
        For $obj_part In $oq_part
            $oq_disk = $objWMIService.ExecQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & $obj_part.DeviceID & """} WHERE AssocClass = Win32_LogicalDiskToPartition", "WQL", $iFlags)
            If IsObj($oq_disk) Then
                For $obj_disk In $oq_disk
                    $sDrive &= $obj_disk.Name
                Next
            EndIf
        Next
    EndIf
    Return $sDrive
EndFunc   ;==>_GetDriveLetterFromDisk