AutoIt Français

Code : Tout sélectionner

#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>

; ===============================================================================================================================
; Description ...: Shows how to display a PNG image
; Author ........: Paul Campbell (PaulIA)
; Notes .........:
; ===============================================================================================================================

; ===============================================================================================================================
; Global variables
; ===============================================================================================================================
Global $hGUI, $hImage, $hGraphic

; Create GUI
$hGUI = GUICreate("Show PNG", 240, 240)
GUISetState()

; Load PNG image
_GDIPlus_Startup()
$hImage = _GDIPlus_ImageLoadFromFile("..\Torus.png")

; Draw PNG image
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsDrawImage($hGraphic, $hImage, 0, 0)

; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

; Clean up resources
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_Shutdown()
 

Code : Tout sélectionner

#include <GDIPlus.au3>

$image = "G:\Program Files\AutoIt3\Examples\GUI\Torus.png"   ; chemin perso

$hGUI = GUICreate("GDI+", 200, 200)
$Pic = GUICtrlCreatePic("", 0, 0, 200, 200)
GUISetState()

_SetPic($hGui, GuiCtrlGetHandle($Pic), $image)

Do
Until GUIGetMsg() = -3  ;$GUI_EVENT_CLOSE

;===================================================
Func _SetPic($hWnd, $hPic, $png)
    Local $aBmp, $hbmp, $MainImage, $MainGraphic, $hGraphic
    _GDIPlus_Startup()

; on charge le png
    $hImg = _GDIPlus_ImageLoadFromFile($png)
    $w = _GDIPlus_ImageGetWidth($hImg)
    $h = _GDIPlus_ImageGetHeight($hImg)

; on crée une image
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hWnd)
    $MainImage = _GDIPlus_BitmapCreateFromGraphics(200, 200, $hGraphic)
    $MainGraphic = _GDIPlus_ImageGetGraphicsContext($MainImage)

; on y met ce qu'on veut
   _GDIPlus_GraphicsDrawImageRect($MainGraphic, $hImg, 10, 10, $w, $h)

; on balance l'image dans le controle
    $hbmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($MainImage)
    $aBmp = DllCall("user32.dll", "hwnd", "SendMessage", "hwnd", $hPic, "int", "0x0172", "int", "0", "int", $hbmp)
    If $aBmp[0] <> 0 Then _WinAPI_DeleteObject($aBmp[0])
    _WinAPI_DeleteObject($hbmp)

; et on fait le ménage
    _GDIPlus_ImageDispose($hImg)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_GraphicsDispose($MainImage)
    _GDIPlus_GraphicsDispose($MainGraphic)
    _GDIPlus_Shutdown()
EndFunc