AutoIt Français

Bonjour suite à ce post là http://www.autoitscript.fr/forum/viewto ... 20&t=11643

J'ai modifié mon code comme ceci afin de faire des règles de calcul, or la 2 ieme ligne paladins ne fonctionne pas, quelqu'un pourrait il me dire pourquoi!

Code : Tout sélectionner

;----- Table Example 4 -----
GUICtrlCreateLabel(" Example 4 ", 250, 250, 100, 13)
$Table4 = _GUICtrlTable_Create(200, 80, 62, 18, 31, 6, 0)
_GUICtrlTable_Set_RowHeight($Table4, 1, 35)
_GUICtrlTable_Set_Justify_All($Table4, 1, 1)
_GUICtrlTable_Set_TextFont_All($Table4, 8.5, 800, 0, "Tahoma")
_GUICtrlTable_Set_CellColor_Row($Table4, 1, 0x555555)
_GUICtrlTable_Set_TextColor_All($Table4, 0x555555)
_GUICtrlTable_Set_TextColor_Row($Table4, 1, 0xFFFFFF)
For $row = 3 To 31 Step 2
    _GUICtrlTable_Set_CellColor_Row($Table4, $row, 0xDDDDDD)
Next

_GUICtrlTable_Set_Text_Row($Table4, 1, "Date|Archers|Paladins|Evo.Arc.|Evo.Pal.")
$sections = IniReadSectionNames("test.ini")
For $i = 1 to $sections[0]
  $archers = IniRead("test.ini", $sections[$i], "archers", "")
  $paladins = IniRead("test.ini", $sections[$i], "paladins", "")
  $date = StringRegExpReplace($sections[$i], '(\d\d)(\d\d)', '$1/$2')
  $archers1 = IniRead("test.ini", $sections[$i -1], "archers", "") ; comparaison jour -1
  $paladins1 = IniRead("test.ini", $sections[$i -1], "paladins", ""); comparaison jour -1
 $op = (($archers - $archers1)*100) / $archers1 ; Règle de calcul pour obtenir mon pourcentage
 $op1 = (($paladins - $paladins1)*100) / $paladins1 ; règle de calcul pour obtenir mon pourcentage

_GUICtrlTable_Set_Text_Row($Table4, $i+1, $date&"|"&$archers&"|"&$paladins&"|"&$op&"%"&"|"&$op1)
Next

_GUICtrlTable_Set_Border_Table($Table4, 0x555555)

voici mon fichier test.ini

Code : Tout sélectionner

[2808]
archers=20
paladins=89
[2908]
archers=16
paladins=80
[3008]
archers=150
paladins=231
[3108]
archers=150
paladins=231
[0109]
archers=150
paladins=231
[0309]
archers=150
paladins=231
[0509]
archers=150
paladins=231
[0609]
archers=150
paladins=231
[0809]
archers=150
paladins=231
[1009]
archers=150
paladins=231

comme vous pouvez le voir, à partir de la 3ieme ligne, le calcul s'effectue correctement pour tout le monde.
Pour la 1ere ligne, j'ai 1.#INF ce qui signifie je crois une erreur due à une division par zéro!
Mais pour la 2ième ligne, je ne comprend pas pourquoi le résultat des paladins n'est pas correcte, puisqu'il l'est dans la 3 ième...
Vous remarquerez aussi qu'en ne faisant qu'une simple difference cela marche tres bien...

Code : Tout sélectionner

 $op = ($archers - $archers1)
 $op1 = ($paladins - $paladins1)

Peut être y a t'il une règle specifique aux pourcentages?

Ou est le problème?

Ouala

► Afficher le texte

Génial Mikell

Merci bien

Et maintenant je fonce voir ce que c'est que ce "round" ^^

++

Bonjour

je l'ai fait hier, j'ai oublié de te le poster. Tu trouveras 2 versions, une qui recherche la date du jour précédent (le 2013/08/22 => 2013/08/21) et fait le calcul, l'autre qui va chercher les valeurs dans la section précédente. Je suis parti du fait que tu peux ne pas avoir de stats pour un jour donné.

J'ai modifier a cette fin le nom des sections au lieu de 22/08 => 2013/08/22. Tu as au début du script du code pour mettre à jour le fichier. D'ailleur mon code en créer un automatiquement pour le test avec des dates et des valeurs aléatoires.

Dans les 2 cas j'ai corriger ta règle de calcul pour voir les %.

Tu verra le résultats dans la console en lançant ce code dans scite.

► Afficher le texte

Code : Tout sélectionner

#cs
[2013/08/10]
archers=45
paladins=155
[2013/08/30]
archers=63
paladins=52
[2013/08/07]
archers=151
paladins=29
[2013/08/26]
archers=125
paladins=36
[2013/08/04]
archers=170
paladins=156
[2013/08/17]
archers=63
paladins=106
[2013/08/19]
archers=108
paladins=11
[2013/08/16]
archers=47
paladins=133
[2013/08/14]
archers=71
paladins=86
[2013/08/28]
archers=77
paladins=92
#ce

#include <array.au3>
#include <date.au3>

Local $iniFile = "File.ini"
FileDelete($iniFile)
For $i = 1 To 10

    $date =  "2013/08/" & StringFormat("%02s", Random(1, 31, 1))
    IniWrite($iniFile, $date, "archers", Random(1, 200, 1))
    IniWrite($iniFile, $date, "paladins", Random(1, 200, 1))

Next
;;; Dans ton code pour l'ajout de nouvelle valeurs
IniWrite($iniFile, _NowCalcDate(), "archers", Random(1, 200, 1))
IniWrite($iniFile, _NowCalcDate(), "paladins", Random(1, 200, 1))

$aSections = IniReadSectionNames($iniFile)

For $i = 1 to $aSections[0]
    $date0 = $aSections[$i]
    $archers0 = IniRead($iniFile, $date0, "archers", 0)
    $paladins0 = IniRead($iniFile, $date0, "paladins", 0)

    $date1 = _DateAdd("D", -1, $date0)
    ConsoleWrite($date0 & " => " & $date1 & @LF)

    $archers1 = IniRead($iniFile, $date1, "archers", "")    ; comparaison jour -1
    $paladins1 = IniRead($iniFile, $date1, "paladins", "")  ; comparaison jour -1

    ConsoleWrite("  Archers0: " & $archers0 & " Archers1: " & $archers1 & @LF)
    ConsoleWrite("  Paladins0: " & $paladins0 & " Paladins1: " & $paladins1 & @LF)

    $op0 = 100 * ($archers1 - $archers0) / $archers0    ; Règle de calcul pour obtenir mon pourcentage
    $op1 = 100 * ($paladins1 - $paladins0) / $paladins0 ; Règle de calcul pour obtenir mon pourcentage

    ConsoleWrite("  op0: " & StringFormat("%.2f %", $op0) & @LF)
    ConsoleWrite("  op1: " & StringFormat("%.2f %", $op1) & @LF)
Next

ConsoleWrite("============================================================" & @LF)

_ArraySort($aSections, 0, 1)
For $i = 2 to $aSections[0]
    $date0 = $aSections[$i]
    $archers0 = IniRead($iniFile, $date0, "archers", 0)
    $paladins0 = IniRead($iniFile, $date0, "paladins", 0)

    $date1 = $aSections[$i - 1]
    ConsoleWrite($date0 & " => " & $date1 & @LF)
    $archers1 = IniRead($iniFile, $date1, "archers", "")    ; comparaison Section en cours / section précédentes
    $paladins1 = IniRead($iniFile, $date1, "paladins", "")  ; comparaison Section en cours / section précédentes

    ConsoleWrite("  Archers0: " & $archers0 & " Archers1: " & $archers1 & @LF)
    ConsoleWrite("  Paladins0: " & $paladins0 & " Paladins1: " & $paladins1 & @LF)

    $op0 = 100 * ($archers1 - $archers0) / $archers0    ; Règle de calcul pour obtenir mon pourcentage
    $op1 = 100 * ($paladins1 - $paladins0) / $paladins0 ; Règle de calcul pour obtenir mon pourcentage

    ConsoleWrite("  op0: " & StringFormat("%.2f %", $op0) & @LF)
    ConsoleWrite("  op1: " & StringFormat("%.2f %", $op1) & @LF & @LF)
Next

Merci gary, je vais regarder ton code de plus près, mais à première vue, il a l'air plus compliqué!
Mais plus c'est long , plus c'est bon..........enfin il parait

AutoIt Français

[R] Problemes avec les regles de calculs

[R] Problemes avec les regles de calculs

Re: [..] Problemes avec les regles de calculs

Re: [..] Problemes avec les regles de calculs

Re: [R] Problemes avec les regles de calculs

Re: [R] Problemes avec les regles de calculs

Re: [R] Problemes avec les regles de calculs