[R] Information sur l'Antivirus

[cbourdu57]

Bonjour,

J'aurai besoin d'une petite aide j'ai un script qui me permet de savoir si j'ai un antivirus activé sur l'ordi et son nom

Voici mon code

Code : Tout sélectionner

Local $avname
Global $state

If @OSVersion = "WIN_XP" Then
    $oWMI = ObjGet("winmgmts:\\localhost\root\SecurityCenter")
    $colItems = $oWMI.ExecQuery("Select * from AntiVirusProduct")

    For $objAntiVirusProduct In $colItems
        $state = $objAntiVirusProduct.onAccessScanningEnabled
    Next

    if $state = True Then
        MsgBox(0,"Info","AV activé")
    Else
        MsgBox(0,"Info","AV désactivé")
    EndIf
Else
    $oWMI = ObjGet("winmgmts:\\localhost\root\SecurityCenter2")
    $colItems = $oWMI.ExecQuery("Select * from AntiVirusProduct")
    For $objAntiVirusProduct In $colItems
        $state = $objAntiVirusProduct.productstate
    Next
    Dim $AvStatus = Hex($state)
    If StringMid($AvStatus, 5, 2) = "10" Or StringMid($AvStatus, 5, 2) = "11" Then
        MsgBox(0, "Info", "AV activé")
    ElseIf StringMid($AvStatus, 5, 2) = "00" Or StringMid($AvStatus, 5, 2) = "01" Then
        MsgBox(0, "Info", "AV désactivé")
    EndIf
EndIf

  For $objAntiVirusProduct In $colItems
        $avname = $objAntiVirusProduct.displayName
  Next
If $avname = False Then
  MsgBox(0,"","Pas d'antivirus installé")
Else
  MsgBox(0,"",$avname)
EndIf

 

Le code là fonctionne super bien mais je voudrais savoir également (en sachant qu'il faut que ça marche pour tout OS)
1) comment savoir s'il est a jour ou pas ?
2 ) faire le meme processus pour l'antispyware et le pare feu ... (si possible)

Si ça peut vous aider j'ai le script en vbs mais que pour les versions après Windows XP

Code : Tout sélectionner

Const ForAppending = 2
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objLogFile = objFSO.OpenTextFile("Report.txt", ForAppending, True)
Set oWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\SecurityCenter2")
     For Each obj in oWMI.ExecQuery("Select * from AntiVirusProduct")
     If InStr(2, Hex(obj.productState), "1", 0) = 2 Then enabled = " [Enabled" Else enabled = " [Disabled"
     If InStr(4, Hex(obj.productState), "0", 0) = 4 Then updated = "|Updated] " Else updated = "|Outdated] "
     objLogFile.Write("AntiVirus: " _
         & obj.displayName _
         & Enabled _
         & Updated _
         & vbCrLf )
Next
For Each obj in oWMI.ExecQuery("Select * from AntiSpywareProduct")
     If InStr(2, Hex(obj.productState), "1", 1) = 2 Then enabled = " [Enabled" Else enabled = " [Disabled"
     If InStr(4, Hex(obj.productState), "0", 1) = 4 Then updated = "|Updated] " Else updated = "|Outdated] "
     objLogFile.Write("AntiSpyware: " _
         & obj.displayName _
         & Enabled _
         & Updated _
         & vbCrLf )
Next
For Each obj in oWMI.ExecQuery("Select * from FirewallProduct")
     If InStr(2, Hex(obj.productState), "1", 1) = 2 Then enabled = " [Enabled] " Else enabled = " [Disabled] "
     objLogFile.Write("Firewall: " _
         & obj.displayName _
         & Enabled _
         & vbCrLf )
Next
 

J'ai vraiment besoin d'une aide là... Après multiples recherches je ne trouve pas ...

[mikell]

Tu as le script vbs et l'équivalent en autoit d'une partie, traduire ce qui manque ne devrait poser aucun problème
http://www.scriptinternals.com/new/us/S ... /41010.htm

[jguinch]

Salut
Pour savoir si l'AV est à jour, c'est le même principe : http://neophob.com/2010/03/wmi-query-wi ... tycenter2/
Pour XP :

Code : Tout sélectionner

For $objAntiVirusProduct In $colItems
   $state = $objAntiVirusProduct.onAccessScanningEnabled
   $updatodate = $objAntiVirusProduct.productUptoDate
Next

Pour Vista et +

Code : Tout sélectionner

If StringMid($AvStatus, 7, 2) = "00" Then
    MsgBox(0, "Info", "AV a jour")
ElseIf StringMid($AvStatus, 7, 2) = "10" Then
    MsgBox(16, "Info", "AV pas a jour")
Else
    MsgBox(48, "Info", "Impossible de savoir si l'AV est a jour")
EndIf

Comme dit Mikell, tu devrais pouvoir t'en sortir pour convertir le VBS, le principe est le même (on t'aidera si tu t'en sors pas).
Par contre juste une remarque, la reqûete WMI Select * from FirewallProduct ne sortira rien pour les postes qui utilisent le firewall Windows. De plus je ne suis pas sûr que les classes AntiSpywareProduct et FirewallProduct existent sous XP et inférieur...

[mikell]

FirewallProduct existe sous XP mais pas en dessous, AntiSpyware non (comme l'indique mon lien ^^)

► Afficher le texte

Code : Tout sélectionner

Dim $Obj_WMIService = ObjGet('winmgmts:\\.\root\SecurityCenter')
    Dim $Col_Items = $Obj_WMIService.ExecQuery('Select * from FirewallProduct')
    For $Obj_Item In $Col_Items
        $FWcomp = "Compagnie : " & $Obj_Item.companyName
        $FWname = "Produit : " & $Obj_Item.displayName
        $FWnbr = "Version : " & $Obj_Item.versionNumber
        $FWstat= "Enabled : " & $Obj_Item.Enabled
    Next
$text = "Firewall" & @CRLF & "--------------------------" & @CRLF
$text&= $FWcomp & @CRLF & $FWname & @CRLF & $FWnbr & @CRLF & $FWstat & @CRLF
MsgBox(0,"", $text)

[cbourdu57]

Merci pour toute vos réponses !

Mais il n'est pas possible de différencier le faite qu'il n'y est aucun parefeu et le faite que c'est celui de windows qui est activé ?

Pour le reste je vais voir tout ça je vous tient au courant

[jguinch]

Salut.
Pour le firewall, tu peux faire en 2 étapes :
1) Requête WMI pour détecter un produit de type Firewall
2) Si pas de résultat avec la requête WMI, tu peux tester si le Firewall Windows est activé :
- soit avec la commande netsh (netsh firewall show state)
- soit par la base de registre HKLM\SYSTEM\CurrentControlSet\services\SharedAccess\Parameters\FirewallPolicy\DomainProfile | PublicProfile | StandardProfile

[jguinch]

La valeur productState est récupérée en décimal.
Une fois convertie en hexadécimal avec la fonction Hex, tu obtiens une valeur sur 8 chiffres

266240(dec) = 0x00041000(hex) = 0x41000(hex)
D'après le lien que je t'ai donnée et les différentes infos que j'ai pu trouver, on comprend qu'il faut décomposer la chaîne pour connaître la signification de cette valeur:
Donc on a 4 groupes : 00 04 10 00
- Le premier groupe "00" ne sert à rien ici (à la position 1 sur 2 caractères)
- Le deuxième groupe "04" correspondrait aux valeurs suivantes additionnées : (à la position 3 sur 2 caractères)
typedef enum _WSC_SECURITY_PROVIDER {
WSC_SECURITY_PROVIDER_FIREWALL = 1,
WSC_SECURITY_PROVIDER_AUTOUPDATE_SETTINGS = 2,
WSC_SECURITY_PROVIDER_ANTIVIRUS = 4,
WSC_SECURITY_PROVIDER_ANTISPYWARE = 8,
WSC_SECURITY_PROVIDER_INTERNET_SETTINGS = 16,
WSC_SECURITY_PROVIDER_USER_ACCOUNT_CONTROL = 32,
WSC_SECURITY_PROVIDER_SERVICE = 64,
WSC_SECURITY_PROVIDER_NONE = 0,
}
- Pour le troisième groupe "10" (à la position 5 sur 2 caractères) c'est un peu flou.
D'après ton code, 10 et 11 voudrait dire que l'AV est activé. Pour ma part j'ai essayé de désactiver puis activer mon AV (Kaspersky) et la valeur ne change pas (toujours 0x41000)
- Pour le quatrième groupe "00" (à la position 7 sur 2 caractères), 00 voudrait dire "à jour" et "10" "too old"

Aucune documentation n'est très claire à ce sujet, vu le nombre d'interrogations sur le web.



Pour l'antispyware, on est bien d'accord que ça ne fonctionnera que pour Vista et supérieur ?

► Afficher le texte

Code : Tout sélectionner

$oWMI = ObjGet("winmgmts:\\localhost\root\SecurityCenter2")
$colItems = $oWMI.ExecQuery("Select * from AntiSpywareProduct")

For $objAntiSpywareProduct In $colItems
    $productName = $objAntiSpywareProduct.displayname
    $state = $objAntiSpywareProduct.productstate
    
    MsgBox(0, "", Hex($state) )
    $AsStatus = Hex($state)
    If StringMid($AsStatus, 5, 2) = "10" Or StringMid($AsStatus, 5, 2) = "11" Then
        MsgBox(0, "AntiSpyware", $productName & " est activé")
    ElseIf StringMid($AsStatus, 5, 2) = "00" Or StringMid($AsStatus, 5, 2) = "01" Then
        MsgBox(0, "AntiSpyware", $productName & " est désactivé")
    EndIf

    If StringMid($AsStatus, 7, 2) = "00" Then
        MsgBox(0, "AntiSpyware", $productName & " est à jour")
    ElseIf StringMid($AsStatus, 7, 2) = "10" Then
        MsgBox(16, "AntiSpyware", $productName & " est périmé")
    Else
        MsgBox(48, "AntiSpyware", "Impossible de savoir si " & $productName & " est à jour")
    EndIf
Next
 

[cbourdu57]

Code : Tout sélectionner

   If @OSVersion = "WIN_XP" Then
        $oWMI = ObjGet("winmgmts:\\localhost\root\SecurityCenter")
        $AVcolItems = $oWMI.ExecQuery("Select * from AntiVirusProduct")

        For $objAntiVirusProduct In $AVcolItems
            $AVstate = $objAntiVirusProduct.onAccessScanningEnabled
            $AVname = $objAntiVirusProduct.displayName
            $AVuptodate = $objAntiVirusProduct.productUptoDate
        Next

        if $AVstate = True Then
            $AVactif=" [ Activé"
        Else
            $AVactif=" [ Désactivé"
        EndIf

        if $AVuptodate = True Then
            $AVajour=" | A jour ]"
        Else
            $AVajour=" | Obsolète ]"
        Endif

        Dim $FWcolItems = $oWMI.ExecQuery('Select * from FirewallProduct')
        For $FWObjItem In $FWcolItems
            $FWname = $FWObjItem.displayName
            $FWstate= $FWObjItem.enabled
        Next

        if $FWstate = True Then
            $FWactif=" [ Activé ]"
        Else
            $FWactif=" [ Désactivé ]"
        EndIf



    Else ;antivirus-----------------------
        $oWMI = ObjGet("winmgmts:\\localhost\root\SecurityCenter2")
        $AVcolItems = $oWMI.ExecQuery("Select * from AntiVirusProduct")

        For $objAntiVirusProduct In $AVcolItems
            $AVstate = $objAntiVirusProduct.productState
            $AVname = $objAntiVirusProduct.displayName
        Next


        Dim $AvStatus = Hex($AVstate)
         If StringMid($AvStatus, 5, 2) = "10" Or StringMid($AvStatus, 5, 2) = "11" Then
            $AVactif="[ Activé"
          ElseIf StringMid($AvStatus, 5, 2) = "00" Or StringMid($AvStatus, 5, 2) = "01" Then
            $AVactif="[ Désactivé"
        EndIf

        If StringMid($AvStatus, 7, 2) = "00" Then
            $AVajour=" | A jour ]"
        ElseIf StringMid($AvStatus, 7, 2) = "10" Then
            $AVajour=" | Obsolète ]"
        EndIf
; parefeu-------------------------------------------

        Dim $FWcolItems = $oWMI.ExecQuery('Select * from FirewallProduct')
        For $FWObjItem In $FWcolItems
            $FWname = $FWObjItem.displayName
            $FWstate= $FWObjItem.productstate
        Next

        Dim $FWStatus = Hex($FWstate)
         If StringMid($FWStatus, 5, 2) = "10" Or StringMid($FWStatus, 5, 2) = "11" Then
            $FWactif="[ Activé ]"
          ElseIf StringMid($FWStatus, 5, 2) = "00" Or StringMid($FWStatus, 5, 2) = "01" Then
            $FWactif="[ Désactivé ]"
        EndIf

    EndIf


    If $AVname = False Then
        GUICtrlSetData($Lbl_antivirus,"Pas d'antivirus installé")
    Else
        GUICtrlSetData($Lbl_antivirus,"Antivirus : " &$AVname & $AVactif & $AVajour)
    EndIf

    If $FWname= False Then
        GUICtrlSetData($Lbl_firewall,"Pas de parefeu installé ou celui de Windows")
    Else
        GUICtrlSetData($Lbl_firewall,"Parefeu : " &$FWname & $FWactif)
    Endif

Voilà le code mais j'ai une erreur : Dim $FWStatus = Hex($FWstate) , $FWstate Variable used without being declared ...

[jguinch]

Si la variable $FWstate n'est pas reconnue à cet endroit, c'est qu'elle n'a pas été initialisée.
Où est-elle initialisé ? => dans la boucle For $FWObjItem In $FWcolItems.
Donc c'est que la requête Select * from FirewallProduct n'a renvoyé aucun résultat.

A moins que tu sois sûr que la requête retourne obligatoirement un seul résultat, tu devrais regrouper ces quelques lignes dans la boucle :

► Afficher le texte

Code : Tout sélectionner

$FWcolItems = $oWMI.ExecQuery('Select * from FirewallProduct')
For $FWObjItem In $FWcolItems
  $FWname = $FWObjItem.displayName
  $FWstate= $FWObjItem.productstate

  $FWStatus = Hex($FWstate)
  If StringMid($FWStatus, 5, 2) = "10" Or StringMid($FWStatus, 5, 2) = "11" Then
    $FWactif="[ Activé ]"
  ElseIf StringMid($FWStatus, 5, 2) = "00" Or StringMid($FWStatus, 5, 2) = "01" Then
    $FWactif="[ Désactivé ]"
  EndIf
Next

[cbourdu57]

Avec ton code, maintenant le problème est en dessous :

Code : Tout sélectionner

    
If $FWname=False Then
        GUICtrlSetData($Lbl_firewall,"Pas de parefeu installé ou celui de Windows")
    Else
        GUICtrlSetData($Lbl_firewall,"Parefeu : " &$FWname & $FWactif)
    Endif
 

Error : $FWname variable used without being declared ... toujours la meme erreur mais plus bas ...

[jguinch]

Essaye de comprendre ce qui n'allait pas le coup d'avant, c'est le même problème.

[cbourdu57]

J'ai laissé tombé le firewall, l'antivirus et le spyware fonctionne super bien

Par contre, avec mon code il m'affiche l'antivirus et le spyware qu'il trouve en dernier (a cause du GUICtrlSetData ...), comment faire pour qu'il me les écrive tous(Créer un label pour chacun et écrire leur nom dedans) ?

Code : Tout sélectionner

        For $objAntiVirusProduct In $AVcolItems
            $AVstate = $objAntiVirusProduct.productState
            $AVname = $objAntiVirusProduct.displayName
        Next

    If $AVname = False Then
        GUICtrlSetData($Lbl_antivirus,"Pas d'antivirus installé")
    Else
        GUICtrlSetData($Lbl_antivirus,"Antivirus : " &$AVname)
    EndIf
 

[jguinch]

raaaah ...
Il faut gérer ça dans la boucle qui lit le résultat de la requête, sinon forcément la valeur de $AVname sera la dernière lue.

► Afficher le texte

Code : Tout sélectionner

GUICreate("", 200, 200)

$oWMI = ObjGet("winmgmts:\\localhost\root\SecurityCenter2")
$AVcolItems = $oWMI.ExecQuery("Select * from AntiVirusProduct")

$i = 0
For $objAntiVirusProduct In $AVcolItems
    $AVname = $objAntiVirusProduct.displayName
    GUICtrlCreateLabel($AVname, 10, $i * 20 + 10, 180, 20)
    $i += 1
Next


GUISetState()

While GUIGetMsg() <> -3
WEnd

[cbourdu57]

Super merci