AutoIt Français

Bonjour à tous, je souhaiterais supprimer un mot qui se trouve dans un fichier texte , tout les mots sont à la ligne.

Par exemple :

Code : Tout sélectionner

William
Thomas
Ludovic
Thierry

Le mot à supprimer est stocké dans la variable $selection = Ludovic

Donc après suppression le fichier devrait ressembler à :

Code : Tout sélectionner

William
Thomas
Thierry

Avec StringReplace ou StringRegExpReplace (ca c'est pour mikell)

Lisez votre texte dans une variable, puis faite le remplacement éléments par éléments (n'oubliez pas le retour à la ligne) puis sauvegardez votre résultat.

Ou _ReplaceStringInFile()

*qui en lui même fait ce qui est proposé plus haut ^^*

L'obsédé du regex

Bah ici apparemment un StringReplace est largement suffisant

Code : Tout sélectionner

$newtext = StringReplace(FileRead("fichier.txt"), "Ludovic" & @crlf, "")
$file = FileOpen("fichier.txt", 2)
FileWrite($file, $newtext)
FileClose($file)

Mais si on veut prendre en compte le fait qu'il peut y avoir des blancs invisibles sur la ligne après le nom à virer, alors c'est vrai vaut mieux

Code : Tout sélectionner

$newtext = StringRegExpReplace(FileRead("fichier.txt"), 'Ludovic\s*', "")

ou avec variable

Code : Tout sélectionner

$kasstoy = "Ludovic"
$newtext = StringRegExpReplace(FileRead("fichier.txt"), $kasstoy & '\s*', "")

Bonsoir.
Je veux pas faire mon chiant mais si on veut être juste, pas sûr que le StringReplace soit suffisant...

Si on imagine la liste suivante :

Code : Tout sélectionner

William
Thomas
Jean-Claude
Ludovic
Thierry
Jean

et on veut supprimer Jean...

Avec stringReplace, on aura le résultat suivant :

Code : Tout sélectionner

William
Thomas
-Claude
Ludovic
Thierry

Je propose le code suivant pour ne pas supprimer la moitié de Jean-Claude :

Code : Tout sélectionner

#include <File.au3>

$str2Delete = "Jean"

Local $content
If NOT _FileReadToArray("fichier.txt", $content) Then Exit

$f = FileOpen("fichier.txt", 2)

For $i = 1 To $content[0]
    If NOT StringRegExp($content[$i], "\A(?i)" & $str2Delete & "\Z") Then FileWriteLine($f, $content[$i])
Next
FileClose($f)

Code : Tout sélectionner

SringReplace(@CRLF & $Selection & @CRLF, @CRLF)

Mais pas de chance pour le 1er et dernier élément (quoi que le dernier peut être bon si vous laissez une ligne vide à la fin)

Merci à vous tous, par contre comme la variable contenant le prénom est selectionée avec une liste donc le jean ne sera pas supprimé , sauf si il y à plusieurs noms avec jean dedans je ne sais pas si votre dernière proposition fonctionnera dans ce cas ...

@PandiPanda
Dans l'absolu, _ReplaceStringInFile() fonctionne, mais il obligera l'ouverture puis la fermeture du fichier pour chaque recherche ...

@mikell
Le fait de dire "Mais si on veut prendre en compte le fait qu'il peut y avoir des blancs invisibles sur la ligne après le nom à virer" implique que la demande ne serait pas complète. Tu rajoute un élément qui n'existe probablement pas et qui si il existe, impliquera bien plus de précaution sur les prénoms composés.

Si Wardow confirme une éventuelle possibilité d'erreur dans le fichier et donc que certaines entrées peuvent être composées d'espace avant ou après le prénom, alors il faudra étudier une solution bien plus évoluée.

En attendant, SringReplace($Selection & @CRLF, "") devrait suffire amplement.

@Tlem
Le petit espace laissé et oublié à la fin d'une ligne de texte est qqe chose d'assez fréquent (alors qu'en début de ligne, on peut le voir)
Et StringReplace($Selection & @CRLF, "") ne marche pas si le prénom à virer est en fin de fichier sans @crlf

@jguinchard
OK alors pour le faire sérieux, avec un fichier type

Code : Tout sélectionner

William
Thomas
Jean-Claude
Jean Marc
Thierry
Jean

tu le fais avec ça

Code : Tout sélectionner

$kasstoy = "jean"
msgbox(0,"", StringRegExpReplace(FileRead("fichier.txt"), '(?i)' & $kasstoy & '\s*(?=\r\n|\z)\s*', "") )

Chaque solution pourra être pris à défaut selon les cas proposés.

Si on commence par imaginer des choses, alors pourquoi se limiter à de simples espaces avant, après, des fins de ligne manquantes, trait d'union etc ...
Pourquoi ne pas aller jusqu'au bout :

Code : Tout sélectionner

JeanMarc
Jean Marc
Jean-Marc 
 Jean -Marc
Jean- Marc
Jean_Marc

Bref, je m’arrête là pour cet exemple, mais il est possible de mixer les accents, les caractères accentués étranger etc ...

Soyons clair. Il n'existe pas de solution miracle. Ou alors il faudrait "développer une IA" capable d'interpréter les données et faire le rapprochement entre Bénédicte et Benedicte ... (1)

Bref, il est possible de ce prendre la tête des heures pour rien, mais si la donnée source ou les données de recherche ne sont pas justes, alors il n'est pas possible en l'état de faire une comparaison viable.

Pour répondre à mikell concernant le @CRLF de fin de fichier, certes celui-ci peut être manquant (bien que ce ne soit pas logique), mais dans ce cas il pourrait être judicieux de passer comme le suggère jguinchard et de faire un traitement dans les deux parties sur les espaces (ce qui limitera les risques d'erreurs, sans toutefois les supprimer totalement).

(1) Bien que je doute que Wardow ait besoin de passer par cet extrême, il pourrait être envisagé "une IA light" qui simplifierait les chaines de recherche/données en un modèle sans fioriture.
Genre :

Code : Tout sélectionner

Jean -Marc => jeanmarc
Jérémie => jeremie
Loïc => loic

Pour les espaces, c'est facile. Pour les caractères accentués, il faudra passer par une table de conversion.

En passant par ce type de traitement sur l'entrée et la donnée à comparer, on peut estimer un résultat sûr à 99% mais il existe encore et toujours des possibilités d'erreur.

Waou, la ça commence à se compliquer, vous pouvez me faire un résumé svp ?

Ben ça dépend de la solution désirée ...

60-80% ou 99% ?

le 99% bien sur

Mais je ne sais pas ... faut quand même que j'y arrive, voila mon script entier :

► Afficher le texteScript

Code : Tout sélectionner

#include <File.au3>
#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $gui = GUICreate("MultiCraft", 163, 362, 361, 156)
Global $liste = GUICtrlCreateList("", 8, 32, 145, 175)
GUICtrlSetData(-1, "")
Global $texte1 = GUICtrlCreateLabel("Liste des sauvegardes :", 24, 8, 116, 17)
Global $use = GUICtrlCreateButton("Utiliser cette sauvegarde", 8, 216, 145, 41)
Global $add = GUICtrlCreateButton("Ajouter une sauvegarde", 8, 264, 145, 41)
Global $del = GUICtrlCreateButton("Supprimer cette sauvegarde", 8, 312, 145, 41)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

_ChargerSauvegardes($Liste, @ScriptDir & "\Multicraft\sauvegardes.txt")
If Not FileExists(@ScriptDir & "\Multicraft\Sauvegardes.txt") Then  ; Si il y a eu une erreur (impossible de trouver le fichier ou de le lire)
$dircreate = DirCreate("Multicraft")
    If $dircreate = 0 Then
        MsgBox(0,"Multicraft","Le dossier n'à pas été créé")
    Else
        MsgBox(0,"Multicraft","Le dossier à été créé")
    EndIf
$filecreate = FileOpen(@ScriptDir & "\Multicraft\Sauvegardes.txt",1)
    If $filecreate = -1 Then
        MsgBox(0,"Multicraft","Le fichier n'à pas été créé")
    Else
        MsgBox(0,"Multicraft","Le fichier à été créé")
    EndIf
EndIf

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
    Exit
  Case $use
    $selection = GUICtrlRead ($liste)
    DirRemove("C:\Users\William.PC-de-JMi-et-Pa\AppData\Roaming\.minecraft",1)
    DirCopy(@ScriptDir & "\Multicraft\" & $selection,"C:\Users\William.PC-de-JMi-et-Pa\AppData\Roaming\.minecraft")
  Case $add
    $name = InputBox("Multicraft","Quel nom souhaitez-vous donner à votre sauvegarde")
    $copy = DirCopy("C:\Users\William.PC-de-JMi-et-Pa\AppData\Roaming\.minecraft",@ScriptDir & "\Multicraft\" & $name)
    If $copy = 1 Then
    MsgBox(0,"Multicraft","La sauvegarde c'est correctement effectuée.")
    GUICtrlSetData ($liste,$name & "|")
    $file = FileOpen(@ScriptDir & "\Multicraft\Sauvegardes.txt",1)
    FileWrite($file,$name & @CRLF)
    FileClose($file)
    Else
    MsgBox(0,"MultiCrat","Une erreur est survenue lors de la copie du dossier.")
    EndIf
  Case $del
    $selection = GUICtrlRead ($liste)
    DirRemove(@ScriptDir & "\Multicraft\" & $selection)

    $f = FileOpen (@ScriptDir & "\Multicraft\sauvegardes.txt" , 0 )
    Dim $aRecords
    _FileReadToArray(@ScriptDir & "\Multicraft\sauvegardes.txt",$aRecords)
    For $x = 1 to $aRecords[0]
    $mot = stringmid($aRecords[$x],1)
    If stringcompare($mot,$selection) = 0 Then
    MsgBox (0,"PWET", "PWET trouvé à la ligne : " & $x)
    _FileWriteToLine($f, $x, "", 1)
    EndIf
    Next
    FileClose($f)

 EndSwitch
WEnd

Func _ChargerSauvegardes($iCtrl, $sFile)
    ; lecture du contenu du fichier
    Local $aFile
    _FileReadToArray($sFile, $aFile)
    If @error Then Return SetError(1, 1, False)
    ; --- On commence la mise à jour
    _GUICtrlListBox_BeginUpdate($iCtrl)
    ; On efface le contenu de la liste
    _GUICtrlListBox_ResetContent($iCtrl)
    For $i = 1 To $aFile[0]
        ; si la ligne n'est pas vide, on l'ajoute à la liste
        If $aFile[$i] Then _GUICtrlListBox_AddString($iCtrl, $aFile[$i])
    Next
    ; Fin de la mise à jour
    _GUICtrlListBox_EndUpdate($iCtrl)
    Return SetError(0, 0, True)
EndFunc

Boss je suis d'accord avec ta démo mais en attendant mon dernier regex gère toutes (?) les exceptions que tu as citées
J'ai pas testé les caractères suédois mais en principe ça doit marcher aussi
Bien sûr, un "e" à la place d'un "é" , ça devient une faute d'orthographe et là ça devient ingérable sauf par une IA

Maintenant faut bien arrêter de déconner à un moment donné, "Matias" et "Mathias" sont 2 noms différents ou alors ya une faute de frappe ?

@mikell
Je l'ai testé et 'Jean Marc' ne passe pas le cap.

De plus, si 'Mathias' et 'Matias' sont deux deux écritures différentes ou une faute de frappe alors 'Marc' et ' Marc' et identique (une faute de frappe

)

Wardow a écrit :le 99% bien sur

Ca ne m'aurait pas étonné !!!

Hé bien comme vous choisissez la solution hard, voici le squelette de ce qu'il vous faudra faire :
Prendre la donnée soumise et la mettre dans une variable (facile).
Prendre les données de votre fichier et les mettre dans un tableau (facile).
Dans une boucle, lire ligne après ligne les données du tableau en les comparant à la donnée source (là ça va encore) mais pour chaque donnée, vous devez appliquer un "filtre" qui transformera la donnée originale en une donnée simplifiée qui ne contiendrait pas de caractère autre que des lettres sans accent (là ça ce corse un peut ^^).

Si deux données sont identique (donnée source = donnée tableau) alors on supprime l'information du tableau. Une fois la boucle terminée, il faut encore transformer le tableau en fichier, mais il ne faudra pas oublier de supprimer les lignes vides ... (bon ça, c'est pas le plus compliqué).

Et voilà ...

Tlem a écrit :@mikell
Je l'ai testé et 'Jean Marc' ne passe pas le cap.

Ah, tu as dû prendre le regex ancienne version, avant que je l'édite

Tricheur.

[Mode triche ON]
Marche pas si on teste "Jéremie" et "Jérémie".

[Mode triche OFF]

Rien du tout ! c'est pas tricher que de présenter un regex qui marche

Et pour le "é" , voir mon post précédent

Ouais, ben je ferais quand même pas l'IA light pour Wardow ce soir car je suis trop crevé.

Rohh, t’arrête pas de ré-éditer tes messages ...
Concernant l'accent comme tout autre caractère, cela devrait être considéré comme une faute. Donc peut importe les espaces, les traits d'union et tout ce qui s'ensuit. Soit on choisit une solution partielle, soit on pousse le vice pour essayer d'atteindre les 100%. Même si ta solution est correcte, elle n'est pas parfaite non plus et entre la première solution et la tienne, le pourcentage d'erreur sera probablement minime. Donc le choix appartient à Wardow : 60-80% ou 99% ^^

Dans ce cas-là, on dit au client :

Et on va roupiller pendant qu'il se prend la tête

Edit
Mon regex marche pas non plus pour "Michel" et "Mikaïlovitch"

AutoIt Français

[R] Supprimer un mot déjà connu d'un fichier texte

[R] Supprimer un mot déjà connu d'un fichier texte

Re: [..]Supprimer un mot déjà connu d'un fichier texte

Re: [..]Supprimer un mot déjà connu d'un fichier texte

Re: [..]Supprimer un mot déjà connu d'un fichier texte

Re: [..]Supprimer un mot déjà connu d'un fichier texte

Re: [..]Supprimer un mot déjà connu d'un fichier texte

Re: [..]Supprimer un mot déjà connu d'un fichier texte

Re: [..]Supprimer un mot déjà connu d'un fichier texte

Re: [..]Supprimer un mot déjà connu d'un fichier texte

Re: [..]Supprimer un mot déjà connu d'un fichier texte

Re: [..] Supprimer un mot déjà connu d'un fichier texte

Re: [..] Supprimer un mot déjà connu d'un fichier texte

Re: [..] Supprimer un mot déjà connu d'un fichier texte

Re: [..] Supprimer un mot déjà connu d'un fichier texte

Re: [..] Supprimer un mot déjà connu d'un fichier texte

Re: [..] Supprimer un mot déjà connu d'un fichier texte

Re: [..] Supprimer un mot déjà connu d'un fichier texte

Re: [..] Supprimer un mot déjà connu d'un fichier texte

Re: [..] Supprimer un mot déjà connu d'un fichier texte

Re: [..] Supprimer un mot déjà connu d'un fichier texte