AutoIt Français

C'est bien ce que je me suis dit...

Bref mon affaire est pas simple...

Je vais faire plusieurs essai et je viendrais plus tard pour donner des nouvelles lol

Episode 1 de la prise de tête

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#Include <File.au3>
#include <Array.au3>
Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)

;==================================
Dim $aTableau1
Global $MonFichierCSV = 'monfichier.csv'
_FileReadToArray($MonFichierCSV, $aTableau1) 
Global $array[$aTableau1[0]][18] 

For $i = 1 To $aTableau1[0]
   For $j = 0 to 17
    Local $split = StringSplit($aTableau1[$i], ";") 
    $array[$i-1][$j] = StringReplace($split[$j+1], '"', "") 
  Next
Next
;_ArrayDisplay($array, 'Tableau2') 

$nblignes = UBound($array)-1
$borneinf = $array[1][14]   ; 15
$bornesup = $array[1][15]   ; 23
;msgbox(0,"", $nblignes &@crlf& $borneinf &@crlf& $bornesup)
;================================================

$coeffV = 50
$coordmiddle = ($bornesup + $borneinf)/2   ; 19
$Hcourbe = ($bornesup - $borneinf)*$coeffV    ; 8*50 = 400
$middle = $Hcourbe/2   ; 200
$Wcourbe = 500


$gui = GUICreate("gui", 520, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GuiCtrlCreateLabel("défilement", 10, 430, 50, 18)
$input_pasdefil = GuiCtrlCreateInput("10", 70, 430, 30, 18)
GuiCtrlCreateLabel("pos X du graphique", 120, 430, 100, 18)
$cont_defil = GuiCtrlCreateLabel("", 220, 430, 50, 18)
GUICtrlSetBkColor(-1, 0xffffff)
GUISetState()

$child = GUICreate("courbe", 500, 400, 10, 10, BitOR($WS_POPUP, $WS_BORDER), _ 
            BitOR($WS_EX_MDICHILD, $WS_EX_COMPOSITED), $gui)
GuiCtrlCreateLabel("", 0, 200, 500, 1)
GUICtrlSetBkColor(-1, 0x999999)
$g = GUICtrlCreateGraphic(0, 0, $nblignes, 400)
GUICtrlSetBkColor(-1, 0xffffff)
GUICtrlSetGraphic($g, $GUI_GR_MOVE, 0, $middle)   ; init
GUICtrlSetGraphic($g, $GUI_GR_PENSIZE, 1)
For $i = 1 to $nblignes-1
 GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0xff)
 $vcoord = Number(StringReplace($array[$i][7], ",", "."))
 GUICtrlSetGraphic($g, $GUI_GR_LINE, $i, ($coordmiddle-$vcoord)*$coeffV+$middle ) 
Next
GUISetState()


While 1
If _IsPressed("01") Then
  $info = GUIGetCursorInfo($child)
  If $info[4] = $g Then
   $pas = GuiCtrlRead($input_pasdefil)
   Do
    $m0 = MouseGetPos()
    $p = ControlGetPos($child, "", $g)
    Sleep(10)
    $m = MouseGetPos()
    $newx = $p[0]+(($m[0]-$m0[0])*$pas)
    If $newx <= 0 and $newx >= $Wcourbe-$nblignes Then
      ControlMove($child, "", $g, $newx, 0)
      GuiCtrlSetData($cont_defil, $newx)
    EndIf
   Until not _IsPressed("01") 
  EndIf
EndIf
Wend

Func _Exit()
  Exit
EndFunc

Pour l'épisode 2 faut que j'achète du doliprane ^^

Ah bin là... Je reste sur le c....
Franchement chapeau!!!

"Vous avez aimé l'épisode 1, vous aimerez l'épisode 2" (post-doliprane)
Le seul bémol c'est que ça fait un peu compact avec 16555 entrées, faudrait faire une gui large de 1000 px plutôt que 500
Tu ne devrais avoir aucun problème pour construire ce tu veux là-dessus (si tu as du doliprane)

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#Include <File.au3>
#include <Array.au3>
#include <SliderConstants.au3>
Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)

;==================================
Dim $aTableau1
Global $MonFichierCSV = 'monfichier.csv'
_FileReadToArray($MonFichierCSV, $aTableau1) 
Global $array[$aTableau1[0]][18] 

For $i = 1 To $aTableau1[0]
   For $j = 0 to 17
    Local $split = StringSplit($aTableau1[$i], ";") 
    $array[$i-1][$j] = StringReplace($split[$j+1], '"', "") 
  Next
Next
;_ArrayDisplay($array, 'Tableau2') 
;================================================

Global $gui, $child, $slider, $dot, $bar, $point, $valeur, $coeffV = 50
$nblignes = UBound($array)-1
$borneinf = $array[1][14]   ; 15
$bornesup = $array[1][15]   ; 23
$coordmiddle = ($bornesup + $borneinf)/2   ; 19
$Hcourbe = ($bornesup - $borneinf)*$coeffV    ; 8*50 = 400
$middle = $Hcourbe/2   ; 200
$Wcourbe = 500


$gui = GUICreate("gui", 520, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GuiCtrlCreateLabel("défilement", 10, 430, 50, 18)
$input_pasdefil = GuiCtrlCreateInput("10", 70, 430, 30, 18)
GuiCtrlCreateLabel("pos X du graphique", 120, 430, 100, 18)
$cont_defil = GuiCtrlCreateLabel("0", 220, 430, 50, 18)
GUICtrlSetBkColor(-1, 0xffffff)
$slider = GUICtrlCreateSlider(0, 470, 520, 20, $TBS_NOTICKS+$TBS_TOP+ $TBS_FIXEDLENGTH)
GUICtrlSetLimit(-1, 500, 0)
GUICtrlSendMsg($slider, $TBM_SETTHUMBLENGTH, 16, 0)
GuiCtrlCreateLabel("point n° ", 300, 430, 40, 17)
$point = GuiCtrlCreateInput("0", 340, 430, 40, 17)
GuiCtrlCreateLabel("valeur : ", 390, 430, 40, 17)
$valeur = GuiCtrlCreateInput("", 430, 430, 60, 17)
GUISetState()


$child = GUICreate("courbe", 500, 400, 10, 10, BitOR($WS_POPUP, $WS_BORDER), _ 
            BitOR($WS_EX_MDICHILD, $WS_EX_COMPOSITED), $gui)
GuiCtrlCreateLabel("", 0, 200, 500, 1)
GUICtrlSetBkColor(-1, 0x999999)
$g = GUICtrlCreateGraphic(0, 0, $nblignes, 400)
GUICtrlSetBkColor(-1, 0xffffff)
GUICtrlSetGraphic($g, $GUI_GR_MOVE, 0, $middle)   ; init
GUICtrlSetGraphic($g, $GUI_GR_PENSIZE, 1)
For $i = 1 to $nblignes-1
 GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0xff)
 $vcoord = Number(StringReplace($array[$i][7], ",", "."))
 GUICtrlSetGraphic($g, $GUI_GR_LINE, $i, ($coordmiddle-$vcoord)*$coeffV+$middle )   ; (19-20)*50+200=150
Next
$bar = GuiCtrlCreateLabel("", 0, 0, 1, 400)
GUICtrlSetBkColor(-1, 0x8888ff)
GUICtrlSetState(-1, $GUI_ONTOP)
$dot = GuiCtrlCreateLabel("", -1, $middle, 3, 3)
GUICtrlSetBkColor(-1, 0xff0000)
GUISetState()


While 1
  _ReadZeSlider()
  _CheckZeGrafik()
Wend


;============================================

Func _CheckZeGrafik()
If _IsPressed("01") Then
  $info = GUIGetCursorInfo($child)
  If $info[4] = $g and $info[0]>0 and $info[0]<500 Then
   $pas = GuiCtrlRead($input_pasdefil)
   Do
    $m0 = MouseGetPos()
    $p = ControlGetPos($child, "", $g)
    Sleep(10)
    $m = MouseGetPos()
    $newx = $p[0]+(($m[0]-$m0[0])*$pas)
    If $newx <= 0 and $newx >= $Wcourbe-$nblignes Then
      ControlMove($child, "", $g, $newx, 0)
          GuiCtrlSetData($cont_defil, $newx)
        _SetZeInfos()
    EndIf
    Until not _IsPressed("01") 
   EndIf
EndIf
EndFunc


Func _ReadZeSlider()
If _IsPressed("01") Then
  $info = GUIGetCursorInfo($gui)
  If $info[4] = $slider Then
    Do
       _SetZeInfos()
    Until not _IsPressed("01") 
   EndIf
EndIf
EndFunc


Func _SetZeInfos()
      Local $slider_val, $pos[4], $index, $v_coord
      $slider_val = GuiCtrlRead($slider)
      $pos = ControlGetPos($child, "", $g)
      $index = $slider_val - $pos[0] 
      GuiCtrlSetData($point, $index)
      GuiCtrlSetData($valeur, $array[$index][7])
      GUICtrlSetPos($bar, $slider_val, 0)
      $v_coord = Number(StringReplace($array[$index][7], ",", "."))
      GUICtrlSetPos($dot, $slider_val-1, ($coordmiddle-$v_coord)*$coeffV+$middle-1)
EndFunc


Func _Exit()
  Exit
EndFunc

Le 'pas' (input de gauche) sert à régler l'intensité du défilement, donc si tu défiles à 100 les infos s'arrêteront à 16500, pour aller à 16555 faut finir en mettant le défilement à 1

En un mot: PARFAIT!!!

Je vais ajouter les 2, 3 choses qui reste... Ça ne devrait pas être trop dur MDR, j'ai le stock de Doliprane!

Sujet résolu et encore une fois merci et bravo, c'est là qu'on voit la différence entre les professionnels et moi!!!

Merci!

Glad I could help

NB : finalement agrandir la gui x2 n'est pas une bonne idée, avec un graphique dynamique large de 32000 px il commence à y avoir des bugs d'affichage assez sévères ^^
NB2 : Et non, c'est pas parfait... Il faut introduire des variables de proportions pour le cas où le fichier comporte moins de 500 lignes

Re, J'aurai quelques questions...

1ère: Est-ce qu'il serait possible de dessiner les bornes mini/maxi en fonction de chaque point (surement en utilisant $GUI_GR_PIXEL?)? J'ai essayé mais perdu dans la mise à l'echelle...

2ème (un peu plus compliquée): Est-ce qu'il serait possible d'intégrer au pied de mon graphique:
-A gauche, la date qui correspond à la valeur extreme gauche de mon graphique -> $LabelL,
-A droite, la date qui correspond à la valeur extreme droite de mon graphique -> $LabelR,
Et bien sur en dynamique, vu qu'on peu faire slider le graphique...

Et j'ai un p'tit bug... Si jamais mon fichier à moins de 500 points, lorsque l'on slide tout à droite mon GUI se ferme...

Ci joint mon code, j'ai rajouté des affichage supplementaires... rien de bien dur....

Merci par avance de votre aide.

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#Include <File.au3>
#include <Array.au3>
#include <SliderConstants.au3>
Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)

;==[ Déclaration du fichier ]================================
$Path =  @ScriptDir & "\csv\"
$ThisFile = "MonFichier"
$Ext = ".csv"
Global $MonFichierCSV = $Path & $ThisFile & $Ext

;==[ Déclaration ]===========================================
Dim $aTableau1
_FileReadToArray($MonFichierCSV, $aTableau1)

Global $array[$aTableau1[0]][18]

;==[ Récupération des données du fichier *.csv]==============
For $i = 2 To $aTableau1[0]
   For $j = 0 to 17
    Local $split = StringSplit($aTableau1[$i], ";")
    $array[$i-1][$j] = StringReplace($split[$j+1], '"', "")
  Next
Next
;_ArrayDisplay($array, 'Tableau2')

;==[ Détermination mise en forme ]=======================================================
Global $gui, $child, $slider, $dot, $bar, $IDLogWPC, $valeur, $coeffV = 40, $Reference, $Moyenne, $Jour
$nblignes = UBound($array)-1
$borneinf = $array[1][14]   ; 15
$bornesup = $array[1][15]   ; 23
$coordmiddle = ($bornesup + $borneinf)/2   ; 19
$Hcourbe = ($bornesup - $borneinf)*$coeffV    ; 8*50 = 400
$middle = $Hcourbe/2   ; 200
$Wcourbe = 500

$gui = GUICreate($ThisFile, 520, 600)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

GuiCtrlCreateLabel("Défilement:", 10, 465, 75, 18)
$input_pasdefil = GuiCtrlCreateInput("10", 80, 465, 30, 18)

GuiCtrlCreateLabel("Pos X du graphique:", 120, 465, 130, 18)
$cont_defil = GuiCtrlCreateLabel("0", 250, 465, 50, 18)

GUICtrlSetBkColor(-1, 0xffffff)
$slider = GUICtrlCreateSlider(0, 440, 520, 25, $TBS_NOTICKS + $TBS_TOP + $TBS_FIXEDLENGTH)

GUICtrlSetLimit(-1, 500, 0)
GUICtrlSendMsg($slider, $TBM_SETTHUMBLENGTH, 25, 0)

$LabelL = GuiCtrlCreateLabel("L", 10, 415, 130, 20)  ;==[ Date gauche graphique ]=================
$LabelR = GuiCtrlCreateLabel("R", 400, 415, 130, 20) ;==[ Date droite graphique ]=================

GuiCtrlCreateLabel("Tol. Min", 15, 495, 65, 17)
$borneinf = GuiCtrlCreateInput("0", 10, 515, 60, 20, $WS_DISABLED)

GuiCtrlCreateLabel("Valeur", 88, 495, 65, 17)
$valeur = GuiCtrlCreateInput("", 75, 515, 65, 20, $WS_DISABLED)

GuiCtrlCreateLabel("Tol. Maxi", 145, 495, 65, 17)
$bornesup = GuiCtrlCreateInput("0", 145, 515, 60, 20, $WS_DISABLED)

GuiCtrlCreateLabel("Date", 255, 495, 65, 17)
$Jour = GuiCtrlCreateInput("0", 210, 515, 130, 20, $WS_DISABLED)

GuiCtrlCreateLabel("Réference", 365, 495, 65, 17)
$Reference = GuiCtrlCreateInput("0", 345, 515, 100, 20, $WS_DISABLED)

GuiCtrlCreateLabel("ID logique", 10, 545, 65, 17)
$IDLogWPC = GuiCtrlCreateInput("0", 10, 565, 65, 20, $WS_DISABLED)

GUISetState()

$child = GUICreate("courbe", 500, 400, 10, 10, BitOR($WS_POPUP, $WS_BORDER), BitOR($WS_EX_MDICHILD, $WS_EX_COMPOSITED), $gui)
GuiCtrlCreateLabel("", 0, 200, 500, 1)
GUICtrlSetBkColor(-1, 0x999999)
$g = GUICtrlCreateGraphic(0, 0, $nblignes, 400)
GUICtrlSetBkColor(-1, 0xffffff)
GUICtrlSetGraphic($g, $GUI_GR_MOVE, 0, $middle)   ; init
GUICtrlSetGraphic($g, $GUI_GR_PENSIZE, 1)

For $i = 1 to $nblignes-1
    GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0xff)
    $vcoord = Number(StringReplace($array[$i][7], ",", "."))
    GUICtrlSetGraphic($g, $GUI_GR_LINE, $i, ($coordmiddle-$vcoord)*$coeffV+$middle )   ; (19-20)*50+200=150
Next

$bar = GuiCtrlCreateLabel("", 0, 0, 1, 400)
GUICtrlSetBkColor(-1, 0x8888ff)
GUICtrlSetState(-1, $GUI_ONTOP)
$dot = GuiCtrlCreateLabel("", -1, $middle, 3, 3)
GUICtrlSetBkColor(-1, 0xff0000)
GUISetState()

While 1
    _ReadZeSlider()
    _CheckZeGrafik()
Wend

Func _CheckZeGrafik()
If _IsPressed("01") Then
    $info = GUIGetCursorInfo($child)
        If $info[4] = $g and $info[0]>0 and $info[0]<500 Then
            $pas = GuiCtrlRead($input_pasdefil)
        Do
            $m0 = MouseGetPos()
            $p = ControlGetPos($child, "", $g)
            Sleep(10)
            $m = MouseGetPos()
            $newx = $p[0]+(($m[0]-$m0[0])*$pas)
        If $newx <= 0 and $newx >= $Wcourbe-$nblignes Then
            ControlMove($child, "", $g, $newx, 0)
            GuiCtrlSetData($cont_defil, $newx)
            _SetZeInfos()
        EndIf
        Until not _IsPressed("01")
        EndIf
EndIf
EndFunc

Func _ReadZeSlider()
If _IsPressed("01") Then
    $info = GUIGetCursorInfo($gui)
    If $info[4] = $slider Then
        Do
            _SetZeInfos()
        Until not _IsPressed("01")
    EndIf
EndIf
EndFunc

Func _SetZeInfos()
    Local $slider_val, $pos[4], $index, $v_coord
    $slider_val = GuiCtrlRead($slider)
    $pos = ControlGetPos($child, "", $g)
    $index = $slider_val - $pos[0]
    GuiCtrlSetData($IDLogWPC, $index)
    GuiCtrlSetData($valeur, $array[$index][7])
    GuiCtrlSetData($borneinf, $array[$index][14])
    GuiCtrlSetData($valeur, $array[$index][7])
    GuiCtrlSetData($bornesup, $array[$index][15])
    GuiCtrlSetData($Jour, $array[$index][3])
    GuiCtrlSetData($Reference, $array[$index][2])
    GuiCtrlSetData($IDLogWPC, $array[$index][11])
    GUICtrlSetPos($bar, $slider_val, 0)
    $v_coord = Number(StringReplace($array[$index][7], ",", "."))
    GUICtrlSetPos($dot, $slider_val-1, ($coordmiddle-$v_coord)*$coeffV+$middle-1)
EndFunc

Func _Exit()
    Exit
EndFunc

Hugues a écrit : Si jamais mon fichier à moins de 500 points, lorsque l'on slide tout à droite mon GUI se ferme...

Je sais et je l'ai signalé dans mon post précédent... faut faire une adaptation (pas évidente) mais là je bosse et une journée n'a que 24h ^^

Hugues a écrit :Est-ce qu'il serait possible de dessiner les bornes mini/maxi en fonction de chaque point

Je ne comprends pas la question...

Les dates, tu es arrivé à les faire afficher en dynamique, pour les 2 labels il suffit d'afficher la 1ère et la dernière valeur prises dans l'array

NB : les inputs désactivés c'est moche, vaudrait mieux mettre des labels à fond blanc (ou pas) avec le style $WS_BORDER

LOL, j'ai bien le moche, c'est plutôt beau...

Pour les bornes mini maxi, je m'explique:
-Regarde le trait rouge sur la courbe jointe, elle correspond à la tolérance maxi http://imagesia.com/curve_7zlk

Ah ok
Dans mon code ces bornes de tolérance correspondent en fait aux limites sup et inf du graphique, ça permet d'avoir une échelle cohérente pour que l'affichage de la courbe soit "lisible"
Par exemple pour le fichier csv fourni, en échelle verticale le graphique va de 15 à 23 (bornes < et > constantes dans le fichier) et le "milieu" affiché est à 19, la moyenne (15+23)/2
Un point situé au-delà de ces bornes (à 24 par ex.) sortirait du graphique

Oui j'ai compris dans ton code que tu les utilisais pour avoir une échelle cohérente

.

Car dans le futur, je souhaite faire de cette petite application un "lecteur de courbe universel"... en rajoutant, un bouton parcourir pour ouvrir un fichier *.csv ayant la même structure que celui-ci... mais par contre ayant des tolérances inférieure et supérieure différentes (normal puisque ce ne sont pas les même points de mesures...) donc au final le plus dur et de faire une mise à l'echelle "automatique" en fonction du fichier que l'on voudra ouvrir...

Ci joint, un exemple d'autre fichier...
http://cjoint.com/?CEyvtQpPmDL
http://cjoint.com/?CEyvuQeWIat

Hum oui "mise à l'echelle automatique" on peut, pourvu que les csv aient exactement la même structure
Le bug des fichiers à nombre de lignes < 500 est corrigé, et ya quelques bricoles en plus

En fait pour tout dire je pense avoir l'usage de ce type de script, alors je suis allé un peu plus loin que l'aide habituelle et le script est complet
Le nom des fonctions et des variables permet de comprendre facilement leur rôle
Tu peux tester la souplesse du code en mettant $Wcourbe = 800 ou 1000

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#Include <File.au3>
#include <Array.au3>
#include <SliderConstants.au3>
#include <ListviewConstants.au3>
Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)

;==================================
Global $dossierOuKyaLesCsv = @ScriptDir & "\"
Global $my_file, $array
Global $middle, $coeffV, $Mcourbe, $Wcourbe, $nblignes, $step
Global $gui, $child, $g, $grafic_width, $slider, $dot, $bar, $LVitem
Global $btn_left, $btn_right, $input_pasdefil

_OpenAndLoadAllZeStuff()

While 1
  If WinActive($gui) Then 
      _ReadZeSlider()
      _CheckBtnsGrafik()
  ElseIf WinActive($child) Then 
      _DragZeGrafik()
  EndIf
Wend

;=================================
; FONCTIONS
;=================================

Func _ChouzeFile()
  Local $var = FileOpenDialog("Choisir un csv...", $dossierOuKyaLesCsv, "CSV (*.csv)", 1)
  If @error Then Exit
  Return $var
EndFunc


Func _OpenAndLoadAllZeStuff()
   If WinExists($gui) Then GuiDelete($gui)
   If WinExists($child) Then GuiDelete($child)
   $my_file = _ChouzeFile()   ; 'monfichier3.csv'
   _BuildZeArray()
   _BuildZeGuis()
EndFunc


Func _BuildZeArray()
SplashTextOn ("", "Chargement ...", 250, 55, -1, -1, 49)
Dim $aTableau1
_FileReadToArray($my_file, $aTableau1) 
Dim $array[$aTableau1[0]][18] 
For $i = 1 To $aTableau1[0]
   For $j = 0 to 17
    Local $split = StringSplit($aTableau1[$i], ";") 
    $array[$i-1][$j] = StringReplace($split[$j+1], '"', "") 
  Next
Next
SplashOff()
;_ArrayDisplay($array, 'Tableau2') 
EndFunc


Func _BuildZeGuis()
;;== échelle verticale
Local $aberr_inf = Number(StringReplace($array[1][13], ",", "."))   
Local $aberr_sup = Number(StringReplace($array[1][16], ",", "."))  
Local $Hcourbe = 400
$middle = ($aberr_sup + $aberr_inf)/2   
$coeffV = $Hcourbe/($aberr_sup - $aberr_inf)  
$Mcourbe = $Hcourbe/2   ; 200

;;== échelle horizontale
$Wcourbe = 500
$nblignes = UBound($array)-1
If $nblignes >= $Wcourbe Then
  $step = 1
Else
  For $i = 1 to $Wcourbe
     If $nblignes < $Wcourbe/$i and $nblignes > $Wcourbe/($i+1) Then
        $step = $i+1
        Exitloop
     EndIf
  Next
EndIf
$grafic_width = $nblignes*$step

;;==guis
Local $left = 50

$gui = GUICreate($my_file, $Wcourbe+$left+20, 505)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
Local $a = Number(StringLen(Int($aberr_sup - $aberr_inf))-2)
Local $b = 10^$a
For $i = $aberr_inf to $aberr_sup step $b
  GuiCtrlCreateLabel("", 10, _GetZePosY($i)+4, 40, 17, 2)
  GuiCtrlSetFont(-1, 8, 400, 0, "Arial Unicode MS")
  GuiCtrlSetData(-1, Round($i, 2) & " " & ChrW(9472) )
  GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
Next
GuiCtrlCreateLabel($array[1][3], $left, 420, 110, 17)    ; dates
GuiCtrlCreateLabel($array[$nblignes][3], $Wcourbe-50, 420, 110, 17)
$btn_left = GuiCtrlCreateButton(ChrW(9668), $left+($Wcourbe/2)-27, 415, 25, 20)
$btn_right = GuiCtrlCreateButton(ChrW(9658), $left+($Wcourbe/2)+2, 415, 25, 20)
$btn_open = GuiCtrlCreateButton("...", 10, 440, 25, 20)
GUICtrlSetOnEvent(-1, "_OpenAndLoadAllZeStuff")
$slider = GUICtrlCreateSlider($left-10, 440, $Wcourbe+20, 20, $TBS_NOTICKS+$TBS_TOP+ $TBS_FIXEDLENGTH)
GUICtrlSetLimit(-1, $Wcourbe/$step, 0)
GUICtrlSendMsg($slider, $TBM_SETTHUMBLENGTH, 16, 0)
GuiCtrlCreateLabel("défilement", 10, 472, 50, 15)
$input_pasdefil = GuiCtrlCreateInput("1", 65, 470, 30, 18)

$LV = GuiCtrlCreateListview(" | | | | ", 110, 460, 440, 35, $LVS_NOCOLUMNHEADER, $LVS_EX_GRIDLINES)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 0, 60)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 1, 80)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 2, 120)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 3, 100)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 4, 70)
GuiCtrlCreateListViewItem("Point|Valeur|Date|Reference|ID Logique", $LV)
$LVitem = GuiCtrlCreateListViewItem(" | | | | ", $LV)
GUISetState()


$child = GUICreate("courbe", $Wcourbe, 400, $left, 10, BitOR($WS_POPUP, $WS_BORDER), _ 
            BitOR($WS_EX_MDICHILD, $WS_EX_COMPOSITED), $gui)
GUISetBkColor(0xffffff)
GuiCtrlCreateLabel("", 0, _GetZePosY($array[1][15]), $Wcourbe, 1)  ; tol sup
GUICtrlSetBkColor(-1, 0xff0000)
GuiCtrlCreateLabel("tol. sup : " & $array[1][15], 5, _GetZePosY($array[1][15])-15, 120, 17)  
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GuiCtrlCreateLabel("", 0, _GetZePosY($array[1][14]), $Wcourbe, 1)  ; tol inf
GUICtrlSetBkColor(-1, 0xff0000)
GuiCtrlCreateLabel("tol. inf : " & $array[1][14], 5, _GetZePosY($array[1][14]), 120, 17)  
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GuiCtrlCreateLabel("", 0, 200, $Wcourbe, 1)  ; moyenne
GUICtrlSetBkColor(-1, 0x999999)
;GuiCtrlCreateLabel("moy : " & $middle, 5, 185, 60, 17)  
;GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GuiCtrlCreateLabel("aberr. sup : " & $array[1][16], 5, 0, 120, 17)  
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GuiCtrlCreateLabel("aberr. inf : " & $array[1][13], 5, 385, 120, 17)  
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$g = GUICtrlCreateGraphic(0, 0, $grafic_width, 400)
GUICtrlSetBkColor(-1, 0xffffff)
GUICtrlSetGraphic($g, $GUI_GR_MOVE, 0, $Mcourbe)   ; init
GUICtrlSetGraphic($g, $GUI_GR_PENSIZE, 1)
For $i = 1 to $nblignes-1
 GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0xff)
 GUICtrlSetGraphic($g, $GUI_GR_LINE, $i*$step, _GetZePosY($array[$i][7]) ) 
Next
$bar = GuiCtrlCreateLabel("", 0, 0, 1, 400)
GUICtrlSetBkColor(-1, 0x8888ff)
GUICtrlSetState(-1, $GUI_ONTOP)
$dot = GuiCtrlCreateLabel("", -1, $Mcourbe, 3, 3)
GUICtrlSetBkColor(-1, 0xff0000)
GUISetState()
EndFunc


Func _GetZePosY($array_value)
    Local $temp = Number(StringReplace($array_value, ",", "."))
    Return ($middle-$temp)*$coeffV+$Mcourbe
EndFunc


Func _CheckBtnsGrafik()
If _IsPressed("01") Then
 Local $info = GUIGetCursorInfo($gui)
 If $info[4] = $btn_left Then 
   Do
     _MoveZeGrafik(-1)
   Until not _IsPressed("01")
 ElseIf $info[4] = $btn_right Then 
   Do
    _MoveZeGrafik(1)
  Until not _IsPressed("01")
 EndIf
EndIf
EndFunc


Func _DragZeGrafik()
If _IsPressed("01") Then
  Local $info = GUIGetCursorInfo($child)
  If $info[4] = $g and $info[0]>0 and $info[0]<$Wcourbe Then
   Do
    $m0 = MouseGetPos()
    Sleep(10)
    $m = MouseGetPos()
    _MoveZeGrafik($m[0]-$m0[0])
    Until not _IsPressed("01") 
   EndIf
EndIf
If _IsPressed("25") Then   ; left 
   Do
    _MoveZeGrafik(-1)
    ; Sleep(100)
    Until not _IsPressed("25") 
EndIf
If _IsPressed("27") Then   ; right
   Do
    _MoveZeGrafik(1)
    ; Sleep(100)
    Until not _IsPressed("27") 
EndIf
EndFunc


Func _MoveZeGrafik($val)
   Local $pas, $p, $newx
   $pas = GuiCtrlRead($input_pasdefil)
   $p = ControlGetPos($child, "", $g)
   $newx = $p[0]+($val*$pas*$step)
   If $newx <= 0 and $newx >= $Wcourbe-$grafic_width Then
     ControlMove($child, "", $g, $newx, 0)
     _SetZeInfos()
   EndIf
EndFunc


Func _ReadZeSlider()
If _IsPressed("01") Then
  $info = GUIGetCursorInfo($gui)
  If $info[4] = $slider Then
    Do
      $slider_val0 = GuiCtrlRead($slider)
      Sleep(10)
      $slider_val = GuiCtrlRead($slider)
      If $slider_val<>$slider_val0 Then
         _SetZeInfos()
      EndIf
    Until not _IsPressed("01") 
   EndIf
EndIf
EndFunc


Func _SetZeInfos()
   Local $slider_val, $pos[4], $index
   $slider_val = GuiCtrlRead($slider)
   $pos = ControlGetPos($child, "", $g)
   $index = $slider_val - $pos[0]/$step
   GUICtrlSetPos($bar, $slider_val*$step, 0)
   GUICtrlSetPos($dot, ($slider_val*$step)-1, _GetZePosY($array[$index][7])-1)
   GUICtrlSetData($LVitem, $index &"|"& $array[$index][7] &"|"& _ 
       $array[$index][3] &"|"& $array[$index][2] &"|"& $array[$index][11])
EndFunc


Func _Exit()
  Exit
EndFunc

Bien marrant à faire, finalement... surtout les échelles

Si tu as des questions n'hésite pas

LOL, tu t'es bien "éclaté", c'est de l'excellent travail. On voit vraiment que vous êtes des passionnés et des experts!!!

J'essai de modifier juste une dernière chose, mais je peine... (normal je suis nul...

) j'essai d'afficher en même temps que tu slides la courbe, les tolérances mini maxi, car en fonction de mon fichier on peut avoir plus tolérances differentes (voir photo jointe).

http://cjoint.com/?CEBnGP1knLj

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#Include <File.au3>
#include <Array.au3>
#include <SliderConstants.au3>
#include <ListviewConstants.au3>
Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)

;==================================
Global $dossierOuKyaLesCsv = @ScriptDir & "\csv\"
Global $my_file, $array
Global $middle, $coeffV, $Mcourbe, $Wcourbe, $nblignes, $step
Global $gui, $child, $g, $grafic_width, $slider, $dot, $bar, $LVitem
Global $btn_left, $btn_right, $input_pasdefil

_OpenAndLoadAllZeStuff()

While 1
  If WinActive($gui) Then
      _ReadZeSlider()
      _CheckBtnsGrafik()
  ElseIf WinActive($child) Then
      _DragZeGrafik()
  EndIf
Wend

;=================================
; FONCTIONS
;=================================

Func _ChouzeFile()
  Local $var = FileOpenDialog("Choisir un csv...", $dossierOuKyaLesCsv, "CSV (*.csv)", 1)
  If @error Then Exit
  Return $var
EndFunc


Func _OpenAndLoadAllZeStuff()
   If WinExists($gui) Then GuiDelete($gui)
   If WinExists($child) Then GuiDelete($child)
   $my_file = _ChouzeFile()   ; 'monfichier3.csv'
   _BuildZeArray()
   _BuildZeGuis()
EndFunc


Func _BuildZeArray()
SplashTextOn ("", "Chargement ...", 250, 55, -1, -1, 49)
Dim $aTableau1
_FileReadToArray($my_file, $aTableau1)
Dim $array[$aTableau1[0]][18]
For $i = 2 To $aTableau1[0]
   For $j = 0 to 17
    Local $split = StringSplit($aTableau1[$i], ";")
    $array[$i-1][$j] = StringReplace($split[$j+1], '"', "")
  Next
Next
SplashOff()
;_ArrayDisplay($array, 'Tableau2')
EndFunc


Func _BuildZeGuis()
;==[ Echelle verticale ]=============================================
Local $aberr_inf = Number(StringReplace($array[1][13], ",", "."));13
Local $aberr_sup = Number(StringReplace($array[1][16], ",", "."));16
Local $Hcourbe = 400
$middle = ($aberr_sup + $aberr_inf)/2
$coeffV = $Hcourbe/($aberr_sup - $aberr_inf)
$Mcourbe = $Hcourbe/2   ; 200

;==[ Echelle horizontale ]===========================================
$Wcourbe = 500
$nblignes = UBound($array)-1
If $nblignes >= $Wcourbe Then
  $step = 1
Else
  For $i = 1 to $Wcourbe
     If $nblignes < $Wcourbe/$i and $nblignes > $Wcourbe/($i+1) Then
        $step = $i+1
        Exitloop
     EndIf
  Next
EndIf
$grafic_width = $nblignes*$step

;;==guis
Local $left = 50

$gui = GUICreate($my_file, $Wcourbe+$left+20+150, 580)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
Local $a = Number(StringLen(Int($aberr_sup - $aberr_inf))-2)
Local $b = 10^$a
For $i = $aberr_inf to $aberr_sup step $b
  GuiCtrlCreateLabel("", 10, _GetZePosY($i)+4, 40, 17, 2)
  GuiCtrlSetFont(-1, 8, 400, 0, "Arial Unicode MS")
  GuiCtrlSetData(-1, Round($i, 2) & " " & ChrW(9472) )
  GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
Next
;GuiCtrlCreateLabel($array[1][3], $left, 420, 150, 17)    ; dates
;GuiCtrlCreateLabel($array[$nblignes][3], $Wcourbe-65, 420, 150, 17)
$btn_left = GuiCtrlCreateButton(ChrW(9668), $left+($Wcourbe/2)-27, 415, 25, 20)
$btn_right = GuiCtrlCreateButton(ChrW(9658), $left+($Wcourbe/2)+2, 415, 25, 20)
$btn_open = GuiCtrlCreateButton("...", 10, 440, 25, 20)
GUICtrlSetOnEvent(-1, "_OpenAndLoadAllZeStuff")
$slider = GUICtrlCreateSlider($left-10, 440, $Wcourbe+20, 20, $TBS_NOTICKS+$TBS_TOP+$TBS_FIXEDLENGTH)
GUICtrlSetLimit(-1, $Wcourbe/$step, 0)
GUICtrlSendMsg($slider, $TBM_SETTHUMBLENGTH, 16, 0)
GuiCtrlCreateLabel("Défilement", 10, 472, 70, 15)
$input_pasdefil = GuiCtrlCreateInput("1", 85, 470, 30, 18)

$LV = GuiCtrlCreateListview(" | | | | | ", 5, 500, 640, 60, $LVS_NOCOLUMNHEADER, $LVS_EX_GRIDLINES)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 0, 70)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 1, 120)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 2, 70)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 3, 150)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 4, 130)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 5, 70)
;GuiCtrlCreateListViewItem("Point|Valeur|Date|Reference|ID Logique", $LV)
GuiCtrlCreateListViewItem("Mini|Valeur|Maxi|Date|Reference|ID Logique", $LV)
$LVitem = GuiCtrlCreateListViewItem(" | | | | | ", $LV)
GUISetState()


$child = GUICreate("courbe", $Wcourbe, 400, $left, 10, BitOR($WS_POPUP, $WS_BORDER), _
            BitOR($WS_EX_MDICHILD, $WS_EX_COMPOSITED), $gui)
GUISetBkColor(0xffffff)
GuiCtrlCreateLabel("", 0, _GetZePosY($array[1][15]), $Wcourbe, 1)  ; tol sup
GUICtrlSetBkColor(-1, 0xff0000)
GuiCtrlCreateLabel("Tol. sup : " & $array[1][15], 5, _GetZePosY($array[1][15])-15, 120, 17)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GuiCtrlCreateLabel("", 0, _GetZePosY($array[1][14]), $Wcourbe, 1)  ; tol inf
GUICtrlSetBkColor(-1, 0xff0000)
GuiCtrlCreateLabel("Tol. inf : " & $array[1][14], 5, _GetZePosY($array[1][14]), 120, 17)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GuiCtrlCreateLabel("", 0, 200, $Wcourbe, 1)  ; moyenne
GUICtrlSetBkColor(-1, 0x999999)
;GuiCtrlCreateLabel("moy : " & $middle, 5, 185, 60, 17)
;GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GuiCtrlCreateLabel("Aberr. sup : " & $array[1][16], 5, 0, 120, 17)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GuiCtrlCreateLabel("Aberr. inf : " & $array[1][13], 5, 385, 120, 17)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$g = GUICtrlCreateGraphic(0, 0, $grafic_width, 400)
GUICtrlSetBkColor(-1, 0xffffff)
GUICtrlSetGraphic($g, $GUI_GR_MOVE, 0, $Mcourbe)   ; init
GUICtrlSetGraphic($g, $GUI_GR_PENSIZE, 1)

For $i = 1 to $nblignes-1
 GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0xff)
 GUICtrlSetGraphic($g, $GUI_GR_LINE, $i*$step, _GetZePosY($array[$i][7]) )
Next

$bar = GuiCtrlCreateLabel("", 0, 0, 1, 400)
GUICtrlSetBkColor(-1, 0x8888ff)
GUICtrlSetState(-1, $GUI_ONTOP)
$dot = GuiCtrlCreateLabel("", -1, $Mcourbe, 3, 3)
GUICtrlSetBkColor(-1, 0xff0000)
GUISetState()
EndFunc


Func _GetZePosY($array_value)
    Local $temp = Number(StringReplace($array_value, ",", "."))
    Return ($middle-$temp)*$coeffV+$Mcourbe
EndFunc


Func _CheckBtnsGrafik()
If _IsPressed("01") Then
 Local $info = GUIGetCursorInfo($gui)
 If $info[4] = $btn_left Then
   Do
     _MoveZeGrafik(-1)
   Until not _IsPressed("01")
 ElseIf $info[4] = $btn_right Then
   Do
    _MoveZeGrafik(1)
  Until not _IsPressed("01")
 EndIf
EndIf
EndFunc


Func _DragZeGrafik()
If _IsPressed("01") Then
  Local $info = GUIGetCursorInfo($child)
  If $info[4] = $g and $info[0]>0 and $info[0]<$Wcourbe Then
   Do
    $m0 = MouseGetPos()
    Sleep(10)
    $m = MouseGetPos()
    _MoveZeGrafik($m[0]-$m0[0])
    Until not _IsPressed("01")
   EndIf
EndIf
If _IsPressed("25") Then   ; left
   Do
    _MoveZeGrafik(-1)
    ; Sleep(100)
    Until not _IsPressed("25")
EndIf
If _IsPressed("27") Then   ; right
   Do
    _MoveZeGrafik(1)
    ; Sleep(100)
    Until not _IsPressed("27")
EndIf
EndFunc


Func _MoveZeGrafik($val)
   Local $pas, $p, $newx
   $pas = GuiCtrlRead($input_pasdefil)
   $p = ControlGetPos($child, "", $g)
   $newx = $p[0]+($val*$pas*$step)
   If $newx <= 0 and $newx >= $Wcourbe-$grafic_width Then
     ControlMove($child, "", $g, $newx, 0)
     _SetZeInfos()
   EndIf
EndFunc


Func _ReadZeSlider()
If _IsPressed("01") Then
  $info = GUIGetCursorInfo($gui)
  If $info[4] = $slider Then
    Do
      $slider_val0 = GuiCtrlRead($slider)
      Sleep(10)
      $slider_val = GuiCtrlRead($slider)
      If $slider_val<>$slider_val0 Then
         _SetZeInfos()
      EndIf
    Until not _IsPressed("01")
   EndIf
EndIf
EndFunc


Func _SetZeInfos()
   Local $slider_val, $pos[4], $index
   $slider_val = GuiCtrlRead($slider)
   $pos = ControlGetPos($child, "", $g)
   $index = $slider_val - $pos[0]/$step
   GUICtrlSetPos($bar, $slider_val*$step, 0)
   GUICtrlSetPos($dot, ($slider_val*$step)-1, _GetZePosY($array[$index][7])-1)
   GUICtrlSetData($LVitem, $array[$index][14] &"|"& $array[$index][7] &"|"& $array[$index][15] &"|"& $array[$index][3] &"|"& $array[$index][2] &"|"& $array[$index][11])
EndFunc


Func _Exit()
  Exit
EndFunc

Tiens c'est nouveau ça...

Tu posterais pas le csv ?

LOL oui c'est pas nouveau, c'est un oubli de ma part...

http://cjoint.com/?CEBorfB87kM

Voilà

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#Include <File.au3>
#include <Array.au3>
#include <SliderConstants.au3>
#include <ListviewConstants.au3>
Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)

;==================================
Global $dossierOuKyaLesCsv = @ScriptDir & "\"
Global $my_file, $array
Global $middle, $coeffV, $Mcourbe, $Wcourbe, $nblignes, $step
Global $gui, $child, $g, $grafic_width, $slider, $dot, $bar, $LVitem
Global $btn_left, $btn_right, $input_pasdefil

_OpenAndLoadAllZeStuff()

While 1
  If WinActive($gui) Then 
      _ReadZeSlider()
      _CheckBtnsGrafik()
  ElseIf WinActive($child) Then 
      _DragZeGrafik()
  EndIf
Wend

;=================================
; FONCTIONS
;=================================

Func _ChouzeFile()
  Local $var = FileOpenDialog("Choisir un csv...", $dossierOuKyaLesCsv, "CSV (*.csv)", 1)
  If @error Then Exit
  Return $var
EndFunc


Func _OpenAndLoadAllZeStuff()
   If WinExists($gui) Then GuiDelete($gui)
   If WinExists($child) Then GuiDelete($child)
   $my_file = _ChouzeFile()   ; 'monfichier3.csv'
   _BuildZeArray()
   _BuildZeGuis()
EndFunc


Func _BuildZeArray()
SplashTextOn ("", "Chargement ...", 250, 55, -1, -1, 49)
Dim $aTableau1
_FileReadToArray($my_file, $aTableau1) 
Dim $array[$aTableau1[0]][18] 
For $i = 1 To $aTableau1[0]
   For $j = 0 to 17
    Local $split = StringSplit($aTableau1[$i], ";") 
    $array[$i-1][$j] = StringReplace($split[$j+1], '"', "") 
  Next
Next
SplashOff()
;_ArrayDisplay($array, 'Tableau2') 
EndFunc


Func _BuildZeGuis()
;;== échelle verticale
Local $aberr_inf = Number(StringReplace($array[1][13], ",", "."))   
Local $aberr_sup = Number(StringReplace($array[1][16], ",", "."))  
Local $Hcourbe = 400
$middle = ($aberr_sup + $aberr_inf)/2   
$coeffV = $Hcourbe/($aberr_sup - $aberr_inf)  
$Mcourbe = $Hcourbe/2   ; 200

;;== échelle horizontale
$Wcourbe = 600
$nblignes = UBound($array)-1
If $nblignes >= $Wcourbe Then
  $step = 1
Else
  For $i = 1 to $Wcourbe
     If $nblignes < $Wcourbe/$i and $nblignes > $Wcourbe/($i+1) Then
        $step = $i+1
        Exitloop
     EndIf
  Next
EndIf
$grafic_width = $nblignes*$step

;;==guis
Local $left = 50

$gui = GUICreate($my_file, $Wcourbe+$left+20, 505)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
Local $a = Number(StringLen(Int($aberr_sup - $aberr_inf))-2)
Local $b = 10^$a
For $i = $aberr_inf to $aberr_sup step $b
  GuiCtrlCreateLabel("", 0, _GetZePosY($i)+4, $left, 17, 2)
  GuiCtrlSetFont(-1, 8, 400, 0, "Arial Unicode MS")
  GuiCtrlSetData(-1, Round($i, 2) & " " & ChrW(9472) )
  GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
Next
GuiCtrlCreateLabel($array[1][3], $left, 420, 110, 17)    ; dates
GuiCtrlCreateLabel($array[$nblignes][3], $Wcourbe-50, 420, 110, 17)
$btn_left = GuiCtrlCreateButton(ChrW(9668), $left+($Wcourbe/2)-27, 415, 25, 20)
$btn_right = GuiCtrlCreateButton(ChrW(9658), $left+($Wcourbe/2)+2, 415, 25, 20)
$btn_open = GuiCtrlCreateButton("...", 10, 440, 25, 20)
GUICtrlSetOnEvent(-1, "_OpenAndLoadAllZeStuff")
$slider = GUICtrlCreateSlider($left-10, 440, $Wcourbe+20, 20, $TBS_NOTICKS+$TBS_TOP+ $TBS_FIXEDLENGTH)
GUICtrlSetLimit(-1, $Wcourbe/$step, 0)
GUICtrlSendMsg($slider, $TBM_SETTHUMBLENGTH, 16, 0)
GuiCtrlCreateLabel("défilement", 10, 472, 50, 15)
$input_pasdefil = GuiCtrlCreateInput("1", 65, 470, 30, 18)

$LV = GuiCtrlCreateListview(" | | | | | ", $Wcourbe+$left-540, 460, 540, 35, $LVS_NOCOLUMNHEADER, $LVS_EX_GRIDLINES)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 0, 80)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 1, 80)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 2, 80)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 3, 120)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 4, 100)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 5, 70)
;GuiCtrlCreateListViewItem("Point|Valeur|Date|Reference|ID Logique", $LV)
GuiCtrlCreateListViewItem("Tol. mini|Valeur|Tol. maxi|Date|Reference|ID Logique", $LV)
$LVitem = GuiCtrlCreateListViewItem(" | | | | | ", $LV)
GUISetState()


$child = GUICreate("courbe", $Wcourbe, 400, $left, 10, BitOR($WS_POPUP, $WS_BORDER), _ 
            BitOR($WS_EX_MDICHILD, $WS_EX_COMPOSITED), $gui)
GUISetBkColor(0xffffff)
GuiCtrlCreateLabel("tol. sup", 5, _GetZePosY($array[1][15])-15, 60, 17)  
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GuiCtrlCreateLabel("tol. inf", 5, _GetZePosY($array[1][14]), 60, 17)  
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
;GuiCtrlCreateLabel("", 0, 200, $Wcourbe, 1)  ; moyenne
;GUICtrlSetBkColor(-1, 0x999999)
GuiCtrlCreateLabel("aberr. sup : " & $array[1][16], 5, 0, 120, 17)  
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GuiCtrlCreateLabel("aberr. inf : " & $array[1][13], 5, 385, 120, 17)  
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$g = GUICtrlCreateGraphic(0, 0, $grafic_width, 400)
GUICtrlSetBkColor(-1, 0xffffff)
GUICtrlSetGraphic($g, $GUI_GR_MOVE, 0, $Mcourbe)   ; init
GUICtrlSetGraphic($g, $GUI_GR_PENSIZE, 1)
For $i = 1 to $nblignes-1
 GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0xff)
 GUICtrlSetGraphic($g, $GUI_GR_LINE, $i*$step, _GetZePosY($array[$i][7]) ) 
Next

GUICtrlSetGraphic($g, $GUI_GR_HINT, 2)
GUICtrlSetGraphic($g, $GUI_GR_MOVE, 0, _GetZePosY($array[1][15]))   ; init
GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0xff0000)
For $i = 1 to $nblignes-1
  If ($array[$i][15])<>($array[$i-1][15]) Then _ 
    GUICtrlSetGraphic($g, $GUI_GR_LINE, $i-1, _GetZePosY($array[$i][15]) )  
  GUICtrlSetGraphic($g, $GUI_GR_LINE, $i, _GetZePosY($array[$i][15]) )   ; tol sup
Next
GUICtrlSetGraphic($g, $GUI_GR_MOVE, 0, _GetZePosY($array[1][14]))   ; init
For $i = 1 to $nblignes-1
  If ($array[$i][14])<>($array[$i-1][14]) Then _ 
    GUICtrlSetGraphic($g, $GUI_GR_LINE, $i-1, _GetZePosY($array[$i][14]) )  
  GUICtrlSetGraphic($g, $GUI_GR_LINE, $i, _GetZePosY($array[$i][14]) )   ; tol inf
Next
GUICtrlSetGraphic($g, $GUI_GR_MOVE, 0, (_GetZePosY($array[1][14])+_GetZePosY($array[1][15]))/2 )   ; init
GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0x999999)
For $i = 1 to $nblignes-1
  If ($array[$i][14])<>($array[$i-1][14]) Then _ 
    GUICtrlSetGraphic($g, $GUI_GR_LINE, $i-1, (_GetZePosY($array[$i][14])+_GetZePosY($array[$i][15]))/2 )  
  GUICtrlSetGraphic($g, $GUI_GR_LINE, $i, (_GetZePosY($array[$i][14])+_GetZePosY($array[$i][15]))/2 )   ; moy
Next

$bar = GuiCtrlCreateLabel("", 0, 0, 1, 400)
GUICtrlSetBkColor(-1, 0x8888ff)
GUICtrlSetState(-1, $GUI_ONTOP)
$dot = GuiCtrlCreateLabel("", -1, $Mcourbe, 3, 3)
GUICtrlSetBkColor(-1, 0xff0000)
GUISetState()
EndFunc


Func _GetZePosY($array_value)
    Local $temp = Number(StringReplace($array_value, ",", "."))
    Return ($middle-$temp)*$coeffV+$Mcourbe
EndFunc


Func _CheckBtnsGrafik()
If _IsPressed("01") Then
 Local $info = GUIGetCursorInfo($gui)
 If $info[4] = $btn_left Then 
   Do
     _MoveZeGrafik(-1)
   Until not _IsPressed("01")
 ElseIf $info[4] = $btn_right Then 
   Do
    _MoveZeGrafik(1)
  Until not _IsPressed("01")
 EndIf
EndIf
EndFunc


Func _DragZeGrafik()
If _IsPressed("01") Then
  Local $info = GUIGetCursorInfo($child)
  If $info[4] = $g and $info[0]>0 and $info[0]<$Wcourbe Then
   Do
    $m0 = MouseGetPos()
    Sleep(10)
    $m = MouseGetPos()
    _MoveZeGrafik($m[0]-$m0[0])
    Until not _IsPressed("01") 
   EndIf
EndIf
If _IsPressed("25") Then   ; left 
   Do
    _MoveZeGrafik(-1)
    ; Sleep(100)
    Until not _IsPressed("25") 
EndIf
If _IsPressed("27") Then   ; right
   Do
    _MoveZeGrafik(1)
    ; Sleep(100)
    Until not _IsPressed("27") 
EndIf
EndFunc


Func _MoveZeGrafik($val)
   Local $pas, $p, $newx
   $pas = GuiCtrlRead($input_pasdefil)
   $p = ControlGetPos($child, "", $g)
   $newx = $p[0]+($val*$pas*$step)
   If $newx <= 0 and $newx >= $Wcourbe-$grafic_width Then
       ControlMove($child, "", $g, $newx, 0)
       _SetZeInfos()
   EndIf
EndFunc


Func _ReadZeSlider()
If _IsPressed("01") Then
  $info = GUIGetCursorInfo($gui)
  If $info[4] = $slider Then
    Do
      $slider_val0 = GuiCtrlRead($slider)
      Sleep(10)
      $slider_val = GuiCtrlRead($slider)
      If $slider_val<>$slider_val0 Then
        _SetZeInfos()
      EndIf
    Until not _IsPressed("01") 
   EndIf
EndIf
EndFunc


Func _SetZeInfos()
Sleep(10)
   Local $slider_val, $pos[4], $index
   $slider_val = GuiCtrlRead($slider)
   $pos = ControlGetPos($child, "", $g)
   $index = $slider_val - $pos[0]/$step
   GUICtrlSetPos($bar, $slider_val*$step, 0)
   GUICtrlSetPos($dot, ($slider_val*$step)-1, _GetZePosY($array[$index][7])-1)
   GUICtrlSetData($LVitem, $array[$index][14] &"|"& $array[$index][7] &"|"& _ 
    $array[$index][15] &"|"& $array[$index][3] &"|"& $array[$index][2] &"|"& $array[$index][11])
EndFunc


Func _Exit()
  Exit
EndFunc

Mais un changement d'échelle dynamique visuel, ça c'est pas possible puisque c'est l'affichage d'une courbe et pas un affichage de point
Idem pour les valeurs farfelues qui donnent des artefacts sur la courbe même si l'affichage des valeurs est correct

Ca me convient parfaitement!!!

Maintenant, il me plus qu'à vraiment analyser ce code pour approfondir mes piètres connaissances...

Sujet Résolu!

Encre un grand Merci à toi, OH maître de l'AutoIt!

AutoIt Français

[R] Courbe dynamique

Re: [..] Courbe dynamique

Re: [..] Courbe dynamique

Re: [..] Courbe dynamique

Re: [..] Courbe dynamique

Re: [..] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique

Re: [R] Courbe dynamique