[R] Proxy Téléchargement

[Chrono47]

Bonjour à tous.

Je suis actuellement entrain de réfléchir à un moyen de me faire gagner du temps dans mes dépannages informatiques.

En effet, je repars des PC qui sont infectés de Virus etc, si bien que je dois réinstaller souvent le Windows qui est en vrac afin de rendre un système propre à mon client.
A chaque PC que je réinstaller, il me manque des pilotes, que je télécharge sur le site officiel du constructeur afin de les installer.

Afin de m'éviter de télécharger les pilotes à chaque PC, je stock sur mon serveur par modèle l'ensemble des pilotes d'une machine que je classe par modèle (afin de m'éviter de re-télécharger l'ensemble des pilotes si une machine avec le même modèle rentre 15 jours plus tard.)

La problématique qui m'amène aujourd'hui, est que j'ai tout de même des doublons de pilotes, en effet, les pilotes d'un Acer Aspire 5300 sont pour la plupart les mêmes que le Acer Aspire 5200 mais je me dois de re-télécharger l'ensemble des pilotes afin de m'assurer qu'ils soient bons tout de même.

L'idée alors, serait la mise en place d'un " downloadeur " intelligent, en effet, le lien FTP du pilote chez Acer est le mêmes (ils ne vont pas s'amuser à copier/coller des pilotes sur leur serveur, ils orientent simplement le modèle sur le bon fichier) et j'aimerai mettre en place quelque chose qui soit capable de me dire si j'ai déjà télécharger ce fichier ou pas, et si oui, qu'il me le retélécharge instantanément grâce à un cache/proxy.

Exemple concret :

Jean télécharge les pilotes pour un Acer Aspire 5300 le 15/01/2015 en passant par le downloadeur, le downloadeur ne trouvant pas les pilotes dans sa base de données, les télécharge.

Trois jours plus tard, Baptiste télécharge les pilotes pour un Acer Aspire 5200 en passant toujours par le downloadeur, le logiciel le préviens alors que les pilotes Son/Lan & Wifi sont identiques à ceux télécharger trois jours plus tôt par Jean pour le Acer Aspire 5300, et les télécharge donc de façon instantané grâce au cache/ proxy => gain de temps pour Baptiste qui ne doit pas attendre que les pilotes Son/Lan & Wifi qu'à déjà télécharger Jean ne se re télécharge.


Bref, voilà ma problématique, si quelqu'un à une idée

Merci,

Chrono

[TommyDDR]

Vous pouvez faire un système de clé/valeur où la clé serait l'URL de téléchargement, si la clé n'existe pas, on télécharge le fichier et on ajoute l'URL en clé et le chemin vers le fichier téléchargé en valeur, si la clé existe, on récupère le fichier grace à la valeur associée à la clé.

[Chrono47]

Je peux abusé en demandant un bout pré-mâché de script ?

[TommyDDR]

Vous avez de la chance d'avoir posté dans "Demande de création de script" ^^

Cadeau :

► Afficher le textecode

Code : Tout sélectionner

Enum $C_KEY, $C_VALUE, $C_MAX

Global Const $cacheDir = "C:\cache\" ; A remplacer par un dossier accessible depuis n'importe quelle machine de votre réseau
Global Const $cacheFile = $cacheDir & "cache.ini"
Global $cache[0][$C_MAX]
DirCreate($cacheDir)
_Cache_LoadFromFile($cacheFile)

Global $oldUrl = ""

While(True)
    Local $url = InputBox("URL", "Indiquer le fichier à télécharger et exécuter", $oldUrl)
    If(@error) Then ExitLoop
    $oldUrl = $url
    If(StringLen($url) > 0) Then
        _Cache_Run($url)
    EndIf
WEnd

Func _Cache_Run($url)
    Local $indice = _Cache_FindKey($url)
    If($indice < 0 Or Not(FileExists($cache[$indice][$C_VALUE]))) Then
        $indice = _Cache_AddUrl($url)
    Else
        ConsoleWrite("GetFromCache" & @CRLF)
    EndIf
    If($indice >= 0) Then
        Local $fileName = $cache[$indice][$C_VALUE]
        ConsoleWrite($fileName & @CRLF)
        ShellExecute($fileName)
    Else
        MsgBox(0, "Erreur", "Le fichier n'a pas pu être télécharger.")
    EndIf
EndFunc

Func _Cache_AddUrl($url)
    Local $retour = -1
    _Cache_Delete($url)
    Local $fileName = $cacheDir & _URLToFileName($url)
    ConsoleWrite("Download : " & $url & @CRLF)
    If(InetGet($url, $fileName, 1+8) > 0) Then
        $retour = _Cache_AddKeyValue($url, $fileName)
        IniWrite($cacheFile, $retour, "key", $url)
        IniWrite($cacheFile, $retour, "value", $fileName)
    EndIf
    Return $retour
EndFunc

Func _Cache_FindKey($key)
    Local $retour = -1
    For $i = 0 To UBound($cache, 1) -1
        If($cache[$i][$C_KEY] = $key) Then
            $retour = $i
            ExitLoop
        EndIf
    Next
    Return $retour
EndFunc

Func _Cache_Delete($key)
    Local $indice = _Cache_FindKey($key)
    If($indice >= 0) Then
        For $i = $indice To UBound($cache, 1)-2
            $cache[$i][$C_KEY] = $cache[$i+1][$C_KEY]
            $cache[$i][$C_KEY] = $cache[$i+1][$C_VALUE]
        Next
        ReDim $cache[UBound($cache, 1)-1][UBound($cache, 2)]
    EndIf
EndFunc

Func _Cache_AddKeyValue($key, $value)
    Local $indice = UBound($cache, 1)
    ReDim $cache[$indice+1][UBound($cache, 2)]
    $cache[$indice][$C_KEY] = $key
    $cache[$indice][$C_VALUE] = $value
    Return $indice
EndFunc

Func _Cache_LoadFromFile($cacheFile)
    Local $sections = IniReadSectionNames($cacheFile)
    If(IsArray($sections)) Then
        Local $key
        Local $value
        For $i = 1 To $sections[0]
            $key = IniRead($cacheFile, $sections[$i], "key", "")
            $value = IniRead($cacheFile, $sections[$i], "value", "")
            If(StringLen($key) > 0 And StringLen($value) > 0) Then
                _Cache_AddKeyValue($key, $value)
            EndIf
        Next
    EndIf
EndFunc

Func _URLToFileName($url)
    Local $retour = StringReplace($url, "\", "_")
    $retour = StringReplace($retour, "/", "_")
    $retour = StringReplace($retour, ":", "_")
    $retour = StringReplace($retour, "*", "_")
    $retour = StringReplace($retour, "?", "_")
    $retour = StringReplace($retour, """", "_")
    $retour = StringReplace($retour, "<", "_")
    $retour = StringReplace($retour, ">", "_")
    $retour = StringReplace($retour, "|", "_")
    Return $retour
EndFunc

Lancez le programme et coller les URL une par une dans la InputBox puis validez. Le programme téléchargera le fichier s'il n'existe pas déjà et l'exécutera.

Pensez à paramètrer le dossier $cacheDir pour pointer sur un dossier accessible (en lecture + écriture) de n'importe où.

[Chrono47]

Voui, pour le coup j'ai été malin

ça m'avance pas mal votre code, mais j'y comprends franchement pas grand chose

Je ne souhaite pas que le lien que je télécharge s’exécute à la fin, je préférai à la place une barre de progression du téléchargement ^^"

C'possible ?

Merci en tout cas pour votre aide

[TommyDDR]

Pour supprimer l'exécution -> enlevez le ShellExecute
Pour la barre de progression... Pas possible avec InetGet.

[orax]

Pour la barre de progression... Pas possible avec InetGet.

Même avec $INET_DOWNLOADBACKGROUND ?

► Afficher le texte

Code : Tout sélectionner

#include <InetConstants.au3>
#include <MsgBoxConstants.au3>

Local $sFilePath = @TempDir & "\tmp.tmp"
Local $hDownload = InetGet("http://ftp.freebsd.org/pub/FreeBSD/ISO-IMAGES-amd64/10.0/FreeBSD-10.0-RELEASE-amd64-dvd1.iso", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)

Do
    Sleep(250)
    $aData = InetGetInfo($hDownload)
    $s = "Bytes read: " & $aData[$INET_DOWNLOADREAD] & @CRLF & _ ; Or use 0 instead of the constant.
            "Size: " & $aData[$INET_DOWNLOADSIZE] & @CRLF & _ ; Or use 1 instead of the constant.
            "Complete: " & $aData[$INET_DOWNLOADCOMPLETE] & @CRLF & _ ; Or use 2 instead of the constant.
            "successful: " & $aData[$INET_DOWNLOADSUCCESS] & @CRLF & _ ; Or use 3 instead of the constant.
            "@error: " & $aData[$INET_DOWNLOADERROR] & @CRLF & _ ; Or use 4 instead of the constant.
            "@extended: " & $aData[$INET_DOWNLOADEXTENDED] & @CRLF ; Or use 5 instead of the constant.
    ConsoleWrite($s & @CRLF)

Until $aData[$INET_DOWNLOADCOMPLETE]

InetClose($hDownload)
FileDelete($sFilePath)

[TommyDDR]

J'avais complètement oublié le mode background... désolé.