[R] Récupérer Index Item d'un menu

Hugues · #1

Bonjour,

J'aimerai savoir comment récupérer le text d'un Item d'un menu?

Je crée un menu à partir d'un fichier *.ini (une partie, les autres sont en dur dans mon script ^^), mais vu que le crée je ne peux plus (ou vois pas comment) utiliser la fonction Func WM_COMMAND()

Voici mon code:

► Afficher le texte

et la partie WM_COMMAND

► Afficher le texte

Merci par avance.

#2

À la ligne

Code : Tout sélectionner

_GUICtrlMenu_InsertMenuItem($hLineChoice, $j - 1 , "&" & $ReadSection[$j][1], "$e_id" & $ReadSection[$j][0], $ReadSection[$j-1][0])

le 4ème paramètre "$e_id" & $ReadSection[$j][0] n'est pas un nombre, c'est une chaîne. Il faudrait utiliser eval() pour obtenir la valeur de $e_id... (si c'est bien une variable), mais eval reste déconseillé.

► Afficher le texteexemple

#3

Si le nombre de clés tirées du ini peut varier, tu peux aussi essayer de stocker les itemID dans une array

► Afficher le texte

Hugues · #4

Bonjour, merci à vous 2

J'ai presque reussi, j'arrive bien à récupérer mes indes, maintenant c'est avec la partie WM_COMMAND que j'ai un soussaille...

Je voudrais que une fois l'index récupéré, je fasse une boucle qui me récupére la cléf correspondant à l'index contenu dans mon fichier ini pour lancer ma fonction.

Ci joint mon code fonctionnel avec le fichier ini.

Code:

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=favicon.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
;==[ Création ]========:   xx/xx/20xx
;==[ Auteur ]==========:    xxxxxxxxxxxxxxxxxxxxxxx
;==[ Service ]=========:    xxxxxxxxxxxxxxxxxxxxxxx
;==[ Description ]=====:    ************************************
;==[ Modification ]====:    Dernière modification le xx/xx/20xx
;==[ Nature modification ]====:
    ;==[xx/xx/20xx: ***********************************]========

;==[Include]====
#include <GuiStatusBar.au3>
#include <Timers.au3>
#include <Date.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <Color.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <File.au3>
#include <ArrayEx.au3>
#include <Array.au3>
#include <WinAPI.au3>
#include <WinNet.au3>
#include <ComboConstants.au3>
#include <GuiComboBox.au3>
#include <GuiComboBoxEx.au3>
#include <ColorConstantS.au3>
#include <String.au3>
Opt("GUIOnEventMode", 1)

;==[Variables globales & autres]====
Global $ApplicationName = "__________", $Version = "V_._._", $CreationDate = "xx/xx/20xx", $NumberOfModification = "", $LastModification = "", $Area
Global $hStatus, $aParts[4] = [200, 450, 480, 200], $aGuiPos, $iMemo
Global $hGUI, $hFile, $hLineChoice, $hHelp
Global Enum $e_idNew = 1000, $e_idAbout, $e_idExit, $e_idHowTo

$LineFile =  @ScriptDir & "\ini\MenuAuto.ini"
$IniFilePath = @ScriptDir & "\ini\cells.ini"
$IniMesurePoint = @ScriptDir & "\ini\MesurePoint.ini"

;==[Programme]====
_Main()

AdlibRegister("_ScreenAdaptation")
GUIRegisterMsg($WM_SIZE, "WM_SIZE")
GUIRegisterMsg($WM_TIMER, "WM_TIMER")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUIRegisterMsg($WM_DRAWITEM, "_WM_DRAWITEM")
$iTimer = _Timer_SetTimer($hGUI, 1000)

While GUIGetMsg() <> -3
WEnd

Func _Main()

    Global  $iColorResult = 0x000FF0
    $Couleur1 = 0x999999
    $Couleur2 = 0xe5e5e5

    $hGUI = GUICreate($ApplicationName & " - Powered By __________. Version: " & $Version, @DesktopWidth - 100, @DesktopHeight - 100, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Quitter", $hGUI)

    $hFile = _GUICtrlMenu_CreateMenu()
    $New= GUICtrlCreateMenuItem("Nouveau" & @TAB & "Ctrl+N", $hFile)
    _GUICtrlMenu_AddMenuItem($hFile, "Fermer l'application", $e_idExit)

    ;=========================================================================================================================================
    ;=========================================================================================================================================
    ;==[DEBUT MENU CHOIX LIGNE AVEC ITEM VARIABLE]============================================================================================
    ;=========================================================================================================================================
    ;=========================================================================================================================================

    $hLineChoice = _GUICtrlMenu_CreateMenu()
    Global $ReadSection = IniReadSection($LineFile, "LineName")
    Global $IDMenu[$ReadSection[0][0]]

    For $j = 1 To $ReadSection[0][0]
        _GUICtrlMenu_InsertMenuItem($hLineChoice, $j - 1 , "&" & $ReadSection[$j][1], 1000 + ($j - 1))
        $IDMenu[$j-1] = 1000 + ($j - 1)
        ;consolewrite($IDMenu[$j-1] & @CRLF)
    Next

    ;=========================================================================================================================================
    ;=========================================================================================================================================
    ;==[FIN MENU CHOIX LIGNE AVEC ITEM VARIABLE]==============================================================================================
    ;=========================================================================================================================================
    ;=========================================================================================================================================

    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hHelp, "&A propos", $e_idAbout)
    _GUICtrlMenu_AddMenuItem($hHelp, "&Comment utiliser " & $ApplicationName & "?", $e_idHowTo)

    ; Create Main menu
    Global $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hMain, "&Fichier", 0, $hFile)
    _GUICtrlMenu_AddMenuItem($hMain, "&Choix de la ligne", 1, $hLineChoice)
    _GUICtrlMenu_AddMenuItem($hMain, "&?", 3, $hHelp)

    $hStatus = _GUICtrlStatusBar_Create($hGUI, -1, "", $SBARS_SIZEGRIP)

    ;==[StatusBar]==============================
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", $hStatus, "wstr", 0, "wstr", 0)
    $hIcons = _WinAPI_LoadShell32Icon(265)
    _GUICtrlStatusBar_SetIcon($hStatus, 0, $hIcons)
    $hIcons2 = _WinAPI_LoadShell32Icon(160)
    _GUICtrlStatusBar_SetIcon($hStatus, 1, $hIcons2)
    _GUICtrlStatusBar_SetText($hStatus, "Utilisateur: " & StringUpper(@UserName) & " " & "Poste: " & @ComputerName, 1)
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

EndFunc

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam
    $itemID = _WinAPI_LoWord($wParam)

    For $i = 0 to UBound($IDMenu) - 1
        If $itemID = $IDMenu[$i] Then ConsoleWrite("Index: " & $i & @CRLF)
    Next

    Return $GUI_RUNDEFMSG

EndFunc   ;==>WM_COMMAND

Func _WM_DRAWITEM($hWnd, $Msg, $wParam, $lParam)
    #forceref $Msg, $wParam, $lParam
    Local $tDRAWITEMSTRUCT = DllStructCreate("uint CtlType;uint CtlID;uint itemID;uint itemAction;uint itemState;HWND hwndItem;HANDLE hDC;long rcItem[4];ULONG_PTR itemData", $lParam)
    Local $itemID = DllStructGetData($tDRAWITEMSTRUCT, "itemID")
    Local $hDC = DllStructGetData($tDRAWITEMSTRUCT, "hDC")
    Local $tRect = DllStructCreate("long left;long top;long right; long bottom", DllStructGetPtr($tDRAWITEMSTRUCT, "rcItem"))
    Local $iTop = DllStructGetData($tRect, "top")
    Local $iLeft = DllStructGetData($tRect, "left")
    Local $hBrush

    Switch $itemID
        ;Case 0
            ;$hBrush = _WinAPI_CreateSolidBrush(0xFFFF00)
           ; _WinAPI_FillRect($hDC, DllStructGetPtr($tRect), $hBrush)
            ;_WinAPI_SetBkMode($hDC, $TRANSPARENT)
            ;DllStructSetData($tRect, "top", $iTop + 1)
            ;DllStructSetData($tRect, "left", $iLeft + 1)
            ;_WinAPI_DrawText($hDC, "Part 1", $tRect, $DT_LEFT)
            ;_WinAPI_DeleteObject($hBrush)
        ;Case 1
            ;$hBrush = _WinAPI_CreateSolidBrush(0x00FF00)
            ;_WinAPI_FillRect($hDC, DllStructGetPtr($tRect), $hBrush)
            ;_WinAPI_SetBkMode($hDC, $TRANSPARENT)
            ;DllStructSetData($tRect, "top", $iTop + 1)
            ;DllStructSetData($tRect, "left", $iLeft + 1)
            ;_WinAPI_DrawText($hDC, "Part 2", $tRect, $DT_LEFT)
            ;_WinAPI_DeleteObject($hBrush)
        Case 2
            $hBrush = _WinAPI_CreateSolidBrush($iColorResult)
            _WinAPI_FillRect($hDC, DllStructGetPtr($tRect), $hBrush)
            _WinAPI_SetBkMode($hDC, $TRANSPARENT)
            DllStructSetData($tRect, "top", $iTop + 1)
            DllStructSetData($tRect, "left", $iLeft + 1)
            ;_WinAPI_DrawText($hDC, "Part 3", $tRect, $DT_LEFT)
            _WinAPI_DeleteObject($hBrush)
        EndSwitch

    $tDRAWITEMSTRUCT = 0
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_DRAWITEM

Func _ScreenAdaptation()
    $WorkAera = _GetWorkArea()  ;Etait Local $WorkAera = _GetWorkArea() et non Global
    Local $aGuiPos = WinGetPos($hGui)

    ;If WinExists($MachDatGUI) Then
        If $aGuiPos[0] <> $WorkAera[0] OR $aGuiPos[1] <> $WorkAera[1] OR $aGuiPos[2] <> $WorkAera[4] OR $aGuiPos[3] <> $WorkAera[5] Then WinMove($hGui, "", $WorkAera[0]+4, $WorkAera[1]+4, $WorkAera[4] - 8, $WorkAera[5] - 8)
    ;EndIf
EndFunc

Func _GetWorkArea()
    global $Area[6]
    Local $StartRect = DllStructCreate("int[4]")
    Local $PStartRect = DllStructGetPtr($StartRect)
    DllCall("user32.dll", "int", "SystemParametersInfo", "int", 48, "int", 0, "ptr", $PStartRect, "int", 0)
    $Area[0] = DllStructGetData($StartRect,1,1)
    $Area[1] = DllStructGetData($StartRect,1,2)
    $Area[2] = DllStructGetData($StartRect,1,3)
    $Area[3] = DllStructGetData($StartRect,1,4)
    $Area[4] = $Area[2] - $Area[0]
    $Area[5] = $Area[3] - $Area[1]
    Return $Area
EndFunc

Func WM_TIMER($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam

    Switch _Timer_GetTimerID($iwParam)
        Case $iTimer
            _UpdateStatusBarClock()
        EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_TIMER

Func _UpdateStatusBarClock()
   _GUICtrlStatusBar_SetText($hStatus, @TAB & StringFormat(_NowDate() & " " & "%02d:%02d:%02d", @HOUR, @MIN, @SEC), 0)
EndFunc

Func WM_SIZE($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam
    _GUICtrlStatusBar_Resize($hStatus)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE

Func _Quitter()
    Exit
EndFunc

Fichier ini:

► Afficher le texte

Merci par avance

Hugues · #5

Bon, j'ai encore presque reussi de ce que je voulais

Sauf que maintenant c'est au niveau de la gestion des autres menu qui se croisent au niveau des index... pfff

Par exemple, si je séléctionne "Fichier" puis "fermer l'application, il va m'ouvrir un array alors que moi je veux que l'application se ferme...

Erreur:

► Afficher le texte

Mon code complet:

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=favicon.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
;==[ Création ]========:   xx/xx/20xx
;==[ Auteur ]==========:    xxxxxxxxxxxxxxxxxxxxxxx
;==[ Service ]=========:    xxxxxxxxxxxxxxxxxxxxxxx
;==[ Description ]=====:    ************************************
;==[ Modification ]====:    Dernière modification le xx/xx/20xx
;==[ Nature modification ]====:
    ;==[xx/xx/20xx: ***********************************]========

;==[Include]====
#include <GuiStatusBar.au3>
#include <Timers.au3>
#include <Date.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <Color.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <File.au3>
#include <ArrayEx.au3>
#include <Array.au3>
#include <WinAPI.au3>
#include <WinNet.au3>
#include <ComboConstants.au3>
#include <GuiComboBox.au3>
#include <GuiComboBoxEx.au3>
#include <ColorConstantS.au3>
#include <String.au3>
Opt("GUIOnEventMode", 1)

;==[Variables globales & autres]====
Global $ApplicationName = "__________", $Version = "V_._._", $CreationDate = "xx/xx/20xx", $NumberOfModification = "", $LastModification = "", $Area
Global $hStatus, $aParts[4] = [200, 450, 480, 200], $aGuiPos, $iMemo
Global $hGUI, $hFile, $hLineChoice, $hHelp
Global Enum $e_idNew = 1000, $e_idAbout, $e_idExit, $e_idHowTo

$LineFile =  @ScriptDir & "\ini\MenuAuto.ini"
$IniFilePath = @ScriptDir & "\ini\cells.ini"
$IniMesurePoint = @ScriptDir & "\ini\MesurePoint.ini"

;==[Programme]====
_Main()

AdlibRegister("_ScreenAdaptation")
GUIRegisterMsg($WM_SIZE, "WM_SIZE")
GUIRegisterMsg($WM_TIMER, "WM_TIMER")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUIRegisterMsg($WM_DRAWITEM, "_WM_DRAWITEM")
$iTimer = _Timer_SetTimer($hGUI, 1000)

While GUIGetMsg() <> -3
WEnd

Func _Main()

    Global  $iColorResult = 0x000FF0
    $Couleur1 = 0x999999
    $Couleur2 = 0xe5e5e5

    $hGUI = GUICreate($ApplicationName & " - Powered By __________. Version: " & $Version, @DesktopWidth - 100, @DesktopHeight - 100, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Quitter", $hGUI)

    $hFile = _GUICtrlMenu_CreateMenu()
    $New= GUICtrlCreateMenuItem("Nouveau" & @TAB & "Ctrl+N", $hFile)
    _GUICtrlMenu_AddMenuItem($hFile, "Fermer l'application", $e_idExit)

    ;=========================================================================================================================================
    ;=========================================================================================================================================
    ;==[DEBUT MENU CHOIX LIGNE AVEC ITEM VARIABLE]============================================================================================
    ;=========================================================================================================================================
    ;=========================================================================================================================================

    $hLineChoice = _GUICtrlMenu_CreateMenu()
    Global $ReadSection = IniReadSection($LineFile, "LineName")
    Global $IDMenu[$ReadSection[0][0]]

    For $j = 1 To $ReadSection[0][0]
        _GUICtrlMenu_InsertMenuItem($hLineChoice, $j - 1 , "&" & $ReadSection[$j][1], 1000 + ($j - 1))
        $IDMenu[$j-1] = 1000 + ($j - 1)
        ;consolewrite($IDMenu[$j-1] & @CRLF)
    Next

    ;=========================================================================================================================================
    ;=========================================================================================================================================
    ;==[FIN MENU CHOIX LIGNE AVEC ITEM VARIABLE]==============================================================================================
    ;=========================================================================================================================================
    ;=========================================================================================================================================

    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hHelp, "&A propos", $e_idAbout)
    _GUICtrlMenu_AddMenuItem($hHelp, "&Comment utiliser " & $ApplicationName & "?", $e_idHowTo)

    ; Create Main menu
    Global $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hMain, "&Fichier", 0, $hFile)
    _GUICtrlMenu_AddMenuItem($hMain, "&Choix de la ligne", 1, $hLineChoice)
    _GUICtrlMenu_AddMenuItem($hMain, "&?", 3, $hHelp)

    $hStatus = _GUICtrlStatusBar_Create($hGUI, -1, "", $SBARS_SIZEGRIP)

    ;==[StatusBar]==============================
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", $hStatus, "wstr", 0, "wstr", 0)
    $hIcons = _WinAPI_LoadShell32Icon(265)
    _GUICtrlStatusBar_SetIcon($hStatus, 0, $hIcons)
    $hIcons2 = _WinAPI_LoadShell32Icon(160)
    _GUICtrlStatusBar_SetIcon($hStatus, 1, $hIcons2)
    _GUICtrlStatusBar_SetText($hStatus, "Utilisateur: " & StringUpper(@UserName) & " " & "Poste: " & @ComputerName, 1)
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

EndFunc

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam
    $itemID = _WinAPI_LoWord($wParam)

    ;For $i = 0 to UBound($IDMenu) - 1
        ;If $itemID = $IDMenu[$i] Then ConsoleWrite("Index: " & $i & @CRLF)
    ;Next

    Select
        Case $itemID
            Global $ReadSection2 = IniReadSection($IniFilePath, $ReadSection[$itemID - 999][0])
            _ArrayDisplay($ReadSection2)

        Case $e_idExit
            Exit
            
    EndSelect

    Return $GUI_RUNDEFMSG

EndFunc   ;==>WM_COMMAND

Func _WM_DRAWITEM($hWnd, $Msg, $wParam, $lParam)
    #forceref $Msg, $wParam, $lParam
    Local $tDRAWITEMSTRUCT = DllStructCreate("uint CtlType;uint CtlID;uint itemID;uint itemAction;uint itemState;HWND hwndItem;HANDLE hDC;long rcItem[4];ULONG_PTR itemData", $lParam)
    Local $itemID = DllStructGetData($tDRAWITEMSTRUCT, "itemID")
    Local $hDC = DllStructGetData($tDRAWITEMSTRUCT, "hDC")
    Local $tRect = DllStructCreate("long left;long top;long right; long bottom", DllStructGetPtr($tDRAWITEMSTRUCT, "rcItem"))
    Local $iTop = DllStructGetData($tRect, "top")
    Local $iLeft = DllStructGetData($tRect, "left")
    Local $hBrush

    Switch $itemID
        ;Case 0
            ;$hBrush = _WinAPI_CreateSolidBrush(0xFFFF00)
           ; _WinAPI_FillRect($hDC, DllStructGetPtr($tRect), $hBrush)
            ;_WinAPI_SetBkMode($hDC, $TRANSPARENT)
            ;DllStructSetData($tRect, "top", $iTop + 1)
            ;DllStructSetData($tRect, "left", $iLeft + 1)
            ;_WinAPI_DrawText($hDC, "Part 1", $tRect, $DT_LEFT)
            ;_WinAPI_DeleteObject($hBrush)
        ;Case 1
            ;$hBrush = _WinAPI_CreateSolidBrush(0x00FF00)
            ;_WinAPI_FillRect($hDC, DllStructGetPtr($tRect), $hBrush)
            ;_WinAPI_SetBkMode($hDC, $TRANSPARENT)
            ;DllStructSetData($tRect, "top", $iTop + 1)
            ;DllStructSetData($tRect, "left", $iLeft + 1)
            ;_WinAPI_DrawText($hDC, "Part 2", $tRect, $DT_LEFT)
            ;_WinAPI_DeleteObject($hBrush)
        Case 2
            $hBrush = _WinAPI_CreateSolidBrush($iColorResult)
            _WinAPI_FillRect($hDC, DllStructGetPtr($tRect), $hBrush)
            _WinAPI_SetBkMode($hDC, $TRANSPARENT)
            DllStructSetData($tRect, "top", $iTop + 1)
            DllStructSetData($tRect, "left", $iLeft + 1)
            ;_WinAPI_DrawText($hDC, "Part 3", $tRect, $DT_LEFT)
            _WinAPI_DeleteObject($hBrush)
        EndSwitch

    $tDRAWITEMSTRUCT = 0
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_DRAWITEM

Func _ScreenAdaptation()
    $WorkAera = _GetWorkArea()  ;Etait Local $WorkAera = _GetWorkArea() et non Global
    Local $aGuiPos = WinGetPos($hGui)

    ;If WinExists($MachDatGUI) Then
        If $aGuiPos[0] <> $WorkAera[0] OR $aGuiPos[1] <> $WorkAera[1] OR $aGuiPos[2] <> $WorkAera[4] OR $aGuiPos[3] <> $WorkAera[5] Then WinMove($hGui, "", $WorkAera[0]+4, $WorkAera[1]+4, $WorkAera[4] - 8, $WorkAera[5] - 8)
    ;EndIf
EndFunc

Func _GetWorkArea()
    global $Area[6]
    Local $StartRect = DllStructCreate("int[4]")
    Local $PStartRect = DllStructGetPtr($StartRect)
    DllCall("user32.dll", "int", "SystemParametersInfo", "int", 48, "int", 0, "ptr", $PStartRect, "int", 0)
    $Area[0] = DllStructGetData($StartRect,1,1)
    $Area[1] = DllStructGetData($StartRect,1,2)
    $Area[2] = DllStructGetData($StartRect,1,3)
    $Area[3] = DllStructGetData($StartRect,1,4)
    $Area[4] = $Area[2] - $Area[0]
    $Area[5] = $Area[3] - $Area[1]
    Return $Area
EndFunc

Func WM_TIMER($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam

    Switch _Timer_GetTimerID($iwParam)
        Case $iTimer
            _UpdateStatusBarClock()
        EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_TIMER

Func _UpdateStatusBarClock()
   _GUICtrlStatusBar_SetText($hStatus, @TAB & StringFormat(_NowDate() & " " & "%02d:%02d:%02d", @HOUR, @MIN, @SEC), 0)
EndFunc

Func WM_SIZE($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam
    _GUICtrlStatusBar_Resize($hStatus)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE

Func _Quitter()
    Exit
EndFunc

#6

Code : Tout sélectionner

    $itemID = _WinAPI_LoWord($wParam)
    Select
        Case $itemID   ; et là ysspass quoi si $itemID = $e_idExit ?

Hugues · #7

Bin c'est le caca... Le problème c'est que j'ai créé des ComboBox et quand je clic dessus ca me renvoie des Index... Et qui me mette le bazard, donc j'ai fais ça pour "éliminer" les contrôles qui ont un Index < 1000

► Afficher le texte

#8

?

Code : Tout sélectionner

    $itemID = _WinAPI_LoWord($wParam)
    Select
         Case $itemID = $e_idExit
            Exit
        Case ($itemID > 999) AND ($itemID <> $e_idExit)
            For $i = 0 to UBound($IDMenu) - 1
                 If $itemID = $IDMenu[$i] Then ConsoleWrite($ReadSection[$i][1] & @crlf)
            Next
    EndSelect

Hugues · #9

Bin non, car si tu testes mon code, tu verras que lorsque tu sélectionnes l'item "Fermer application", il retourne un index 2 et si tu sélectionnes l'item "ABS9 ligne 1" du menu Choix de la ligne, il retourne lui aussi un index 2... donc dans le cas

Code : Tout sélectionner

Select
         Case $itemID = $e_idExit
            Exit

bin ca ne marche pas...

#10

C'est normal. $e_idExit = 1002 et l'ID dans $IDMenu pour "ABS9 ligne 1" = 1002 aussi.
J'ai changé, dans la boucle For, l'ID de début (j'ai mis 1100 au lieu de 1000) pour éviter un conflit.

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=favicon.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
;==[ Création ]========:   xx/xx/20xx
;==[ Auteur ]==========:    xxxxxxxxxxxxxxxxxxxxxxx
;==[ Service ]=========:    xxxxxxxxxxxxxxxxxxxxxxx
;==[ Description ]=====:    ************************************
;==[ Modification ]====:    Dernière modification le xx/xx/20xx
;==[ Nature modification ]====:
;==[xx/xx/20xx: ***********************************]========

;==[Include]====
#include <GuiStatusBar.au3>
#include <Timers.au3>
#include <Date.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <Color.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <File.au3>
;~ #include <ArrayEx.au3>
#include <Array.au3>
#include <WinAPI.au3>
#include <WinNet.au3>
#include <ComboConstants.au3>
#include <GuiComboBox.au3>
#include <GuiComboBoxEx.au3>
#include <ColorConstantS.au3>
#include <String.au3>
Opt("GUIOnEventMode", 1)

;==[Variables globales & autres]====
Global $ApplicationName = "__________", $Version = "V_._._", $CreationDate = "xx/xx/20xx", $NumberOfModification = "", $LastModification = "", $Area
Global $hStatus, $aParts[4] = [200, 450, 480, 200], $aGuiPos, $iMemo
Global $hGUI, $hFile, $hLineChoice, $hHelp
Global Enum $e_idNew = 1000, $e_idAbout, $e_idExit, $e_idHowTo

;~ $LineFile = @ScriptDir & "\ini\MenuAuto.ini"
$LineFile = @ScriptDir & "\fichier_ini.ini"
$IniFilePath = @ScriptDir & "\ini\cells.ini"
$IniMesurePoint = @ScriptDir & "\ini\MesurePoint.ini"

;==[Programme]====
_Main()

AdlibRegister("_ScreenAdaptation")
GUIRegisterMsg($WM_SIZE, "WM_SIZE")
GUIRegisterMsg($WM_TIMER, "WM_TIMER")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUIRegisterMsg($WM_DRAWITEM, "_WM_DRAWITEM")
$iTimer = _Timer_SetTimer($hGUI, 1000)

While GUIGetMsg() <> -3
WEnd

Func _Main()

    Global $iColorResult = 0x000FF0
    $Couleur1 = 0x999999
    $Couleur2 = 0xe5e5e5

    $hGUI = GUICreate($ApplicationName & " - Powered By __________. Version: " & $Version, @DesktopWidth - 100, @DesktopHeight - 100, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Quitter", $hGUI)

    $hFile = _GUICtrlMenu_CreateMenu()
    $New = GUICtrlCreateMenuItem("Nouveau" & @TAB & "Ctrl+N", $hFile)
    _GUICtrlMenu_AddMenuItem($hFile, "Fermer l'application", $e_idExit)

    ;=========================================================================================================================================
    ;=========================================================================================================================================
    ;==[DEBUT MENU CHOIX LIGNE AVEC ITEM VARIABLE]============================================================================================
    ;=========================================================================================================================================
    ;=========================================================================================================================================

    $hLineChoice = _GUICtrlMenu_CreateMenu()
    Global $ReadSection = IniReadSection($LineFile, "LineName")
;~  _ArrayDisplay($ReadSection)
    Global $IDMenu[$ReadSection[0][0]]

    For $j = 1 To $ReadSection[0][0]
        _GUICtrlMenu_InsertMenuItem($hLineChoice, $j - 1, "&" & $ReadSection[$j][1], 1100 + ($j - 1))
        $IDMenu[$j - 1] = 1100 + ($j - 1)
        ;consolewrite($IDMenu[$j-1] & @CRLF)
    Next

    ;=========================================================================================================================================
    ;=========================================================================================================================================
    ;==[FIN MENU CHOIX LIGNE AVEC ITEM VARIABLE]==============================================================================================
    ;=========================================================================================================================================
    ;=========================================================================================================================================

    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hHelp, "&A propos", $e_idAbout)
    _GUICtrlMenu_AddMenuItem($hHelp, "&Comment utiliser " & $ApplicationName & "?", $e_idHowTo)

    ; Create Main menu
    Global $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hMain, "&Fichier", 0, $hFile)
    _GUICtrlMenu_AddMenuItem($hMain, "&Choix de la ligne", 1, $hLineChoice)
    _GUICtrlMenu_AddMenuItem($hMain, "&?", 3, $hHelp)

    $hStatus = _GUICtrlStatusBar_Create($hGUI, -1, "", $SBARS_SIZEGRIP)

    ;==[StatusBar]==============================
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", $hStatus, "wstr", 0, "wstr", 0)
    $hIcons = _WinAPI_LoadShell32Icon(265)
    _GUICtrlStatusBar_SetIcon($hStatus, 0, $hIcons)
    $hIcons2 = _WinAPI_LoadShell32Icon(160)
    _GUICtrlStatusBar_SetIcon($hStatus, 1, $hIcons2)
    _GUICtrlStatusBar_SetText($hStatus, "Utilisateur: " & StringUpper(@UserName) & " " & "Poste: " & @ComputerName, 1)
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

EndFunc   ;==>_Main

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam
    $itemID = _WinAPI_LoWord($wParam)
    ;For $i = 0 to UBound($IDMenu) - 1
    ;If $itemID = $IDMenu[$i] Then ConsoleWrite("Index: " & $i & @CRLF)
    ;Next
    ConsoleWrite(UBound($ReadSection) & @CRLF)
    ConsoleWrite($itemID - 1099 & @CRLF)
    ConsoleWrite($itemID & @CRLF)
    Select
        Case $itemID = $e_idExit
            Exit
        Case ($itemID >= 1100) And ($itemID <> $e_idExit)
            For $i = 0 To UBound($IDMenu) - 1
                If $itemID = $IDMenu[$i] Then ConsoleWrite($ReadSection[$i + 1][1] & @CRLF)
            Next
    EndSelect

    Return $GUI_RUNDEFMSG

EndFunc   ;==>WM_COMMAND

Func _WM_DRAWITEM($hWnd, $Msg, $wParam, $lParam)
    #forceref $Msg, $wParam, $lParam
    Local $tDRAWITEMSTRUCT = DllStructCreate("uint CtlType;uint CtlID;uint itemID;uint itemAction;uint itemState;HWND hwndItem;HANDLE hDC;long rcItem[4];ULONG_PTR itemData", $lParam)
    Local $itemID = DllStructGetData($tDRAWITEMSTRUCT, "itemID")
    Local $hDC = DllStructGetData($tDRAWITEMSTRUCT, "hDC")
    Local $tRect = DllStructCreate("long left;long top;long right; long bottom", DllStructGetPtr($tDRAWITEMSTRUCT, "rcItem"))
    Local $iTop = DllStructGetData($tRect, "top")
    Local $iLeft = DllStructGetData($tRect, "left")
    Local $hBrush

    Switch $itemID
        ;Case 0
        ;$hBrush = _WinAPI_CreateSolidBrush(0xFFFF00)
        ; _WinAPI_FillRect($hDC, DllStructGetPtr($tRect), $hBrush)
        ;_WinAPI_SetBkMode($hDC, $TRANSPARENT)
        ;DllStructSetData($tRect, "top", $iTop + 1)
        ;DllStructSetData($tRect, "left", $iLeft + 1)
        ;_WinAPI_DrawText($hDC, "Part 1", $tRect, $DT_LEFT)
        ;_WinAPI_DeleteObject($hBrush)
        ;Case 1
        ;$hBrush = _WinAPI_CreateSolidBrush(0x00FF00)
        ;_WinAPI_FillRect($hDC, DllStructGetPtr($tRect), $hBrush)
        ;_WinAPI_SetBkMode($hDC, $TRANSPARENT)
        ;DllStructSetData($tRect, "top", $iTop + 1)
        ;DllStructSetData($tRect, "left", $iLeft + 1)
        ;_WinAPI_DrawText($hDC, "Part 2", $tRect, $DT_LEFT)
        ;_WinAPI_DeleteObject($hBrush)
        Case 2
            $hBrush = _WinAPI_CreateSolidBrush($iColorResult)
            _WinAPI_FillRect($hDC, DllStructGetPtr($tRect), $hBrush)
            _WinAPI_SetBkMode($hDC, $TRANSPARENT)
            DllStructSetData($tRect, "top", $iTop + 1)
            DllStructSetData($tRect, "left", $iLeft + 1)
            ;_WinAPI_DrawText($hDC, "Part 3", $tRect, $DT_LEFT)
            _WinAPI_DeleteObject($hBrush)
    EndSwitch

    $tDRAWITEMSTRUCT = 0
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_DRAWITEM

Func _ScreenAdaptation()
    $WorkAera = _GetWorkArea() ;Etait Local $WorkAera = _GetWorkArea() et non Global
    Local $aGuiPos = WinGetPos($hGUI)

    ;If WinExists($MachDatGUI) Then
    If $aGuiPos[0] <> $WorkAera[0] Or $aGuiPos[1] <> $WorkAera[1] Or $aGuiPos[2] <> $WorkAera[4] Or $aGuiPos[3] <> $WorkAera[5] Then WinMove($hGUI, "", $WorkAera[0] + 4, $WorkAera[1] + 4, $WorkAera[4] - 8, $WorkAera[5] - 8)
    ;EndIf
EndFunc   ;==>_ScreenAdaptation

Func _GetWorkArea()
    Global $Area[6]
    Local $StartRect = DllStructCreate("int[4]")
    Local $PStartRect = DllStructGetPtr($StartRect)
    DllCall("user32.dll", "int", "SystemParametersInfo", "int", 48, "int", 0, "ptr", $PStartRect, "int", 0)
    $Area[0] = DllStructGetData($StartRect, 1, 1)
    $Area[1] = DllStructGetData($StartRect, 1, 2)
    $Area[2] = DllStructGetData($StartRect, 1, 3)
    $Area[3] = DllStructGetData($StartRect, 1, 4)
    $Area[4] = $Area[2] - $Area[0]
    $Area[5] = $Area[3] - $Area[1]
    Return $Area
EndFunc   ;==>_GetWorkArea

Func WM_TIMER($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam

    Switch _Timer_GetTimerID($iwParam)
        Case $iTimer
            _UpdateStatusBarClock()
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_TIMER

Func _UpdateStatusBarClock()
    _GUICtrlStatusBar_SetText($hStatus, @TAB & StringFormat(_NowDate() & " " & "%02d:%02d:%02d", @HOUR, @MIN, @SEC), 0)
EndFunc   ;==>_UpdateStatusBarClock

Func WM_SIZE($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam
    _GUICtrlStatusBar_Resize($hStatus)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE

Func _Quitter()
    Exit
EndFunc   ;==>_Quitter

Hugues · #11

Ok impeccable, merci à vous 2!

AutoIt Français

[R] Récupérer Index Item d'un menu

[R] Récupérer Index Item d'un menu

Re: [..] Récupérer Index Item d'un menu

Re: [..] Récupérer Index Item d'un menu

Re: [..] Récupérer Index Item d'un menu

Re: [..] Récupérer Index Item d'un menu

Re: [..] Récupérer Index Item d'un menu

Re: [..] Récupérer Index Item d'un menu

Re: [..] Récupérer Index Item d'un menu

Re: [..] Récupérer Index Item d'un menu

Re: [..] Récupérer Index Item d'un menu

Re: [R] Récupérer Index Item d'un menu