[R] La plus grande valeur d'un tableau multidimensionel

[Hugues]

Bonjour à tous,

Je n'arrive pas à trouver la valeur la plus grande d'un tableau mutidimensionel...

J'ai un tableau qui fait 4 colonnes et x lignes... Je voudrais trouver la plus grande valeur qui se trouve dans la colonne 4...

Je sais qu'il existe la fonction _ArrayMaxIndex() mais je ne sais pas trop l'utiliser (ou si on le peut) sur un tableau multi...

Merci par avance de votre aide.

[jguinch]

Tu peux passer par un tableau temporaire d'une seule colonne qui contiendra les valeurs de la colonne 4, comme ça tu pourras utiliser _ArrayMax ou_ArrayMaxIndex :

Code : Tout sélectionner

#Include <Array.au3>
Local $aData[2][4] = [ [ 1, 2, 3, 4], [5, 6, 7, 8] ]
Local $aTemp[Ubound($aData)]

For $i = 0 To UBound($aData) - 1
    $aTemp[$i] = $aData[$i][3]
Next
Local $iMaxIndex = _ArrayMaxIndex($aTemp)

MsgBox(0, "", "La valeur max est " & $aTemp[$iMaxIndex])

[Hugues]

Arff, c'est ce que je viens de faire...

Je joins mon code, comme je suis pas programmeur, est-il possible de le simplifier?

► Afficher le texte

Code : Tout sélectionner

;==[ Les Includes ]====
#include <Array.au3>
#include<FileListToArrayNT.au3>
#include <File.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

HotKeySet("{ESC}", "Terminate")

;==[ On cherche les fichiers *.dat]====
$DATArray = _FileListToArrayNT (@WorkingDir & "*.dat", 1, 0, True, "Exclusion.DAT")

;==[ Options _FileListToArrayNT ]====
;$sPath : Chemin de recherche
;$sFilter : Filtres de recherches (multiples filtres acceptés - caractères génériques et multi-fichiers séparés par un point virgule)
;$iSearchType : 0 = Retourne fichier et répertoire (défaut), 1 = Retourne que les fichiers, 2 = Retourne que les répertoires.
;$iPathType : Format des éléments renvoyés : 0 = Seulement le nom fichier/dossier (défaut), 1 = Chemin relatif, 2 = Chemin complet
;$bRecursive : Recherche récursive : False = Non (défaut), True = Oui
;$sExclude : Liste des exclusions, séparées par un point virgule.
;$iRetFormat : Format de renvoi du résultat. 0 = Tableau base 0, 1 = Tableau base 1 (défaut), 2 = Chaîne (délimitée par "|")

Local $aRecords
Local $HelpArray[Ubound($DATArray)-1][4]
Local $HelpArray2[Ubound($DATArray)-1]

For $i = 1 to Ubound($DATArray) - 1
    $DATFile = _FileReadToArray(@WorkingDir  & $DATArray[$i], $aRecords)

    Local $CellNumber = StringSplit(StringReplace($aRecords[4], " ", ""), ":", 2)
        $HelpArray[$i-1][0] = $CellNumber[1]

    Local $CellName = StringSplit(StringReplace($aRecords[5], " ", ""), ":", 2)
        $HelpArray[$i-1][1] = $CellName[1]

    Local $PartNrVar = StringSplit(StringReplace($aRecords[10], " ", ""), ":", 2)
        $HelpArray[$i-1][2] = $PartNrVar[1]

    Local $MeanCycleTime = StringSplit(StringReplace($aRecords[28], " ", ""), ":", 2)
        $HelpArray[$i-1][3] = $MeanCycleTime[1]

               $HelpArray2[$i-1] = $MeanCycleTime[1]   ;ICI MON TABLEAU TEMPORAIRE
Next


_ArrayDisplay($HelpArray2)


$azerty = _ArrayMax($HelpArray2, 1, 1)

MsgBox(0, "Error", $azerty)

Func Terminate()
    Exit
EndFunc
 

[Tlem]

Sinon, en reprenant le code de jguinch et en ce basant sur le code de _ArrayMaxIndex(), on peux simplifier la chose comme ceci :

Code : Tout sélectionner

Local $aData[2][4] = [ [ 1, 2, 3, 4], [5, 6, 7, 8] ]
Local $ValMax = 0

For $i = 0 To UBound($aData) - 1
    If Number($ValMax) < Number($aData[$i][3]) Then $ValMax = $aData[$i][3]
Next

MsgBox(0, "", "La valeur max est " & $ValMax)