[R] Questions sur InputBox & Boutons GUI

[Chrono47]

Bonsoir,

Deux questions très bêtes pour ce soir mais je n'ai pas spécialement trouvé mon bonheur dans mes recherches (et j'ai pas spécialement le temps de les approfondir je dois bien l'avouer) :

1) J'utilise une InputBox à la fin de mon logiciel pour affiché uné clé d'un logiciel (en l'occurence, Avast) que je peux par conséquent sélectionner pour aller la copié/collé dans le logiciel après. Cependant, je suis entrain de revoir tout le design de mon logiciel et j'aimerai pouvoir rendre ça un peu plus sympathique à regarder (avec un logo etc, bref vous m'avez compris) mais le soucis est ... comment on fou une image en fond d'une Inputbox ? J'ai pas trouvé :/


2) Concernant les boutons, j'ai fait entièrement ma GUI de fond de mon logiciel en mettant mes icônes etc pour en faire une seule image mais concernant les boutons, est-il possible de faire l'équivalent d'une " image map " (du langage HTML par exemple) sur mes deux boutons " Installer " et " Quitter" afin que si le souris est cliqué à cet endroit, ça lance la fonction que je souhaite ?

Ou bien dois-je mettre des boutons avec mes images de fond découpée (et si oui, comment on fait ça ?)

Voilà pour les deux questions très bêtes de la soirée, ne vous inquiétez pas, d'autres arriveront surement dans les prochains jours ^^

Merci pour votre aide

[PandiPanda]

Bonjour,
si vous voulez mettre une image en fond d'une "inputbox", va falloir crée une GUI qui "ressemble" à une inputbox ^^

Pour l'image map, j'en ai aucune idée, il devrai avoir moyen de "ruser" mais je pense pas qu'il existe de fonction déjà toute faites ...

[Chrono47]

Décidément, vous êtes toujours là pour m'aider PandiPanda

Merci pour votre réponse, pour le soucis de la GUI qui ressemble à une inputbox c'est de pouvoir ensuite sélectionner le texte (la clé en l'occurence) dedans ... je n'ai pas trouvé comment faire ça !


Et concernant les boutons, comment faire pour utilisez une image à la place d'un bouton ? (ce qui pourrai résoudre mon soucis


Merci !

[mikell]

Concernant l'image map, Autoit sait le faire mais il y a des solutions équivalentes et plus simples (labels transparentes par exemple)
Sinon il faut bien lire l'aide :

A Button control can display an icon or image by using the $BS_ICON or $BS_BITMAP style. Use GUICtrlSetImage to specify the picture to use.

On peut aussi faire des images réactives avec GuiCtrlCreatePic, etc
Pour l'inputbox, montre ton code

[Chrono47]

Ok pour les boutons je vais regardé ça, sinon pour l'inputbox c'est un truc tout bête de la sorte :

Code : Tout sélectionner

InputBox("FIN D'INTERVENTION AUTOMATIQUE", "Clé AVAST : ", "C01XXXXXXXX200A0414-40XXXXXX", "")
 

Et j'aimerai pouvoir y mettre cette image en fond :

[mikell]

Quelque chose comme ça quoi

► Afficher le texte

Code : Tout sélectionner

;InputBox("FIN D'INTERVENTION AUTOMATIQUE", "Clé AVAST : ", "C01027245H1200A0414-40M3B2MS", "")

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$nbr = "C01027245H1200A0414-40M3B2MS"

GUICreate("titre", 250, 250, -1, -1, $WS_POPUP)
GUICtrlCreatePic ("580401KeyAvast.jpg", 0, 0, 250, 250)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreateLabel("Clé AVAST : ", 90, 170, 70, 18, 1)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$input = GUICtrlCreateInput("", 10, 190, 230, 18, 1)
GuiCtrlSetData($input, $nbr)
$ok = GUICtrlCreateButton("OK", 60, 220, 60, 25)
GUICtrlSetBkColor(-1, 0xbadaff)
$cancel = GUICtrlCreateButton("Annuler", 140, 220, 60, 25)
GUICtrlSetBkColor(-1, 0xbadaff)
GuiSetState()

While 1
   $msg = GUIGetMsg()
        Select
            Case $msg = $ok
                Msgbox(0, "", GuiCtrlRead($input) )
                Exit
            Case $msg = $cancel
                Exit
        EndSelect
WEnd
 

[Chrono47]

Parfait ^^

Merci beaucoup

C'est bon pour les boutons aussi !

Sinon, dernière question :

Est-il possible d'inverser l'ordre d'execution de plusieurs checkbox ?

J'entends par là :

Checkbox1=Avast
Checkbox2=Firefox
Checkbox3=VLC

Si je selectionne mes trois checkbox dans mon logiciel, ça va commencer par la 1 puis 2 puis 3 hors j'aimerai pouvoir changer cette ordre en 2 1 3 par exemple, mais sans changer le numéro de la checkbox (en gros, la solution " bah change dans ton logiciel checkbox1=avast par =firefox et voilà n'est pas qq ch de " pratique " pour moi )

Mici !

[mikell]

Hum...
Il me semble que tu avais déjà eu une réponse, là :
http://www.autoitscript.fr/forum/viewto ... 20&t=10173

Mais en fait il y a plusieurs solutions
La plus simple : au fur et à mesure que tu coches tes checkbox dans l'ordre voulu, enregistrer les données dans une array, et ensuite exécuter à partir de l'array
Par exemple :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Global $n, $ordre, $array

GUICreate("My GUI Checkbox") 
$check1 = GUICtrlCreateCheckbox("CHECKBOX 1", 10, 10, 120, 20)
$check2 = GUICtrlCreateCheckbox("CHECKBOX 2", 10, 40, 120, 20)
$check3 = GUICtrlCreateCheckbox("CHECKBOX 3", 10, 70, 120, 20)
$go = GUICtrlCreateButton("Go", 30, 110, 50, 25)
GUISetState() 

_Reset()

While 1
$msg = GUIGetMsg()
Switch $msg       
      Case $GUI_EVENT_CLOSE 
            ExitLoop
      Case $check1,  $check2,  $check3
           If $n <= $array[0] Then 
                If $msg = $check1 Then $array[$n] = "execution 1"
                If $msg = $check2 Then $array[$n] = "execution 2"
                If $msg = $check3 Then $array[$n] = "execution 3"
                $n += 1
           EndIf
      Case $go
           For $i = 1 to $array[0]
               $ordre &= $array[$i] & @crlf
           Next
           Msgbox(0, "ordre", "l'exécution sera faite dans cet ordre :" & @crlf & $ordre)
           _Reset()
EndSwitch
WEnd

Func _Reset()
    GUICtrlSetState($check1, $GUI_UNCHECKED)
    GUICtrlSetState($check2, $GUI_UNCHECKED)
    GUICtrlSetState($check3, $GUI_UNCHECKED)
    $n = 1
    $ordre = ""
    Dim $array[4]
    $array[0] = UBound($array)-1
EndFunc
 

Tu peux aussi écrire dans un Edit ou Listview de controle pour vérifier cet ordre d'exécution, etc

[Chrono47]

Merci beaucoup pour votre aide

Et a bientôt pour d'autres questions stupides