[..] eMail Automatique

[Yoyo86220]

Bonjour a tous,

J'ai créé un formulaire avc autoit sous forme de petit programme... et je voudrai que :

quand je clic sur le bouton envoyer sa envoi un email automatiquement a une adresse spécifié merci de m'aider

[timmalos]

je ne sais pas si il existe une fonction qui peut faire ca, sinon tu utilise ton logiciel (moi j'ai mozilla thunderbird) et tu simule les clics de souris ou appuis sur touche de clavier.)
Si tu ne sais pas faire dis et je te ferai ca des que possible, en me donnant ton logiciel de messagerie .

[Yogui]

bonjour,

Vous trouverez un exemple d'envoie de mail en suivant le lien suivant

http://www.autoitscript.fr/forum/viewto ... &sk=t&sd=a

[Vins83]

Voilà un petit exemple qui bug juste sur l'envoie du texte, j'en profite au passage pour demander au Ténor pourquoi le texte ne s'envoi pas? et si il y a une solution..

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <INet.au3>

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Connaitre SMTP ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

FileDelete(@TempDir & "\fai.tmp")
InetGet("http://arrkhan.free.fr/fai.php", @TempDir & "\fai.tmp", 1, 0)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Connaitre SMTP ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Variable de programme ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

$Titre = "Angelemail"
$version = " v0.1"
$l = 580
$h = 495

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Variable de programme ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Fenetre ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

$fenetre = GUICreate($Titre & $version, $l, $h, -1, -1, $WS_CAPTION)
GUICtrlSetFont(-1, 20, 400, 0, "Arial")
GUISetIcon(@ScriptDir & "\" & $Titre & ".exe", 0)

; Adresse du contact
GUICtrlCreateLabel("Adresse du contact :", 5, 13, 100, 25)
GUICtrlSetFont(-1, 8, 500, 2)
$adresse_contact = GUICtrlCreateInput("", 125, 10, $l - 130, 20, -1, $WS_EX_CLIENTEDGE)

; Adresse du destination
GUICtrlCreateLabel("Adresse de destination :", 5, 38, 115, 25)
GUICtrlSetFont(-1, 8, 500, 2)
$adresse_destinataire = GUICtrlCreateInput("", 125, 35, $l - 130, 20, -1, $WS_EX_CLIENTEDGE)

; Sujet
GUICtrlCreateLabel("Sujet :", 5, 63, 115, 25)
GUICtrlSetFont(-1, 8, 500, 2)
$sujet = GUICtrlCreateInput("", 125, 60, $l - 130, 20, -1, $WS_EX_CLIENTEDGE)

; adresse de serveur SMTP à utiliser - REQUIS
GUICtrlCreateLabel("Smtp :", 5, 88, 30, 25)
GUICtrlSetFont(-1, 8, 500, 2)
$serveur_smtp = GUICtrlCreateInput(FileRead(@TempDir & "\fai.tmp"), 125, 85, 100, 20, -1, $WS_EX_CLIENTEDGE)

; nom de la personne qui envoye le mail
GUICtrlCreateLabel("Nom :", $l - 205, 88, 30, 25)
GUICtrlSetFont(-1, 8, 500, 2)
$nom = GUICtrlCreateInput(@UserName, $l - 105, 85, 100, 20, -1, $WS_EX_CLIENTEDGE)

; Ecrire texte
$texte = GUICtrlCreateEdit("", 5, 113, $l - 10, $h - 155)

; Boutton envoyer email
$bouttonaction = GUICtrlCreateButton("Envoyer", 5, $h - 35, $l - 115, 30)
GUICtrlSetCursor(-1, 0)

; Boutton quitter
$bouttonquitter = GUICtrlCreateButton("Quitter", $l - 105, $h - 35, 100, 30)
GUICtrlSetCursor(-1, 0)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;                                                                                    Case $msg                                                                                     ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

GUISetState(@SW_SHOW)

While 1
    $msg = GUIGetMsg()
    Select

        ; Boutton Quitter
        Case $msg = $bouttonquitter
            Exit
            
            ; Boutton envoyer
        Case $msg = $bouttonaction
            
            ; verrifie adresse du contact
            If GUICtrlRead($adresse_contact) == "" Then
                MsgBox(0, $Titre, "Adresse du contact non renseignée", 5)
            Else
                ; verrifie adresse du destination
                If GUICtrlRead($adresse_destinataire) == "" Then
                    MsgBox(0, $Titre, "Adresse du destination non renseignée", 5)
                Else
                    ; verrifie le sujet
                    If GUICtrlRead($sujet) == "" Then
                        MsgBox(0, $Titre, "Titre du sujet non renseignée", 5)
                    Else
                        ; verrifie le smtp
                        If GUICtrlRead($serveur_smtp) == "" Then
                            MsgBox(0, $Titre, "Serveur smtp non renseignée", 5)
                        Else
                            ; verrifie le nom
                            If GUICtrlRead($nom) == "" Then
                                MsgBox(0, $Titre, "Le nom n'a pas été renseignée", 5)
                            Else
                                $Response = _INetSmtpMail(GUICtrlRead($serveur_smtp), GUICtrlRead($nom), GUICtrlRead($adresse_contact), GUICtrlRead($adresse_destinataire), GUICtrlRead($sujet), GUICtrlRead($texte),"",-1)
                                $err = @error
                                If $Response = 1 Then
                                    MsgBox(0, $Titre, "Mail bien envoyé")
                                Else
                                    MsgBox(0, $Titre, "Le mail a échoué.Le code erreur est: " & $err)
                                EndIf

                            EndIf
                        EndIf
                    EndIf
                EndIf
            EndIf
            
    EndSelect
    
WEnd

[Tlem]

j'en profite au passage pour demander au Ténor pourquoi le texte ne s'envoi pas? et si il y a une solution.

Tout simplement $sujet doit être un tableau simple, dont chaque ligne ce termine par @CRLF.

[VoLCoM]

Bonjour,
Excuser mon ignorance, je débute avec Autoit. Très intéressant cette petite application. Quelle(s) ligne(s) dois-je modifier afin que le texte s'envoi.

Merci pour votre aide.