[R] Tester l'IP d'un mail sur un RBL

[nHioubi]

Bonjour à tous

Les Info :
De nos jours qui ne reçoit pas du spam ?
Dans notre entreprise nous recevons (en Moyenne, en pleine semaine entre 10H et 16H) 25mails / 5secs.
Parmi les 25mails, 80% sont du spam. Merci à l'antispam qui utilise des RBL d'en bloquer 90% de c'est spam !
Le soucis, c'est que l'antispam passe en sur-charge de temps en temps, et laisse passer du spam.

Mon besoin :
- Une Petite IHM avec : un Textbox et un bouton.
- Le textbox recevra l'adresse IP de l'emetteur du mail (Exemple : 119.152.53.196) qui n'a pas été filtré.
- Une fois l'adresse ajouter, on clique sur le bouton "Valider".
- Redirection direct sur le site = http://www.spamcop.net/w3m?action=check ... XXXXXXXXXX (ou XXXXXXX = adresse IP situé dans le Textbox.)
EX : http://www.spamcop.net/w3m?action=check ... 152.53.196
- SI dans la page internet il y a : Causes of listing ALORS un msgbox s'ouvre et nous le signal (IP listé par exemple)
- SINON un msgbox s'ouvre et nous le signal (IP non listé par exemple)
- Dernière demande : Que la page internet ne s'affiche pas.

Voilà, par avance je vous remercie !

[HeartKey]

Va voir du coter de InetGet (ou InetRead pour la beta).

[nHioubi]

Va voir du coter de InetGet (ou InetRead pour la beta).

Bonjour HeartKey,
En fait ce que vous proposez c'est de télécharger la page Web, puis de faire un test en lecture dessus ?
En résumé, une fois le résultat téléchargé en html, on utilisera une fonction pour ouvrir ce ficher, et tester la présence de "Causes of listing" ?

[HeartKey]

C'est exactement sa , la fonction InetGet permet de sauver la page sur le disque puis on ouvre le fichier pour tester son contenu , l'avantage de la fonction InetRead (disponible uniquement sur la version beta de autoit) est que la page est stocker dans une variable, elle est donc directement testable.
Si j'ai un petit moment de libre dans la journée je ferai un exemple voir un script compler.

[nHioubi]

C'est exactement sa , la fonction InetGet permet de sauver la page sur le disque puis on ouvre le fichier pour tester son contenu , l'avantage de la fonction InetRead (disponible uniquement sur la version beta de autoit) est que la page est stocker dans une variable, elle est donc directement testable.
Si j'ai un petit moment de libre dans la journée je ferai un exemple voir un script compler.

C'est très bon à savoir
Je continue à faire mes recherches de mon côtés, merci d'avance si vous pouvez me faire un exemple


(J'ai juste commencé à faire ceci)

► Afficher le texteCode IHM

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
$F_main = GUICreate("SPAM RBL", 167, 88, 436, 184)
GUISetOnEvent($GUI_EVENT_CLOSE, "F_mainClose")
GUISetOnEvent($GUI_EVENT_MINIMIZE, "F_mainMinimize")
GUISetOnEvent($GUI_EVENT_MAXIMIZE, "F_mainMaximize")
GUISetOnEvent($GUI_EVENT_RESTORE, "F_mainRestore")
$tb_ip = GUICtrlCreateInput("tb_ip", 24, 16, 121, 21)
GUICtrlSetOnEvent(-1, "tb_ipChange")
$but_ok = GUICtrlCreateButton("Valider", 32, 48, 100, 22, $BS_FLAT)
GUICtrlSetOnEvent(-1, "but_okClick")
GUISetState(@SW_SHOW)


While 1
    Sleep(100)
WEnd

Func but_okClick()
    $ipTst = GUICtrlRead($tb_ip)
    InetGet("http://www.spamcop.net/w3m?action=checkblock&ip=" & $ipTst , "result.html" , 1 , 0)
EndFunc

Func F_mainClose()
    Exit
EndFunc

Func F_mainMaximize()

EndFunc
Func F_mainMinimize()

EndFunc
Func F_mainRestore()

EndFunc
Func tb_ipChange()

EndFunc
 

[Yogui]

► Afficher le texte

#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 165, 147, 192, 124)
$Input1 = _GUICtrlIpAddress_Create($Form1, 24, 40, 121, 21)
_GUICtrlIpAddress_Set($Input1, "0.0.0.0")
$Button1 = GUICtrlCreateButton("chercher", 40, 72, 75, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Button1
MsgBox(0,"",_GUICtrlIpAddress_Get($Input1))
FileDelete("c:\temps\foo.txt")
_cherchechaine()
EndSwitch
WEnd
Func _cherchechaine()
$var = Ping("www.google.fr", 250)
If $var Then; also possible: If @error = 0 Then ...
InetGet("http://www.spamcop.net/w3m?action=checkblock&ip=" & _GUICtrlIpAddress_Get($Input1), 'c:\temps\foo.txt')
Sleep(1000)
$file = FileOpen("c:\temps\foo.txt", 0)
If $file = -1 Then
MsgBox(0, "Error", "Unable to open file.")
Exit
EndIf
While 1
$ligne = FileReadLine($file)
If @error = -1 Then ExitLoop
If StringInStr($ligne, "Causes of listing") Then
MsgBox(0, "Trouvé", 'Spam')
ExitLoop
EndIf
WEnd
FileClose($file)
Else
MsgBox(16, "Erreur", "Vous n'étes pas connecté à internet")
EndIf
EndFunc ;==>_cherchechaine

[Iste]

l'avantage de la fonction InetRead (disponible uniquement sur la version beta de autoit) est que la page est stocker dans une variable, elle est donc directement testable

Ya aussi _INetGetSource() ou meme la fonction httprequest() que j'ai posté un peu partout sur le forum

[nHioubi]

Merci à vous tous

J'apporte quelque modification par rapport au code de Yogui et je post la source.

[HeartKey]

Malheuresement la fonction _InetGetSource ralenti considérablement le script , pour l'autre fonction je ne sais pas , je ne men suis jamais servi x)

[Yogui]

pour suivre le conseil de Iste :

► Afficher le texte

#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <WindowsConstants.au3>
#include <INet.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 165, 147, 192, 124)
$Input1 = _GUICtrlIpAddress_Create($Form1, 24, 40, 121, 21)
_GUICtrlIpAddress_Set($Input1, "0.0.0.0")
$Button1 = GUICtrlCreateButton("chercher", 40, 72, 75, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
Global $trouve
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Button1
_cherchechaine()
EndSwitch
WEnd
Func _cherchechaine()
$trouve = 0
$var = Ping("www.google.fr", 250)
If $var Then; also possible: If @error = 0 Then ...
$source = _INetGetSource("http://www.spamcop.net/w3m?action=checkblock&ip=" & _GUICtrlIpAddress_Get($Input1))
If StringInStr($source, "Causes of listing") Then
$trouve = 1
EndIf
Else
MsgBox(16, "Erreur", "Vous n'étes pas connecté à internet")
EndIf

If $trouve = 1 Then
MsgBox(0, "Trouvé", 'Spam')
Else
MsgBox(0, "Non trouvé", 'pas de Spam')
EndIf
EndFunc ;==>_cherchechaine

[Iste]

Malheuresement la fonction _InetGetSource ralenti considérablement le script , pour l'autre fonction je ne sais pas , je ne men suis jamais servi x)

Hum, je viens de faire des teste sur 100actions a l'aide de ce script

► Afficher le texte

Code : Tout sélectionner

#include <INet.au3>

Global $array[101], $temps, $temps1, $temps2, $temps3

$temps = TimerInit()
For $i = 1 To 100
    $array[$i] = _INetGetSource("http://www.google.fr/")
Next
$temps1 = TimerDiff($temps)

$temps = TimerInit()
For $i = 1 To 100
    InetGet("http://www.google.fr/", @TempDir&"\testinetget\"&$i, 1)
    $array[$i] = FileRead(@TempDir&"\testinetget\"&$i)
Next
$temps2 = TimerDiff($temps)

$temps = TimerInit()
For $i = 1 To 100
    $array[$i] = _INetGetSource("http://www.google.fr/")
Next
$temps1 = TimerDiff($temps)

$oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
$temps = TimerInit()
For $i = 1 To 100
    $array[$i] = HTTPRequest("POST","http://www.google.fr/")
Next
$temps3 = TimerDiff($temps)

MsgBox(0,0,"_INetGetSource : "&_format_time($temps1)&@CRLF&"InetGet : "&_format_time($temps2)&@CRLF&"HTTPRequest : "&_format_time($temps3))
ClipPut("_INetGetSource : "&_format_time($temps1)&@CRLF&"InetGet : "&_format_time($temps2)&@CRLF&"HTTPRequest : "&_format_time($temps3))

Func HTTPRequest($oMethod, $oURL, $oData = "")
    If Not IsDeclared("$oHTTP") Then $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
    $oHTTP.Open($oMethod, $oURL, False)
    If $oMethod = "POST" Then $oHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
    $oHTTP.Send($oData)
    Return $oHTTP.ResponseText
EndFunc   ;==>HTTPRequest

;===========================================================================================================
; Description : Formate le temps passe en miliseconde en heures, minutes, secondes
; Syntaxe     : _format_time($time_milisecond)
; Parametere  : $time_milisecond = Temps en milisecondes à formater
; Return      : String
;===========================================================================================================
Func _format_time($time_milisecond)
   
    Local $time_milisecond_formater
    Local $seconde_arrondi
    Local $minute
    Local $seconde
    Local $heure
   
    If( $time_milisecond < 60000 ) Then
        $time_milisecond_formater = Round( ($time_milisecond/1000), 2 ) & " secondes"
    ElseIf( ($time_milisecond >= 60000) AND ($time_milisecond < 3600000) ) Then
        $seconde_arrondi = Int( $time_milisecond / 1000 )
        $minute = Int( $seconde_arrondi / 60)
        $seconde = Round( (($time_milisecond / 1000) - $minute*60), 0 )
        $time_milisecond_formater = $minute & " min " & $seconde & " sec"
    Else
        $seconde_arrondi = Int( $time_milisecond / 1000 )
        $heure = Int( $seconde_arrondi / 3600)
        $minute = Int( (($seconde_arrondi - $heure*3600) / 60) )
        $seconde = Round( (($time_milisecond / 1000) - $heure*3600 - $minute*60), 0)
        $time_milisecond_formater = $heure&"h " &$minute & "m " & $seconde & "s"
    EndIf
   
    Return $time_milisecond_formater
EndFunc
;===========================================================================================================
 

Resultats :
InetGet : 55.59 secondes
_INetGetSource : 42.32 secondes
HTTPRequest : 15.18 secondes

En retirant le coté fileread() nécéssaire a Inetget, on tombe a 29.79 secondes

[HeartKey]

Je disait sa par expérience , uniquement sur mon ordi , qui n'est pas de dernière génération .

[Yogui]

Malheuresement la fonction _InetGetSource ralenti considérablement le script , pour l'autre fonction je ne sais pas , je ne men suis jamais servi x)

Hum, je viens de faire des teste sur 100actions a l'aide de ce script

► Afficher le texte

Code : Tout sélectionner

#include <INet.au3>

Global $array[101], $temps, $temps1, $temps2, $temps3

$temps = TimerInit()
For $i = 1 To 100
    $array[$i] = _INetGetSource("http://www.google.fr/")
Next
$temps1 = TimerDiff($temps)

$temps = TimerInit()
For $i = 1 To 100
    InetGet("http://www.google.fr/", @TempDir&"\testinetget\"&$i, 1)
    $array[$i] = FileRead(@TempDir&"\testinetget\"&$i)
Next
$temps2 = TimerDiff($temps)

$temps = TimerInit()
For $i = 1 To 100
    $array[$i] = _INetGetSource("http://www.google.fr/")
Next
$temps1 = TimerDiff($temps)

$oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
$temps = TimerInit()
For $i = 1 To 100
    $array[$i] = HTTPRequest("POST","http://www.google.fr/")
Next
$temps3 = TimerDiff($temps)

MsgBox(0,0,"_INetGetSource : "&_format_time($temps1)&@CRLF&"InetGet : "&_format_time($temps2)&@CRLF&"HTTPRequest : "&_format_time($temps3))
ClipPut("_INetGetSource : "&_format_time($temps1)&@CRLF&"InetGet : "&_format_time($temps2)&@CRLF&"HTTPRequest : "&_format_time($temps3))

Func HTTPRequest($oMethod, $oURL, $oData = "")
    If Not IsDeclared("$oHTTP") Then $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
    $oHTTP.Open($oMethod, $oURL, False)
    If $oMethod = "POST" Then $oHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
    $oHTTP.Send($oData)
    Return $oHTTP.ResponseText
EndFunc   ;==>HTTPRequest

;===========================================================================================================
; Description : Formate le temps passe en miliseconde en heures, minutes, secondes
; Syntaxe     : _format_time($time_milisecond)
; Parametere  : $time_milisecond = Temps en milisecondes à formater
; Return      : String
;===========================================================================================================
Func _format_time($time_milisecond)
   
    Local $time_milisecond_formater
    Local $seconde_arrondi
    Local $minute
    Local $seconde
    Local $heure
   
    If( $time_milisecond < 60000 ) Then
        $time_milisecond_formater = Round( ($time_milisecond/1000), 2 ) & " secondes"
    ElseIf( ($time_milisecond >= 60000) AND ($time_milisecond < 3600000) ) Then
        $seconde_arrondi = Int( $time_milisecond / 1000 )
        $minute = Int( $seconde_arrondi / 60)
        $seconde = Round( (($time_milisecond / 1000) - $minute*60), 0 )
        $time_milisecond_formater = $minute & " min " & $seconde & " sec"
    Else
        $seconde_arrondi = Int( $time_milisecond / 1000 )
        $heure = Int( $seconde_arrondi / 3600)
        $minute = Int( (($seconde_arrondi - $heure*3600) / 60) )
        $seconde = Round( (($time_milisecond / 1000) - $heure*3600 - $minute*60), 0)
        $time_milisecond_formater = $heure&"h " &$minute & "m " & $seconde & "s"
    EndIf
   
    Return $time_milisecond_formater
EndFunc
;===========================================================================================================
 

Resultats :
InetGet : 55.59 secondes
_INetGetSource : 42.32 secondes
HTTPRequest : 15.18 secondes

En retirant le coté fileread() nécéssaire a Inetget, on tombe a 29.79 secondes

@Iste peux tu m'expliquer ou j'ai fait une erreur avec httpRequest merci

► Afficher le texte

#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 165, 147, 192, 124)
$Input1 = _GUICtrlIpAddress_Create($Form1, 24, 40, 121, 21)
_GUICtrlIpAddress_Set($Input1, "119.152.53.196")
$Button1 = GUICtrlCreateButton("chercher", 40, 72, 75, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
Global $trouve
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Button1
_cherchechaine()
EndSwitch
WEnd
Func _cherchechaine()
$trouve = 0
$var = Ping("www.google.fr", 250)
If $var Then; also possible: If @error = 0 Then ...
$oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
$source = HTTPRequest("POST","http://www.spamcop.net/w3m?action=checkblock&ip="& _GUICtrlIpAddress_Get($Input1))
If StringInStr($source, "Causes of listing") Then
$trouve = 1
EndIf
Else
MsgBox(16, "Erreur", "Vous n'étes pas connecté à internet")
EndIf

If $trouve = 1 Then
MsgBox(0, "Trouvé", 'Spam')
Else
MsgBox(0, "Non trouvé", 'pas de Spam')
EndIf
EndFunc ;==>_cherchechaine




Func HTTPRequest($oMethod, $oURL, $oData = "")
If Not IsDeclared("$oHTTP") Then $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
$oHTTP.Open($oMethod, $oURL, False)
If $oMethod = "POST" Then $oHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
$oHTTP.Send($oData)
Return $oHTTP.ResponseText
EndFunc ;==>HTTPRequest

[Iste]

@HeartKey, Le mien non plus ^^
Mais comme j'utilise souvent ces fonctions, me suis dit que serait temps de faire des testes
Enfin bref, fin du HS sur "Qui a la plus rapide" x)

@Yogui : je vais avoir du mal car je n'en vois pas ^^'
Tu as des probleme avec winhttp.winhttprequest.5.1 ?
Pour info je l'ai un jour récup sur le fofo anglais, et ca a toujours marché son mon winXP, mais j'ai pas poussé les testes plus loin

[nHioubi]

Je reviens vers vous car j'ai des difficultés par rapport au retour

► Afficher le texte

Code : Tout sélectionner

;##### INCLUDES
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiIPAddress.au3>
#include <INet.au3>
;##### INCLUDES #####

;##### HOTKEYSET
HotKeySet("{ESC}", "F_mainClose")
;##### HOTKEYSET #####

;##### VARIABLES
Global $trouve
;##### VARIABLES #####

;##### IHM
Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=
$F_main = GUICreate("SPAM RBL", 167, 88, 436, 184)
GUISetOnEvent($GUI_EVENT_CLOSE, "F_mainClose")
$tb_ip = _GUICtrlIpAddress_Create($F_main, 24, 16, 121, 21)
_GUICtrlIpAddress_Set($tb_ip, "0.0.0.0")
$but_ok = GUICtrlCreateButton("Valider", 32, 48, 100, 22, $BS_FLAT)
GUICtrlSetOnEvent(-1, "but_okClick")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
    Sleep(100)
WEnd
;##### IHM #####



;##### FONCTIONS
Func but_okClick()
    _cherchechaine()
EndFunc


Func _cherchechaine()
    $trouve = 0
    $source = _INetGetSource("http://www.spamcop.net/w3m?action=checkblock&ip=" & _GUICtrlIpAddress_Get($tb_ip))
    If StringInStr($source, "Causes of listing") Then
        $trouve = 1
    EndIf
    If $trouve == 1 Then
        MsgBox(0, "Trouvé", 'Spam')
    Else
        MsgBox(0, "Non trouvé", 'pas de Spam')
    EndIf
EndFunc

Func F_mainClose()
    Exit
EndFunc
;##### FONCTIONS #####

 

Le soucis c'est qu'il me retourne toujours le même résultat (Pas de spam). Testé avec les adresses suivantes : 119.152.53.196 et 59.96.102.200
L'une est bloqué et l'autre non.

[Yogui]

En fait mon script me répond pas de spam alors que le site lui dit le contraire avec l'IP par défaut :s

et si j'affiche le contenu de $source dans un msgbox je n'ai effectivement pas la sources de la page en entier.


@ nHioubi

petite modification sur ton script :

Code : Tout sélectionner

   If $trouve = 1 Then
        MsgBox(0, "Trouvé", 'Spam')
    Else
        MsgBox(0, "Non trouvé", 'pas de Spam')
    EndIf

un simple = suffit

[nHioubi]

En fait mon script me répond pas de spam alors que le site lui dit le contraire avec l'IP par défaut :s
et si j'affiche le contenu de $source dans un msgbox je n'ai effectivement pas la sources de la page en entier.

@ nHioubi
petite modification sur ton script :

Code : Tout sélectionner

   If $trouve = 1 Then
        MsgBox(0, "Trouvé", 'Spam')
    Else
        MsgBox(0, "Non trouvé", 'pas de Spam')
    EndIf

un simple = suffit

L'habitude du C++

Et si on fait l'inverse ? C'est à dire au lieu de mettre "Causes of listing", on met "not listed"? C'est un petit moyen de contournement.

[nHioubi]

Je pense que c'est bon

Voici le code final :

► Afficher le texte

Code : Tout sélectionner

;##### INCLUDES
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiIPAddress.au3>
#include <INet.au3>
;##### INCLUDES #####

;##### HOTKEYSET
HotKeySet("{ESC}", "F_mainClose")
;##### HOTKEYSET #####

;##### VARIABLES
Global $trouve
;##### VARIABLES #####

;##### IHM
Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=
$F_main = GUICreate("SPAM RBL", 167, 88, 436, 184)
GUISetOnEvent($GUI_EVENT_CLOSE, "F_mainClose")
$tb_ip = _GUICtrlIpAddress_Create($F_main, 24, 16, 121, 21)
_GUICtrlIpAddress_Set($tb_ip, "0.0.0.0")
$but_ok = GUICtrlCreateButton("Valider", 32, 48, 100, 22, $BS_FLAT)
GUICtrlSetOnEvent(-1, "but_okClick")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
    Sleep(100)
WEnd
;##### IHM #####



;##### FONCTIONS
Func but_okClick()
    _cherchechaine()
EndFunc


Func _cherchechaine()
    $trouve = 0
    $source = _INetGetSource("http://www.spamcop.net/w3m?action=checkblock&ip=" & _GUICtrlIpAddress_Get($tb_ip))
    If StringInStr($source, "not listed") Then
        $trouve = 1
    EndIf
    If $trouve <> 1 Then
        MsgBox(48, "www.spamcop.net", "L'ip est listée.")
    Else
        MsgBox(64, "www.spamcop.net", "L'ip n'est pas listée.")
    EndIf
EndFunc

Func F_mainClose()
    Exit
EndFunc
;##### FONCTIONS #####

 

Merci à tous pour m'avoir aidé
Je vais essayé de l'améliorer avec d'autre RBL

[Iste]

@Yogui trouvé
La méthode a utiliser pour cette page n'est pas POST, mais GET

[Yogui]

logique ... désolé

Merci d'avoir pris le temps de regarder