AutoIt Français

Salut à tous !

Étant en seconde, on nous a demandé de créer un programme sur notre calculatrice permettant de calculer une valeur de X dans un expression algébrique DONNÉE. Étant fondu de l'AutoIt, je me suis permis de le faire. Cependant, en AutoIt, ce programme vous permettra de mettre n'importe quelle expression algébrique sans avoir à toucher au code source, il vous permettra aussi de calculer plusieurs valeurs de X de -10 à 10 par exemple. Vous aurez aussi un fichier log créé pour pouvoir lire les résultats si jamais vous voulez en tester beaucoup. Pour ma part j'ai testé pour x = -2000 à x = 2000 en deux minutes (oui, un tooltip est placé pour vous montrer en combien de temps le programme a calculé l'ensemble des valeurs de x). Les ventilos seront par contre moins silencieux

Remarque : L'expression algébrique doit vraiment être entrée correctement, c'est à dire avec tout les signes opérateurs.

Ex : 3*x+4*(x-8) << Le programme pourra faire la simple distributivité
Ex : 3x+4(x-8) << Les signes "*" ne sont pas entrés, ils ne seront pas détectés.

Pour tester seulement une valeur de X, entrer 0 dans la seconde InputBox.

Améliorations :

S'il fallait l'améliorer, ça serait peut être ajouter un bouton stop car nous sommes dans une autre boucle, la GUI ne reçoit donc pas d'évènement, je me suis renseigner à ce sujet mais j'y suis vraiment pas arrivé.
Trouver un moyen de faire comme les calculettes, ça veut dire que 3x = 3*x ou x(4+5) = x*(4+5).

Le code :

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.8.0
 Author: blacksoul305

 Script Function: Permet de calculer une ou des valeurs de X dans une expression algébrique.

#ce ----------------------------------------------------------------------------

; Script Start - Add your code below here

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Global $Form1 = GUICreate("Tester les valeurs de X avec une expression algébrique - Algorithme.", 591, 287, 192, 124)
Global $Group1 = GUICtrlCreateGroup("Résultats", 328, 40, 241, 193)
Global $Label1 = GUICtrlCreateLabel("Expression algébrique : ", 344, 72, 200, 17)
Global $Label2 = GUICtrlCreateLabel("Nombre de tests : ", 344, 104, 160, 17)
Global $Label3 = GUICtrlCreateLabel("Valeur de x à tester : ", 344, 136, 160, 17)
Global $Label4 = GUICtrlCreateLabel("Signe du résultat : ", 344, 168, 160, 17)
Global $Label5 = GUICtrlCreateLabel("Valeur du résultat : ", 344, 200, 160, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
Global $Group2 = GUICtrlCreateGroup("Expression algébrique", 24, 64, 265, 153)
Global $Input1 = GUICtrlCreateInput("2*x*x+20", 160, 96, 121, 21)
Global $Label6 = GUICtrlCreateLabel("Expression algébrique : ", 40, 96, 116, 17)
Global $Label7 = GUICtrlCreateLabel("Valeurs de x à tester : ", 40, 128, 109, 17)
Global $Input2 = GUICtrlCreateInput("-10", 160, 128, 33, 21)
Global $Label8 = GUICtrlCreateLabel("à ", 200, 128, 13, 17)
Global $Input3 = GUICtrlCreateInput("10", 224, 128, 33, 21)
Global $Button2 = GUICtrlCreateButton("Lancer le test", 48, 160, 121, 33)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Button1 = GUICtrlCreateButton("Ouvrir le fichier enregistré", 104, 248, 169, 25)
$Button4 = GUICtrlCreateButton("Supprimer le fichier enregistré", 296, 248, 169, 25)
GUISetState(@SW_SHOW)

Global $fichier = @ScriptDir&"\calculs.ini"
Global $onlyOneTest = False
Global $test = 1
Global $calcul = 0
Global $lirePremiereValeurDeX = 0
Global $lireDerniereValeurDeX = 0

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            ShellExecute($fichier)
        Case $Button4
            FileDelete($fichier)
        Case $Button2
            $startChrono = TimerInit()
            $lirePremiereValeurDeX = GUICtrlRead($Input2)
            If $lirePremiereValeurDeX = 0 Then
                GUICtrlSetData($Input2,1)
                $lirePremiereValeurDeX = 1
            EndIf
            $lireDerniereValeurDeX = GUICtrlRead($Input3)
            If $lireDerniereValeurDeX = 0 Then $onlyOneTest = True
            $exprAlgebrique = GUICtrlRead($Input1)
            If $onlyOneTest = True Then
                $nouvelleExpression = StringReplace($exprAlgebrique,"x",$lirePremiereValeurDeX)
                $calcul = Execute($nouvelleExpression)
                $test = 1
                _Display()
                _Log()
            Else
                Do
                    $nouvelleExpression = StringReplace($exprAlgebrique,"x",$lirePremiereValeurDeX)
                    $calcul = Execute($nouvelleExpression)
                    _Display()
                    _Log()
                    $test+=1
                    $lirePremiereValeurDeX+=1
                Until $lirePremiereValeurDeX = $lireDerniereValeurDeX+1
            EndIf
            ToolTip("Le programme a mis "&Round(TimerDiff($startChrono)/1000,2)&" secondes pour calculer l'emsemble des valeurs de X.",5,0)
            _Initialize()
        EndSwitch
    WEnd

Func _Display()
    GUICtrlSetData($Label1,"Expression algébrique : "&$exprAlgebrique)
    GUICtrlSetData($Label2,"Nombre de tests : "&$test)
    GUICtrlSetData($Label3,"Valeurs de x à tester : "&$lirePremiereValeurDeX)
    If $calcul < 0 Then
        GUICtrlSetData($Label4,"Signe du résultat : Négatif")
    ElseIf $calcul > 0 Then
        GUICtrlSetData($Label4,"Signe du résultat : Positif")
    Else
        GUICtrlSetData($Label4,"Signe du résultat : Nul")
    EndIf
    GUICtrlSetData($Label5,"Valeur du résultat : "&$calcul)
EndFunc

Func _Log()
    IniWrite($fichier,"calcul"&$test,"Expression",$exprAlgebrique)
    IniWrite($fichier,"calcul"&$test,"valeur de x à tester",$lirePremiereValeurDeX)
    If $calcul < 0 Then
        IniWrite($fichier,"calcul"&$test,"Signe du résultat","Négatif")
    ElseIf $calcul > 0 Then
        IniWrite($fichier,"calcul"&$test,"Signe du résultat","Positif")
    Else
        IniWrite($fichier,"calcul"&$test,"Signe du résultat","Nul")
    EndIf
    IniWrite($fichier,"calcul"&$test,"Valeur du résultat",$calcul)
EndFunc

Func _Initialize()
    $onlyOneTest = False
    $test = 1
    $calcul = 0
    $lirePremiereValeurDeX = 0
    $lireDerniereValeurDeX = 0
EndFunc

Bugs ou améliorations ou simple commentaire, faites-les moi savoir !

Merci à TT22 pour m'avoir aider à trouver une stupide erreur qui me bloquait.

PS : C'est peut être pas glorieux comme programme, mais ça change des habitudes !

EDIT : Ajout de la coloration syntaxique, hé oui Tlem, j'ai le droit

Pas mal ton programme

Maintenant, faut le faire avec plusieurs nombres algébriques (x, y, z et T

)

PS : 49.51 secondes de -2000 à 2000

Héhé, merci !

Sinon, pour expliquer la différence de temps, mon processeur, malgré le fait qu'il soit bien cadencé, n'a qu'un coeur

blacksoul305 a écrit :Trouver un moyen de faire comme les calculettes, ça veut dire que 3x = 3*x ou x(4+5) = x*(4+5)

Code : Tout sélectionner

$string = "3x+4(x-8)x+x(x+1)+5(2-6x)"
$string = StringRegExpReplace($string, '([\d\)])(x)', '$1*$2' )
$string = StringRegExpReplace($string, '(x)([\d\(])', '$1*$2' )
$string = StringRegExpReplace($string, '(\d)(\()', '$1*$2' )
Msgbox(0,"", $string)

mikell a écrit :
blacksoul305 a écrit :Trouver un moyen de faire comme les calculettes, ça veut dire que 3x = 3*x ou x(4+5) = x*(4+5)
Code : Tout sélectionner
$string = "3x+4(x-8)x+x(x+1)+5(2-6x)"
$string = StringRegExpReplace($string, '([\d\)])(x)', '$1*$2' )
$string = StringRegExpReplace($string, '(x)([\d\(])', '$1*$2' )
$string = StringRegExpReplace($string, '(\d)(\()', '$1*$2' )
Msgbox(0,"", $string)

Euh, je comprend rien. Je vais travailler dessus plus tard, j'te remercie !

Code : Tout sélectionner

$string = "3x + 4(x-8)x +  x(x+1) + 5(2-6x  )/2x(  x+1)"
[color=#FF0000] ; vire les blancs éventuels :[/color]
$string = StringRegExpReplace($string, '\h', "")
[color=#FF0000] ; remplace x par *x si x précédé par un chiffre ou une parenthèse de fin :[/color]
$string = StringRegExpReplace($string, '([\d\)])x', '$1*x' )  
[color=#FF0000]; remplace x par x* si x précède un chiffre ou une parenthèse de début :[/color]
$string = StringRegExpReplace($string, 'x([\d\(])', 'x*$1' )  
[color=#FF0000] ; remplace 'chiffre' par 'chiffre*' si 'chiffre' précède une parenthèse de début :[/color]
$string = StringRegExpReplace($string, '(\d)(\()', '$1*$2' )  
Msgbox(0,"", $string)

Il faut que tu ajoute un système de solution d'équations

blacksoul305 a écrit :mon processeur, malgré le fait qu'il soit bien cadencé, n'a qu'un coeur

Alors que moi j'ai deux processeurs de 2Ghz

Ce programme est juste fait pour calculer X dans une expression algébrique, d'où le titre du sujet. J'ai pas fais un programme boite à outils regroupant tout les théorèmes etc... Imagine la taille du code après

AutoIt Français

[Ex] Calculer X dans une expression algébrique

[Ex] Calculer X dans une expression algébrique

Re: [Ex] Calculer X dans une expression algébrique

Re: [Ex] Calculer X dans une expression algébrique

Re: [Ex] Calculer X dans une expression algébrique

Re: [Ex] Calculer X dans une expression algébrique

Re: [Ex] Calculer X dans une expression algébrique

Re: [Ex] Calculer X dans une expression algébrique

Re: [Ex] Calculer X dans une expression algébrique