Page 1 sur 1
[EX] Création automatique de menu avec un fichier ini ou txt
Posté : jeu. 02 déc. 2010 08:17
par jl56
Bonjour à tous
j'en avais marre de modifier mes scripts pour incorporer dans le menu le nouvel utilitaire génial qu'un collègue avait trouvé. Du coup j'ai pensé à leur donné la possibilité de gérer eux même cette modif, en éditant un fichier ini
J'ai conçut un code très simple, qui est assez efficace pour me permettre de le mettre en exemple pour vous.
J'utilise le nom de section pour le titre du menu, le nom de la clé pour les éléments de la liste et la valeur pour la ligne de commande à éxécuter.
j'ai documenté le code au max pour la compréhension.
► Afficher le texte
Code : Tout sélectionner
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Menu auto via un fichier ini", 623, 442, 192, 124)
Global $Button1 = GUICtrlCreateButton("quitter", 376, 292, 75, 25)
Global $nbr_section
Global $nbr_cle[20][50];tableau de la valeur ( ligne de commandes à éxecuter )
Global $menu_handle[20][50];tableau des handles
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
_menu(); fonction pour la création du menu
Do;boucle de la gui
$msg = GUIGetMsg()
;~ test du menu sélectionné
For $j = 1 To $nbr_section;boucle des sections
For $i = 1 To $nbr_cle[$j][0]; boucle des clés de la section en cours
If $msg = $menu_handle[$j][$i] Then ; test si c'est ce menu ( handle ) qui est sélectioné
MsgBox(0, "Programme", $nbr_cle[$j][$i]);boite de dialogue pour afficher la ligne de commande test pour vérifier ( ligne à supprimer )
Run($nbr_cle[$j][$i]);exécution de la valeur stocké dans le tableau
EndIf
Next
Next
Until $msg = $GUI_EVENT_CLOSE Or $msg = $Button1
Exit
Func _menu(); fonction pour la création du menu
$var = IniReadSectionNames(@ScriptDir & "\menuauto.ini"); lecture des sections
If @error Then
MsgBox(4096, "", "Il manque le fichier menuauto.ini " & @ScriptDir & "\menuauto.ini")
Else
$nbr_section = $var[0];stokage du nombre de section dans la variable
For $j = 1 To $nbr_section; boucle des sections
$var2 = IniReadSection(@ScriptDir & "\menuauto.ini", $var[$j]);lecture des clés de la section en cours
$menu_handle[$j][0] = GUICtrlCreateMenu($var[$j], -1, 3);création des titres du menu avec le nom de la section et stokage du handle dans le tableau
$nbr_cle[$j][0] = $var2[0][0];stockage de nombre de clé pour la section en cours
For $i = 1 To $var2[0][0]; boucle des clés de la section en cours
$menu_handle[$j][$i] = GUICtrlCreateMenuItem($var2[$i][0], $menu_handle[$j][0]);création de la liste du menu (avec le nom de la clé) de la section en cours plus stockage du handle dans le tableau
$nbr_cle[$j][$i] = $var2[$i][1];stockage dans le tableau de la valeur ( ligne de commande à exécuter )
Next
Next
EndIf
EndFunc ;==>_menu
Créez un fichier menuauto.ini copier cet exemple
► Afficher le texte
Code : Tout sélectionner
[&Utilitaires]
Lancement Malwarebytes=C:\Program Files\Malwarebytes' Anti-Malware\mbam.exe
= le signe égal, sans clé devant, va créer une ligne de séparation dans la liste
&Déframentation=C:\Program Files\MyDefrag v4.3.1\MyDefrag.exe
[&dos]
Command=cmd
[Sites &internet]
Dégrouptest=C:\Program Files\Internet Explorer\IEXPLORE.EXE http://www.degrouptest.com
&GOOGLE=C:\Program Files\Internet Explorer\IEXPLORE.EXE http://www.google.fr
[&Réseau]
Connexion réseau=C:\WINDOWS\system32\rundll32.exe shell32.dll,Control_RunDLL ncpa.cpl
[&System]
Gestion des disques=mmc.exe c:\windows\system32\diskmgmt.msc
Propriété system=C:\WINDOWS\system32\rundll32.exe shell32.dll,Control_RunDLL sysdm.cpl
= le signe égal, sans clé devant, va créer une ligne de séparation dans la liste
Services=mmc.exe c:\windows\system32\services.msc
Observateur d'évènements=mmc.exe c:\windows\system32\eventvwr.msc
Dossiers partagés c:\windows\system32\fsmgmt.msc
Voila je vous laisse tester, merci de vos suggestions
A+ JL56
Re: [EX] Création automatique de menu avec un fichier ini
Posté : jeu. 02 déc. 2010 14:16
par zeshrek
Hé, mais c'est assez génial en fait comme idée !
Le seul truc que j'ai trouvé 'idiot' là dessus c'est qu'il faille se coltiner une GUI. Ca serait tellement mieux si c'était accessible sous forme d'une petite icone dans le systray. Du coup, j'ai fait une petite adaptation, et là ca le fait bien.
► Afficher le texteMon code :
Code : Tout sélectionner
#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=..\..\..\..\Windows\System32\PerfCenterCpl.ico
#AutoIt3Wrapper_Res_Fileversion=1.0.0.0
#AutoIt3Wrapper_Res_LegalCopyright=(c) L'ogre & jl56
#AutoIt3Wrapper_Res_Language=1036
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#cs
TrayMenu
--------
Lanceur d'applications, basé sur le script ' menuauto ' de jl56
Utilisation :
Les menus et commandes a executer sont stockés dans un fichier INI :
- Le nom de section pour le titre du menu
- le nom de la clé pour les éléments de la liste
- la valeur pour la ligne de commande à éxécuter.
Voir le fichier INI d'exemple joint
#ce
#Include <Constants.au3>
Global $nbr_section
Global $nbr_cle[20][50] ; tableau de la valeur ( ligne de commandes à éxecuter )
Global $tray_handle[20][50] ; tableau des handles
HotKeySet("#{ESC}", "_sortie") ; Hotkey permettant de quitter le Traymenu > touches [Windows] + [Escape]
Opt("TrayMenuMode",1) ; Les items par default du tray menu (Script Paused/Exit) ne seront pas affichés.
TraySetState()
TraySetToolTip ("TrayMenu de ouf !") ; Msg d'info quand on amene la souris au dessus de l'icone du TrayMenu
_tray()
While 1 ; Boucle principale qui attend la sélection d'un item
$msg = TrayGetMsg()
For $j = 1 To $nbr_section ; boucle des sections
For $i = 1 To $nbr_cle[$j][0] ; boucle des clés de la section en cours
If $msg = $tray_handle[$j][$i] Then ; test si c'est cet item ( handle ) qui est sélectioné
MsgBox(0, "Programme", $nbr_cle[$j][$i]) ; boite de dialogue pour afficher la ligne de commande test pour vérifier ( ligne à supprimer en utilisation normale)
TrayItemSetState ($tray_handle[$j][$i], $TRAY_UNCHECKED) ; Décochage de l'item (par defaut autoit coche les item sélectionnés)
Run($nbr_cle[$j][$i]) ; exécution de la commande stocké dans le tableau
EndIf
Next
Next
WEnd
Func _tray() ; fonction pour la création du tray
$var = IniReadSectionNames(@ScriptDir & "\menuauto.ini") ; lecture des sections du fichier ini
If @error Then
MsgBox(4096, "", "Il manque le fichier menuauto.ini " & @ScriptDir & "\menuauto.ini")
Else
$nbr_section = $var[0] ; stokage du nombre de section dans la variable
For $j = 1 To $nbr_section ; boucle des sections
$var2 = IniReadSection(@ScriptDir & "\menuauto.ini", $var[$j]) ; lecture des clés de la section en cours
$tray_handle[$j][0] = TrayCreateMenu($var[$j]) ; création des titres du menu avec le nom de la section et stokage du handle dans le tableau
$nbr_cle[$j][0] = $var2[0][0] ; stockage de nombre de clé pour la section en cours
For $i = 1 To $var2[0][0] ; boucle des clés de la section en cours
$tray_handle[$j][$i] = TrayCreateItem($var2[$i][0], $tray_handle[$j][0]) ; création de la liste d'items du menu (avec le nom de la clé) de la section en cours plus stockage du handle dans le tableau
$nbr_cle[$j][$i] = $var2[$i][1] ; stockage dans le tableau de la valeur ( ligne de commande à exécuter )
Next
Next
EndIf
EndFunc
func _sortie()
Exit
EndFunc
Bon, prochaine étape, concurrencer Framakey et U3 !
Re: [EX] Création automatique de menu avec un fichier ini
Posté : jeu. 02 déc. 2010 20:46
par jl56
Bonjour zeshrek
C'est très bien aussi en traymenu
Merci pour votre code cela donne un choix supplémentaire
A+ JL56
Re: [EX] Création automatique de menu avec un fichier ini
Posté : sam. 04 déc. 2010 08:20
par FuriousFred
Bonjour et merci pour cet exemple de script. (Ces exemples en tenant compte de l'adaptation pour le menu tray). J'utilise régulièrement le tray pour mes script perso et grâce à vôtre travail je vais gagner pas mal de temps.
Je souhaiterais savoir s'il y a une option permettant de créer à l'aide du fichier ini un "sous menu" (j'espère être assez explicite) ou serait-ce un to-do pour une amélioration à prévoir?
Encore toutes mes félicitations et merci du partage.
Re: [EX] Création automatique de menu avec un fichier ini ou txt
Posté : dim. 05 déc. 2010 15:37
par jl56
Bonjour à tous
Suite à la remarque de FuriousFred j'ai réfléchie à nouveau sur ce menu automatique
depuis quelques temps j'utilise exclusivement les fichiers ini ( pas de gestion d'ouverture/fermeture de fichier, accés direct à la valeur pour lire ou écrire etc..) J'avais telement galérer à mes débuts de programmeur sous autoit avec des fichiers txt que j'avais abandonné ce format.
Mais la en l'occurrence je ne modifie pas le fichier source via autoit mais simplement n'importe qui peu modifier ce fichier par un éditeur comme notepad, de plus la lecture est séquentiel, donc le format ini ne s'impose plus.
J'ai donc revu ma copie entièrement. Maintenant il est possible de générer des menus avec des sous menus
dans toutes les configurations possible. Le fichier est plus lisible surtout avec des tabulations en début de ligne.
code avec une gui
► Afficher le texte
Code : Tout sélectionner
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Menu auto via un fichier txt par JL56", 623, 442, 192, 124)
Global $Button1 = GUICtrlCreateButton("quitter", 376, 292, 75, 25)
Global $nbr_element_du_menu = 0, $branche[10], $numero_de_branche = 0
Global $menu_handle_et_valeur[300][2];tableau des handles et ligne de commande
#cs
Lanceur d'applications, de jl56
Utilisation :
Les menus et commandes a executer sont stockés dans un fichier TXT :
au debut de la ligne
un "m=Nom de menu=n° de branche du menu" signifie un nouveau menu avec son nom et position de la branche (0=départ de la branche 1)
un "e=Nom de l'élément=ligne de commande" est un élément de la liste et la ligne de commande
si il n'y a pas de nom présent alors insertion d'un séparateur
si une ligne n'a pas 2 signes = elle n'est pas prise en compte ( utile pour mettre un commentaire ( sans 2 signes = ) ou separarer des blocs par des lignes blanches)
et enfin le mot fin donne l'arret de la lecture du fichier
J'ai paramétré la possibilité d'avoir 300 éléments et 10 niveaux de menu
il n'y a pas de gestion d'erreur (format de la ligne, n° de branche etc ) soyer précis ( 2 signes = par ligne )
#ce
;exemple: ( à copier dans un fichier menuauto.txt supprimer le ; en début de ligne )
; en début de ligne m génére le un nouveau menu. n'oublier pas de placer un signe = aprés le nom de ce menu
; chaque ligne du menu doit avoir 2 signes = et commencer par e ou m
; ensuite l'aboresence respecte le nombre de caractere devant m ou e, le mieux est d'utiliser des tabulations
; cela rend une lecture quasi direct du menu générer.
;
;m=Premier menu=
;
; les éléments de liste déroulante ne sont jamais en début de ligne
;
; e=e1 m1=lc 1 de m1
; e=e2 de m1=lc 2 de m1
; un élément sans nom ajoutera une ligne de séparation dans le menu
; e==
; e=e3 m1=lc 3 de m1
; e==
;
; ici une tabulation suivie de m génère un sous menu de la branche précédente
; m=Sous menu 1 de m1=
;
; on décale les éléments d'une tabulation supplémentaires on vois clairement ci-dessous que e1 e2 et (sm1 de sm1 de m1) font partie de (Sous menu 1 de m1)
;
; e=e1 de Sm1 de m1=lc 1 de Sm1 m1
; e=e2 de Sm1 de m1=lc 2 de Sm1 m1
;
; m=Sm1 de Sm1 de m1=
; e=e1 de Sm1 de Sm1 de m1=lc1 de Sm1 de Sm1 de menu1
;
; m=Sous menu 2 de m1=
; e=e1 de sm2 de m1=lc1 de sm2 de m1
; e=e1 de sm1 de m1=lc1 de sm1 de m1
;
; e=e4 de m1=lc4 de m1
;
; Départ du menu 2
;
;m=Deuxieme menu=
; e=e1 de deuxieme menu=lc1 de deuxieme menu
; arret de la lecture du fichier
;fin
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
_menu() ; fonction pour la création du menu
Do ;boucle de la gui
$msg = GUIGetMsg()
;~ test du menu selectionné
For $i = 1 To $nbr_element_du_menu ; boucle sur le nombre d'élément
If $msg = $menu_handle_et_valeur[$i][0] Then ; test si c'est ce menu ( handle ) qui est sélectioné
MsgBox(0, "Programme", $menu_handle_et_valeur[$i][1]) ;boite de dialogue pour afficher la ligne de commande test pour vérifier ( ligne à supprimer )
Run($menu_handle_et_valeur[$i][1]) ;éxecution de la valeur stocké dans le tableau
EndIf
Next
Until $msg = $GUI_EVENT_CLOSE Or $msg = $Button1
Exit
Func _menu() ; fonction pour la création du menu
$file = FileOpen(@ScriptDir & "\menuauto.txt", 0)
If $file = -1 Then
MsgBox(4096, "", "Il manque le fichier menuauto.txt " & @ScriptDir & "\menuauto.txt", 50)
FileClose($file)
Exit
Else
While 1
$ligne = FileReadLine($file) ;lecture séquenciel du fichier
If @error = -1 Then ExitLoop
If StringLeft($ligne, 3) = "fin" Then ExitLoop ; arret de la boucle avec le mot fin
If StringInStr($ligne, "=", 0, 2) Then ;si la ligne contient 2 signes = ont poursuit le code sinon ligne suivante
$element = StringSplit($ligne, "=") ;decoupage de ligne en trois morceaux (séparés par =)
;~ If Not IsArray($element) Then ExitLoop ;vérification du decoupage
If StringRight($element[1], 1) = "m" Then ;si le premier morceau est m alors
$numero_de_branche = StringLen(StringTrimRight($element[1], 1));comptage du nombre de caratére ( tabulation, espace) devant m
If $numero_de_branche = 0 Then ;si c'est la 1er branche (0 lu dans le 3 emm morceau ) creation du menu
$branche[0] = GUICtrlCreateMenu($element[2]) ;création du menu ( avec le nom stocké dans le 2 emm morceau) et stockage du handle dans le tableau $branche [1]
Else ;si la branche <> de 0
$branche[$numero_de_branche] = GUICtrlCreateMenu($element[2], $branche[$numero_de_branche - 1]);Création du sous menu de la branche précédente et stockage du handle dans le tableau $branche [x]
EndIf
EndIf
If StringRight($element[1], 1) = "e" Then ;si le 1er morceau est e alors
$numero_de_branche = StringLen(StringTrimRight($element[1], 1)) - 1;comptage du nombre de caratére ( tabulation, espace) devant e
If $numero_de_branche >= 0 Then; un élément doit toujours faire partie d'une branche soit au minimum 0 car le ligne précédent soutrait 1
$nbr_element_du_menu = $nbr_element_du_menu + 1 ; incrémentation du nombre d'élément
$menu_handle_et_valeur[$nbr_element_du_menu][0] = GUICtrlCreateMenuItem($element[2], $branche[$numero_de_branche]);Création de l'élément et stockage du handle dans le tableau
$menu_handle_et_valeur[$nbr_element_du_menu][1] = $element[3] ;stockage de la ligne de commande dans le tableau
EndIf
EndIf
EndIf
WEnd
FileClose($file)
EndIf
EndFunc ;==>_menu
Code avec menu tray merci à zeshrek
► Afficher le texte
Code : Tout sélectionner
#NoTrayIcon
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
Global $nbr_element_du_menu = 0, $branche[10], $numero_de_branche = 0
Global $menu_handle_et_valeur[200][2];tableau des handles et ligne de commande
HotKeySet("#{ESC}", "_sortie") ; Hotkey permettant de quitter le Traymenu > touches [Windows] + [Escape]
Opt("TrayMenuMode", 1) ; Les items par default du tray menu (Script Paused/Exit) ne seront pas affichés.
TraySetState()
TraySetToolTip("Lanceur d'application de JL56 et zeshrek") ; Msg d'info quand on amene la souris au dessus de l'icone du TrayMenu
#cs
Lanceur d'applications, de jl56 et zeshrek (pour la partie menu tray)
Utilisation :
Les menus et commandes a executer sont stockés dans un fichier TXT :
au debut de la ligne
un "m=Nom de menu=n° de branche du menu" signifie un nouveau menu avec son nom et position de la branche (0=départ de la branche 1)
un "e=Nom de l'élément=ligne de commande" est un élément de la liste et la ligne de commande
si il n'y a pas de nom présent alors insertion d'un séparateur
si une ligne n'a pas 2 signes = elle n'est pas prise en compte ( utile pour mettre un commentaire ( sans 2 signes = ) ou separarer des blocs par des lignes blanches)
et enfin le mot fin donne l'arret de la lecture du fichier
J'ai paramétré la possibilité d'avoir 300 éléments et 10 niveaux de menu
il n'y a pas de gestion d'erreur (format de la ligne, n° de branche etc ) soyer précis ( 2 signes = par ligne )
#ce
;exemple: ( à copier dans un fichier menuauto.txt supprimer le ; en début de ligne )
; en début de ligne m génére le un nouveau menu. n'oublier pas de placer un signe = aprés le nom de ce menu
; chaque ligne du menu doit avoir 2 signes = et commencer par e ou m
; ensuite l'aboresence respecte le nombre de caractere devant m ou e, le mieux est d'utiliser des tabulations
; cela rend une lecture quasi direct du menu générer.
;
;m=Premier menu=
;
; les éléments de liste déroulante ne sont jamais en début de ligne
;
; e=e1 m1=lc 1 de m1
; e=e2 de m1=lc 2 de m1
; un élément sans nom ajoutera une ligne de séparation dans le menu
; e==
; e=e3 m1=lc 3 de m1
; e==
;
; ici une tabulation suivie de m génère un sous menu de la branche précédente
; m=Sous menu 1 de m1=
;
; on décale les éléments d'une tabulation supplémentaires on vois clairement ci-dessous que e1 e2 et (sm1 de sm1 de m1) font partie de (Sous menu 1 de m1)
;
; e=e1 de Sm1 de m1=lc 1 de Sm1 m1
; e=e2 de Sm1 de m1=lc 2 de Sm1 m1
;
; m=Sm1 de Sm1 de m1=
; e=e1 de Sm1 de Sm1 de m1=lc1 de Sm1 de Sm1 de menu1
;
; m=Sous menu 2 de m1=
; e=e1 de sm2 de m1=lc1 de sm2 de m1
; e=e1 de sm1 de m1=lc1 de sm1 de m1
;
; e=e4 de m1=lc4 de m1
;
; Départ du menu 2
;
;m=Deuxieme menu=
; e=e1 de deuxieme menu=lc1 de deuxieme menu
; arret de la lecture du fichier
;fin
_tray() ; fonction pour la création du menu
While 1 ; Boucle principale qui attend la sélection d'un item
$msg = TrayGetMsg()
;~ test du menu selectionné
For $i = 1 To $nbr_element_du_menu ; boucle sur le nombre d'élément
If $msg = $menu_handle_et_valeur[$i][0] Then ; test si c'est ce menu ( handle ) qui est sélectioné
MsgBox(0, "Programme", $menu_handle_et_valeur[$i][1]) ;boite de dialogue pour afficher la ligne de commande test pour vérifier ( ligne à supprimer )
TrayItemSetState($menu_handle_et_valeur[$i][1], $TRAY_UNCHECKED) ; Décochage de l'item (par defaut autoit coche les item sélectionnés)
Run($menu_handle_et_valeur[$i][1]) ;éxecution de la valeur stocké dans le tableau
EndIf
Next
WEnd
Exit
Func _tray() ; fonction pour la création du menu
$file = FileOpen(@ScriptDir & "\menuauto.txt", 0)
If $file = -1 Then
MsgBox(4096, "", "Il manque le fichier menuauto.txt " & @ScriptDir & "\menuauto.txt", 50)
FileClose($file)
Exit
Else
While 1
$ligne = FileReadLine($file) ;lecture séquenciel du fichier
If @error = -1 Then ExitLoop
If StringLeft($ligne, 3) = "fin" Then ExitLoop ; arret de la boucle avec le mot fin
If StringInStr($ligne, "=", 0, 2) Then ;si la ligne contient 2 signes = ont poursuit le code sinon ligne suivante
$element = StringSplit($ligne, "=") ;decoupage de ligne en trois morceaux (séparés par =)
;~ If Not IsArray($element) Then ExitLoop ;vérification du decoupage
If StringRight($element[1], 1) = "m" Then ;si le premier morceau est m alors
$numero_de_branche = StringLen(StringTrimRight($element[1], 1));comptage du nombre de caratére ( tabulation, espace) devant m
If $numero_de_branche = 0 Then ;si c'est la 1er branche (0 lu dans le 3 emm morceau ) creation du menu
$branche[0] = TrayCreateMenu($element[2]) ;création du menu ( avec le nom stocké dans le 2 emm morceau) et stockage du handle dans le tableau $branche [1]
Else ;si la branche <> de 0
$branche[$numero_de_branche] = TrayCreateMenu($element[2], $branche[$numero_de_branche - 1]);Création du sous menu de la branche précédente et stockage du handle dans le tableau $branche [x]
EndIf
EndIf
If StringRight($element[1], 1) = "e" Then ;si le 1er morceau est e alors
$numero_de_branche = StringLen(StringTrimRight($element[1], 1)) - 1;comptage du nombre de caratére ( tabulation, espace) devant e
If $numero_de_branche >= 0 Then; un élément doit toujours faire partie d'une branche soit au minimum 0 car le ligne précédent soutrait 1
$nbr_element_du_menu = $nbr_element_du_menu + 1 ; incrémentation du nombre d'élément
$menu_handle_et_valeur[$nbr_element_du_menu][0] = TrayCreateItem($element[2], $branche[$numero_de_branche]);Création de l'élément et stockage du handle dans le tableau
$menu_handle_et_valeur[$nbr_element_du_menu][1] = $element[3] ;stockage de la ligne de commande dans le tableau
EndIf
EndIf
EndIf
WEnd
FileClose($file)
EndIf
EndFunc ;==>_tray
Func _sortie()
Exit
EndFunc ;==>_sortie
exemple d'un fichier menuauto.txt en téléchargement ci-joint
Voila je vous laisse tester, merci de vos suggestions
A+ JL56
Re: [EX] Création automatique de menu avec un fichier txt
Posté : dim. 05 déc. 2010 16:03
par jl56
Bonjour à tous
Je viens à nouveau de modifier mon code pour qu'il interprète directement la représentation d'une arborescence (via les tabulations) dans le fichier menuauto.txt.
C'est assez bluffant j'aurais du y penser plutôt.
Du coup le fichier est très lisible et très facilement modifiable par n'importe qui avec par ex. notepad
on peut générer, des menus, sous menu dans toutes les configurations possibles, ainsi que l'ajout de commentaire.
c'est mes collègues qui vont devoir bosser maintenant
tous est dans le post précédent
A+ JL56
ps: je laisse le 1er post avec l'utilisation d'un fichier ini au cas ou mais si les modérateurs veulent faire le ménage
ils peuvent supprimer tous les posts avant le précédent merci
Re: [EX] Création automatique de menu avec un fichier ini ou txt
Posté : lun. 06 déc. 2010 12:03
par ricky
Hello,
je trouve pas mal et bien vu. Je préfère la version avec le ini (j'aime bien les fichiers ini)...
Pour tes collègues, pourquoi ne pas mettre un bouton exit dans le tray? Ça serait plus facile pour eux...
Je le garde dans un coin, merci pour le partage
Re: [EX] Création automatique de menu avec un fichier ini ou
Posté : dim. 09 oct. 2011 21:14
par leoclem
Sympa !
C'est vraiment un scriptlet bien utile.
Merci à jl56 et zeshrek !
Re: [EX] Création automatique de menu avec un fichier ini ou
Posté : ven. 02 déc. 2011 15:36
par DimVar
T'ain !
Et dire que je m'emmerde à installer des dock/gadgets/widget de **** pour avoir mes outils systeme sous la main !
A.DO.PTé !
Merci à toi.
