AutoIt Français

Voila, je me suis rendu compte que je demandais beaucoup d'aide sans pour autant partager énormément,
c'est pourquoi je post ici un petit UDF que je viens de "finir" (il reste quelques améliorations à faire, mais il est fonctionnel)

J'ai créé un testeur pour pouvoir voir directement ce que propose l UDF ^^

Have Fun.

Edit : J'ajoute l'outil pour créer ses propre caracteres
Utilisation : appuyez sur 0 et 1 (Pavé numérique) pour "allumer" ou non un pixel

► Afficher le texteUDF

Code : Tout sélectionner

Dim $Alphabet[27] = ["011111001100011011000110110001101100011011111110110001101100011011000110", "111111001100011011000110110001101111110011000110110001101100011011111100", "011111001100011011000000110000001100000011000000110000001100011001111100", "111111001100011011000110110001101100011011000110110001101100011011111100", "111111101100000011000000110000001111100011000000110000001100000011111110", "111111001100000011000000110000001111100011000000110000001100000011000000", "011111001100011011000000110000001100000011001110110001101100011001111100", "110001101100011011000110110001101111111011000110110001101100011011000110", "000110000001100000011000000110000001100000011000000110000001100000011000", "111111100001100000011000000110000001100000011000000110000001100011110000", "110001101100011011000110110011001111100011001100110001101100011011000110", "110000001100000011000000110000001100000011000000110000001100000011111110", "110001101110111011111110110101101100011011000110110001101100011011000110", "110001101100011011100110111101101111111011011110110011101100011011000110", "011111001100011011000110110001101100011011000110110001101100011001111100", "111111001100011011000110110001101100011011111100110000001100000011000000", "011111001100011011000110110001101100011011000110110011100111110000000110", "111111001100011011000110110001101111110011001100110001101100011011000110", "011111101100000011000000110000000111110000000110000001100000011011111100", "111111100011000000110000001100000011000000110000001100000011000000110000", "110001101100011011000110110001101100011011000110110001101100011001111100", "110001101100011011000110110001101100011011000110011011000011100000010000", "110001101100011011000110110001101100011011010110111111101110111011000110", "110001101100011011000110011011000011100001101100110001101100011011000110", "110001101100011011000110110001100111111000000110000001100000011001111100", "111111100000011000001100000110000011000001100000110000001100000011111110", "000000000000000000000000000000000000000000000000000000000000000000000000"]
Dim $Cases[9][7]
Dim $Casess[9][7]
Dim $CouleurTexte = 0xA00000
Dim $CouleurFond = 0x002000
Dim $Texte = ""
Dim $Position = 0
Dim $NbCaracteresX = 0
Dim $RandMin = 0
Dim $RandMax = 0
Dim $TempsDelai = 100
Dim $TaillePix[2] = [5, 5]
Dim $EspacementPix[2] = [2, 2]
Dim $EtatClignotement = False
Dim $Defiler = False
Dim $Clignoter = False

;===============================================================================
; Nom:   CreerPanneau()
; Description:      Créé un panneau d'affichage (style tram)
; Paramètres:      $TexteParam         : Texte afficher par le panneau
;                   $PosX               : Position dans la fenêtre (abscisse)
;                   $PosY               : Position dans la fenêtre (ordonnée)
;                   $NbCaracteresXParam : Taille du panneau (en nombre de caractères)
;                   $Delai              : Temps d'attente entre chaque mouvements du texte
;                   $TaillePixX         : Taille d'un pixel d'affichage (abscisse)
;                   $TaillePixY         : Taille d'un pixel d'affichage (ordonnée)
;                   $EspacementX        : Taille de l'espacement entre 2 pixels d'affichage (abscisse)
;                   $EspacementY        : Taille de l'espacement entre 2 pixels d'affichage (ordonnée)
; Auteur:       TommyDDR
;===============================================================================
Func CreerPanneau($TexteParam, $PosX, $PosY, $NbCaracteresXParam, $TextCouleur = 0x00A000, $FondCouleur = 0x002000, $Delai = 100, $TaillePixX = 5, $TaillePixY = 5, $EspacementX = 2, $EspacementY = 2)
    If($TextCouleur = -1) Then
        $CouleurTexte = 0x00A000
    Else
        $CouleurTexte = $TextCouleur
    EndIf
    If($FondCouleur = -1) Then
        $CouleurFond = 0x002000
    Else
        $CouleurFond = $FondCouleur
    EndIf
    If($Delai = -1) Then
        $TempsDelai = 100
    Else
        $TempsDelai = $Delai
    EndIf
    If($TaillePixX = -1) Then
        $TaillePix[0] = 5
    Else
        $TaillePix[0] = $TaillePixX
    EndIf
    If($TaillePixY = -1) Then
        $TaillePix[1] = 5
    Else
        $TaillePix[1] = $TaillePixY
    EndIf
    If($EspacementX = -1) Then
        $EspacementPix[0] = 2
    Else
        $EspacementPix[0] = $EspacementX
    EndIf
    If($EspacementY = -1) Then
        $EspacementPix[1] = 2
    Else
        $EspacementPix[1] = $EspacementY
    EndIf

    $TaillePix[0] = $TaillePixX
    $TaillePix[1] = $TaillePixY
    $EspacementPix[0] = $EspacementX
    $EspacementPix[1] = $EspacementY
    $NbCaracteresX = $NbCaracteresXParam
    ReDim $Cases[9][$NbCaracteresX*8]
    ReDim $Casess[9][$NbCaracteresX*8]
    Panneau_Set_Text($TexteParam)
    $Position = $NbCaracteresX*8
    For $i = 0 To ($NbCaracteresX*8)-1
        For $j = 0 To 8
            $Cases[$j][$i] = GUICtrlCreateLabel("", $PosX+$i*($TaillePix[0] + $EspacementPix[0])+Random($RandMin, $RandMax, 1), $PosY+$j*($TaillePix[1] + $EspacementPix[1])+Random($RandMin, $RandMax, 1), $TaillePix[0], $TaillePix[1])
            $Casess[$j][$i] = 0
            GUICtrlSetBkColor(-1, $CouleurFond)
        Next
    Next
    $Defiler = True
    DemarrerDefilement()
EndFunc

;===============================================================================
; Nom:   ChangerDefilement()
; Description:  Arrête / relance le défilement du texte
; Auteur:       TommyDDR
;===============================================================================
Func ChangerDefilement()
    $Defiler = Not $Defiler
    If($Defiler) Then
        DemarrerDefilement()
    Else
        StoperDefilement()
    EndIf
EndFunc

;===============================================================================
; Nom:   DemarrerDefilement()
; Description:  Lance le défilement du texte
; Auteur:       TommyDDR
;===============================================================================
Func DemarrerDefilement()
    AdlibRegister("FaireDefiler", $TempsDelai)
EndFunc

;===============================================================================
; Nom:   StoperDefilement()
; Description:  Arrête le défilement du texte
; Auteur:       TommyDDR
;===============================================================================
Func StoperDefilement()
    AdlibUnRegister("FaireDefiler")
EndFunc

;===============================================================================
; Nom:   ChangerClignotement()
; Description:  Arrête / relance le clignotement du texte
; Auteur:       TommyDDR
;===============================================================================
Func ChangerClignotement()
    $Clignoter = Not $Clignoter
    If($Clignoter) Then
        DemarrerClignotement()
    Else
        StoperClignotement()
    EndIf
EndFunc

;===============================================================================
; Nom:   DemarrerClignotement()
; Description:  Lance le clignotement du texte
; Auteur:       TommyDDR
;===============================================================================
Func DemarrerClignotement()
    StoperDefilement()
    AdlibRegister("FaireClignoter", 200)
EndFunc

;===============================================================================
; Nom:   StoperClignotement()
; Description:  Arrête le clignotement du texte
; Auteur:       TommyDDR
;===============================================================================
Func StoperClignotement()
    AdlibUnRegister("FaireClignoter")
    If($EtatClignotement) Then
        FaireClignoter()
    EndIf
    If($Defiler) Then
        DemarrerDefilement()
    EndIf
EndFunc

;===============================================================================
; Nom:   FaireClignoter()
; Description:  Fait clignoter le texte
; Auteur:       TommyDDR
;===============================================================================
Func FaireClignoter()
    If($EtatClignotement) Then
        For $i = 0 To ($NbCaracteresX*8)-1
            For $j = 0 To 8
                If($Casess[$j][$i] <> 0) Then
                    GUICtrlSetBkColor($Cases[$j][$i], $CouleurTexte)
                EndIf
            Next
        Next
    Else
        For $i = 0 To ($NbCaracteresX*8)-1
            For $j = 0 To 8
                If($Casess[$j][$i] <> 0) Then
                    GUICtrlSetBkColor($Cases[$j][$i], $CouleurFond)
                EndIf
            Next
        Next
    EndIf
    $EtatClignotement = Not $EtatClignotement
EndFunc

;===============================================================================
; Nom:   FaireDefiler()
; Description:  Fait défiler le texte
; Auteur:       TommyDDR
;===============================================================================
Func FaireDefiler()
    StoperDefilement()
    Local $Start = 0
    Local $NumeroLettre = ""
    Local $Police = ""
    Local $Couleur = ""
    Local $var = ""
    Local $Decalage = 0
    $Position -= 1
    If($Position < -(StringLen($Texte)*8)) Then
        $Position = $NbCaracteresX*8
    EndIf
    $Start = $Position
    If($Position < 0) Then
        $Start = 0
        $Decalage = Mod(Abs($Position), 8)
    EndIf
    If($Position >= 0) Then
        $NumeroLettre = 1
        $Decalage = 0
    Else
        $NumeroLettre = Int((Abs($Position))/8)+1
    EndIf
    $Lettre = Asc(StringMid($Texte, $NumeroLettre, 1))-65
    If(Not($Lettre >= 0 And $Lettre < 26)) Then
        $Lettre = 26
    EndIf
    $Police = $Alphabet[$Lettre]
    For $i = $Start To ($NbCaracteresX*8)-1
        If(Mod(($i-$Start+1+$Decalage), 8) = 0) Then
            $NumeroLettre += 1
            $Lettre = Asc(StringMid($Texte, $NumeroLettre, 1))-65
            If(Not($Lettre >= 0 And $Lettre < 26)) Then
                $Lettre = 26
            EndIf
            $Police = $Alphabet[$Lettre]
        EndIf
        If($Lettre <= 26 And $Lettre >= 0) Then
            For $j = 0 To 8
                $Couleur = StringMid($Police, $j*8+1+Mod($i-$Start+$Decalage, 8), 1)
                If($Couleur = 0 And $Casess[$j][$i] = 1) Then
                    GUICtrlSetBkColor($Cases[$j][$i], $CouleurFond)
                    $Casess[$j][$i] = 0
                ElseIf($Couleur = 1 And $Casess[$j][$i] = 0) Then
                    GUICtrlSetBkColor($Cases[$j][$i], $CouleurTexte)
                    $Casess[$j][$i] = 1
                EndIf
            Next
        EndIf
    Next
    If($Defiler And Not $Clignoter) Then
        DemarrerDefilement()
    EndIf
EndFunc

;===============================================================================
; Nom:   Panneau_Set_Text()
; Description:  Change le texte affiché
; Auteur:       TommyDDR
;===============================================================================
Func Panneau_Set_Text($NewTxt)
    If($Defiler) Then
        StoperDefilement()
    EndIf
    $NewTxt = StringUpper($NewTxt)
    $Texte = $NewTxt
    For $i = 0 To ($NbCaracteresX*8)-1
        For $j = 0 To 8
            If($Casess[$j][$i] <> 0) Then
                GUICtrlSetBkColor($Cases[$j][$i], $CouleurFond)
                $Casess[$j][$i] = 0
            EndIf
        Next
    Next
    If($Defiler) Then
        DemarrerDefilement()
    EndIf
EndFunc

► Afficher le textetesteur

► Afficher le texteEdit :Caligraphie

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <misc.au3>
Opt("GUIOnEventMode", 1)

Dim $Gui
Dim $Cases[9][7]
Dim $Casess[9][7]

$Gui = GUICreate("Créer Caracteres", 60, 80)
GUISetBkColor(0x000000)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")
CreerPanneau("", 5, 5, 1)
GUISetState()

While(True)
    For $j = 0 To 8
        For $i = 0 To 6
            Do
                Sleep(10)
            Until(_IsPressed("60") Or _IsPressed("61") Or _IsPressed("DE"))
            If(_IsPressed("DE")) Then
                Exit
            ElseIf(_IsPressed("60")) Then
                $Couleur = 0
            Else
                $Couleur = 1
            EndIf
            Do
                Sleep(10)
            Until(Not(_IsPressed("60") Or _IsPressed("61") Or _IsPressed("DE")))
            If($Couleur = 0) Then
                GUICtrlSetBkColor($Cases[$j][$i], 0x001000)
            Else
                GUICtrlSetBkColor($Cases[$j][$i], 0x008000)
            EndIf
            $Casess[$j][$i] = $Couleur
        Next
    Next
    If(MsgBox(4, "Résultat", "Satisfait ?") = 6) Then
        $file = FileOpen("Test.txt", 1)
        FileWrite($file, ", """)
        For $j = 0 To 8
            For $i = 0 To 6
                FileWrite($file, $Casess[$j][$i])

            Next
        Next
        FileWrite($file, """")
        FileClose($file)
    EndIf
    For $j = 0 To 8
        For $i = 0 To 6
            GUICtrlSetBkColor($Cases[$j][$i], 0xFF0000)
        Next
    Next
WEnd

Func quit()
    Exit
EndFunc

Func CreerPanneau($Texte, $X, $Y, $NbCaracteresX)
    For $j = 0 To 8
        For $i = 0 To ($NbCaracteresX*7)-1
            $Cases[$j][$i] = GUICtrlCreateLabel("", $X+$i*7, $Y+$j*7, 5, 5)
            GUICtrlSetBkColor(-1, 0xFF0000)
        Next
    Next
EndFunc

Pas mal du tout, bon partage, merci à toi

trop fort thx

Vraiment sympa ce script .

Bravo !!!

Haha c'est génial

Sympa.

Petite remarque : L'utilisation de Case au lieu d'une suite de condition If améliorerait grandement le code en clarté et en rapidité.

Fonctions : CreerPanneau et FaireDefiler.

Un code de ce genre :

Code : Tout sélectionner

    $Var  = Not $Var
    If($Var) Then

Peut être réduit à :

Code : Tout sélectionner

    If Not $Clignoter Then

Merci pour votre partage.

Absolument génial!
Surtout avec une fenêtre sans bordure!

Merci pour le code

J'adore, c'est excellent

Koumla

Super ce code va servir a beaucoup de gens .

seul inconvénient cela ne fonctionne pas avec les chifre

Héhé si tu veux le faire fonctionner avec les chiffre tu peux le faire toi même, mais à toi de les dessiner avec les pointillés (1000110101010....)

la première lettre de la liste
Dim $Alphabet[27] = ["011111001100011011000110110001101100011011111110110001101100011011000110",

lettre A

0111110 0
1100011 0
1100011 0
1100011 0
1100011 0
1111111 0
1100011 0
1100011 0
1100011 0

taille 7x9

A faire sur feuille petit carreau et suivre l’exemple
A chaque ligne il y a un zéro en plus

Koumla

Je vous met a disposition un outils que j'ai fait pour créer ces caracteres.

J'UP mon 1er post.

Alors la ! Tip top woualou !

Très sympa comme script/UDF.

Comme je débute totalement dans le domaine de la programmation, veuillez bien pardonner mes remarques suivantes si elles sont absurdes.

1. L'éditeur de caractère fonctionne sauf qu'il ne génère pas le nombre de pixels suffisant pour qu'il s'affiche correctement. Par exemple, le nombre total de pixels des lettres intégrées dans CreerPanneau.au3 est de 72. Or l'éditeur génère des caractères d'une longueur de 63 pixels seulement.

Ensuite, toujours à propos de l'éditeur, ce serait bien de pouvoir corriger avec la touche <BackSpace> qui recolorerait la case précédente en rouge. Mais c'est sans doute plus simple à dire qu'à faire. Déjà que j'ai pas encore le niveau pour comprendre toutes les subtilités du script fourni.

2. Une fois qu'on a généré nos caractères, les chiffres par exemple, comment les ajoute-t-on au script pour qu'il soit pris en compte à l'appui des touches du pavé numérique ou des touches numériques en haut des claviers (pour les laptop).

Par exemple, le 1:

0011100 0
0011100 0
0111100 0
0011100 0
0011100 0
0011100 0
0011100 0
0011100 0
0111110 0

donne le code "001110000011100001111000001110000011100000111000001110000011100001111100" qu'il m'a semblé logique d'ajouter à Dim $Alphabet[27] que je modifie en Dim $Alphabet[28]
.
Mais après, je sèche car je ne comprends pas comment le script récupère les lettres entrées dans l'InputBox de l'exemple pour les associer à leur correspondance listée dans le tableau $Alphabet qui, d'après ce que je constate, liste les lettres dans l'ordre alphabétique finissant par <espace> tel que [A-Z\s] en regex.

J'ai besoin de vos lumière. Ça m'aidera pas mal pour la suite de ma compréhension des langages informatiques et de l'AutoIt en particulier.

C'est sympa comme tout. Merci pour ce partage

vraiment cool le code

Bonjour,
je débute sur ce langage et je trouve ce code vraiment sympa.
@ FredMea, il faut aussi changer tous les "26" dans le code par "27" et pour faire apparaitre ton chiffre,tu dois taper "[" qui est le code ascii qui suit le "Z"
Pour le moment je n'ai pu valider que 6 chiffres (les codes ascii se trouvant entre le "Z" et le "a".

Chocapic69

Excellent

Voici une version qui gère les chiffres mais plus les minuscules.

Chocapic69

Bonjour,
j'ai bien regardé les scripts et j'ai fait quelques modifications.

je joints plusieurs fichiers:
"monTesteurPanneau.au3" qui permet de tester le panneau
"monCreerPanneau.au3" qui gère les caractères du code ascii 32 à 126.
"mon Texte to image.au3" qui m'a permis de créer la liste des codes "1001001000...."
"Test_Ok.txt" qui est le résultat obtenu automatiquement avec "mon Texte to image.au3"
"apple.zip" qui est une police windows que j'ai trouvé en libre service et qui est utilisée par "mon Texte to image.au3"

petites remarques :
les fonctions AdlibEnable et AdlibDesable sont à remplacer par AdlibRegister et AdlibUnregister en fonction de la version de Autoit.
Pour ce qui est de "mon Texte to image.au3" :
[img]

[/img]
le bouton "Dessin manuel" permet de dessiner l'image du texte dans la fenêtre de gauche.
le bouton "dessin automatique" permet de dessiner de façon automatique les caractères ascii de 32 à 126.
le bouton "Ok" enregistre le dessin de la fenêtre de droite qu'on peut modifier avec la souris en allumant ou éteignant les cases par un click sur chaque case.

Voili voila, j'espère que ça est bien....

AutoIt Français

[Ex] Créer un panneau d'affichage (comme dans les trams ^^)

[Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)

Re: [Ex] Créer un panneau d'affichage (comme dans les trams ^^)