AutoIt Français

Bonjour

J'ai voulu plusieurs fois répondre sur le forum sur l'utilisation de IE.au3.

Donc pour tester les <> codes à créer, j'avais besoin d'un petit espace de test donc je vous propose ce script pour vous aider.

► Afficher le texteVoir le code

Toute idées bienvenues. On peut également mettre ici des exemples.

Chris

Bonjour,

je viens de tester plusieurs méthodes pour poster 1 ou plusieurs fichiers sur un serveur web, dans ce petit navigateur et j'en ai une qui fonctionne bien.

Comment effectuer ce test ?
1/ installé un serveur web, j'utilise un ultralight, opensource, 0 conf, ZMWS diponible ici http://www.zmws.com/
je le fais tourner sur ma clef USB, avec MySQL et PHP 5
2 créer un page php pour obtenir les fichiers uploader
Créer un dossier upload dans H:\ZMWS\_web.zmwsc\Test\
H:\ZMWS\_web.zmwsc\Test\post_files.php

Code : Tout sélectionner

<?php
echo("\$_POST<pre>" . print_r($_POST, true) . "</pre>");
echo("\$_FILES<pre>" . print_r($_FILES, true) . "</pre><hr />");

if (isset($_FILES)) {
    $target_path = "upload/";
    echo("Upload dir=" . realpath($target_path) . "<br />" . "<br />");
    foreach ($_FILES as $key => $file) {
        echo($key . "<br />");
        echo("<pre>" . print_r($file, true) . "</pre>");
        
        move_uploaded_file($file["tmp_name"], $target_path . basename($file["name"]));
        
        $targeturl = "http://" . $_SERVER['SERVER_NAME'] . "/test/" . $target_path;
        echo("<a href=\"" . $targeturl . basename($file["name"]) . "\">" . basename($file["name"]) . "</a><br />");
    }
}
?>

Ainsi tous les fichiers uploader se retrouvent dans H:\ZMWS\_web.zmwsc\Test\Upload

La partie AutoIt qui envoi une capture d'écran en JPG ainsi que la date et un commentaire.
On fera par la suite une interface graphique pour une utilisation plus souple, mais ici c'est le principe que je voulais exposer.

Code : Tout sélectionner

Func _Post_File()
    Local $URL = _WinHttpCrackUrl("http://localhost/test/post_files.php")
    Local $hOpen = _WinHttpOpen()
    Local $hConnect = _WinHTTPConnect($hOpen, $URL[2], $URL[3])
    Local $hRequest = _WinHttpOpenRequest($hConnect, "POST", $URL[6] & $URL[7], "HTTP/1.1", "http://" & $URL[2])


    Local $form_fields[2][2] = [["Date", _Now()],["commentaire", "Plein de gros test & é a ê î è"]]
    
    _ScreenCapture_Capture("capture.jpg", 100, 100, 400, 500, False)
    Local $form_files[1][2] = [["capture", "capture.jpg"]]
    
    
    Local $FormDatas = Encode_MultiPart_FormData($form_fields, $form_files)
    Local $content_type = 'Content-Type: ' & $FormDatas[0] & @CRLF
    _WinHttpSendRequest($hRequest, $content_type, $WINHTTP_NO_REQUEST_DATA, StringLen($FormDatas[1]))
    _WinHTTPWriteData($hRequest, StringToBinary($FormDatas[1]), 1)

    _WinHttpReceiveResponse($hRequest)
    Local $html = ""
    If _WinHttpQueryDataAvailable($hRequest) Then
        Local $temp
        While 1
            $temp = _WinHttpReadData($hRequest)
            If $temp = "" Then ExitLoop
            $html &= $temp
        WEnd
        $temp = ""
    EndIf
    ConsoleWrite(_WinHttpQueryHeaders($hRequest) & @LF)
    ConsoleWrite($html & @LF)
    ;_IEDocWriteHTML($oIE, $html)

    _WinHttpCloseHandle($hRequest)
    _WinHttpCloseHandle($hConnect)
    _WinHttpCloseHandle($hOpen)
EndFunc   ;==>_Post_File

source forum anglais:
http://www.autoitscript.com/forum/index ... hl=winhttp
Après avoir parcouru le forum j'ai ajouter la fonction : Encode_MultiPart_FormData() dans le fichier WinHTTP.au3.

Bonjour

Une autre version, pour envoyer une capture d'écran sur le site de dl.free.fr.

On pourra trés bien imaginer automatiser l'envoie d'une capture non pas de l'écran mais de la WebCam toutes les 5 mn et faire de la télésurveillance

J'ai qd même un truc qui me chiffone, et je trouve pas l'erreur.
A la fin de l'envoie Free me donne une adresse pour supprimer le fichier sur leur serveur, qd je clique dans la fenêtre sur ce lien ca plante AutoIt, par contre copier l'adresse du lien et utiliser le menu "page/aller a une adresse" et que j'y colle le lien ca marche.

Idée bienvenue !!

► Afficher le texteLe code

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

    AutoIt Version : 3.3.0.0
    Auteur:         GaRy delaMer

    Fonction du Script : Exemple
    Un petit navigateur web intégrer dans une GUI

#ce ----------------------------------------------------------------------------
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=GaRy deleMer WebBrowser.Exe
#AutoIt3Wrapper_Compression=4
#Tidy_Parameters=/sf
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#Region ;**** Options AutoIt                           ****
Opt('MustDeclareVars', 1)
Opt('GUICloseOnESC', 1)
#EndRegion ;===============================================
#Region ;**** Include AutoIt                           ****
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <WindowsConstants.au3>
#include <IE.au3>
#include <INet.au3>
#include <Misc.au3>
#include <GuiStatusBar.au3>
#include <ScreenCapture.au3>
#EndRegion ;===============================================

Global $Titre_Appli = "GaRy delaMer FileUpload://"
If Not @Compiled Then
    _Singleton($Titre_Appli)
    HotKeySet("!x", "_GUIEvent_Quit")
EndIf

#include <WinHTTPConstants.au3>
#include <WinHTTP.au3>

#Region ;**** Gui, ActiveX _IE, Menu                ****
Global $hGUI = GUICreate($Titre_Appli, @DesktopWidth * 3 / 5, @DesktopHeight * 3 / 5, -1, -1, _
        $WS_OVERLAPPEDWINDOW + $WS_VISIBLE + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
;; les menus
Global $filemenu = GUICtrlCreateMenu("&Page")
Global $urlitem = GUICtrlCreateMenuItem("&Aller à l'adresse", $filemenu)
Global $fileitem = GUICtrlCreateMenuItem("&Ouvre un fichier", $filemenu)
Global $htmlitem = GUICtrlCreateMenuItem("&Coller du code html", $filemenu)
GUICtrlCreateMenuItem("", $filemenu)
Global $exititem = GUICtrlCreateMenuItem("&Quitter", $filemenu)
;; Le contrôle ActivX IE
_IEErrorHandlerRegister()
Global $oIE = _IECreateEmbedded()
Global $hIE = GUICtrlCreateObj($oIE, 22, 0)
; Assign events to UDFs starting with IEEvent_
Global $LoadComplete = False
Global $oIEEvent = ObjEvent($oIE, "_IEEvent_", "DWebBrowserEvents2")

Global $URL = "about&#058;blank"
_IENavigateComplete($URL)

GUIRegisterMsg($WM_SIZE, "_My_WM_SIZE")
GUISetState() ;Show GUI
_GUIEVENT_Resize()
#EndRegion ;===============================================

Global $testmenu = GUICtrlCreateMenu("&Test")
Global $post_files = GUICtrlCreateMenuItem("&Poster un fichier chez Free.fr", $testmenu)

While 1
    Local $msg = GUIGetMsg()
    Switch $msg
        Case $post_files
            _Post_Files()
        Case $urlitem
            Local $surl = InputBox("Entrer l'adresse", "Saisir l'adresse du site")
            If $surl <> "" Then _IENavigate($oIE, $surl) 
        Case $fileitem
            Local $hFile = FileOpenDialog("Ouvre une source HTML", @ScriptDir, _
                    "Source html (*.html; *.htm; *.txt)|Tous (*.*)", 11, "", WinGetHandle($hGUI))
            If Not @error Then
                Local $html = FileRead($hFile)
                If $html <> "" Then
                    _IEBodyWriteHTML($oIE, $html)
                EndIf
            EndIf
        Case $htmlitem
            Local $html = ClipGet()
            If IsString($html) And $html <> "" Then _IEBodyWriteHTML($oIE, $html)
        Case $GUI_EVENT_CLOSE, $exititem
            _GUIEvent_Quit()
    EndSwitch
WEnd

Func _Post_Files()
    Local $hOpen = _WinHttpOpen("AutoIt v3.3.0", $WINHTTP_ACCESS_TYPE_DEFAULT_PROXY)
    Local $URL = _WinHttpCrackUrl("http://dl.free.fr/index_nojs.pl")
    Local $Host = $URL[2]
    Local $Port = $URL[3]
    Local $Referrer = "http://" & $URL[2]
    Local $QueryString = $URL[6] & $URL[7]
    Local $hConnect = _WinHTTPConnect($hOpen, $Host, $Port)

    ;; Juste pour retrouver l'adresse pour faire le post peu être caché
    Local $hRequest = _WinHttpOpenRequest($hConnect, "GET", $QueryString, "HTTP/1.1", $Referrer)
    _WinHttpSendRequest($hRequest)
    _WinHttpReceiveResponse($hRequest)
    Local $html[3] = ["", _WinHttpQueryHeaders($hRequest), _WinHttpQueryOption($hRequest, $WINHTTP_OPTION_URL)]
    If _WinHttpQueryDataAvailable($hRequest) Then
        Local $temp
        While 1
            $temp = _WinHttpReadData($hRequest)
            If $temp = "" Then ExitLoop
            $html[0] &= $temp
        WEnd
        $temp = ""
    EndIf
    _WinHttpCloseHandle($hRequest)
    _Debug($html[1] & $html[2] & @LF)
    _IEDocWriteHTML($oIE, $html[0])

    _ScreenCapture_Capture(@TempDir & "\capture.jpg", 100, 100, 100, 100, False)
    Local $oForm = _IEFormGetCollection($oIE, 1)
    Local $URL = _WinHttpCrackUrl("http://dl.free.fr" & $oForm.action)
    Local $Host = $URL[2]
    Local $Port = $URL[3]
    Local $Referrer = "http://" & $URL[2]
    Local $QueryString = $URL[6] & $URL[7]
    Local $email = InputBox("Envoie de fichier sur Free", _
            "On y va !!!" & @LF & @LF & _
            "http://dl.free.fr" & $oForm.action & @LF & @LF & _
            "Entrez votre adresse email" & @LF & _
            "pour être notifié par free de l'adresse pour le télécharger.", "", "", 360, -1)
    If $email  = "" Then Return

    Local $hRequest = _WinHttpOpenRequest($hConnect, "POST", $QueryString, "HTTP/1.1", $Referrer)
    Local $form_files[1][2] = [["ufile", @TempDir & "\capture.jpg"]]
    Local $form_fields [7][2] = [ _
        ["mail1", $email], _
        ["mail2", ""], _
        ["mail3", ""], _
        ["mail4", ""], _
        ["message", "Test AutoIt"], _
        ["password", ""], _
        ["submit", "Envoyer"]]
    Local $FormDatas = Encode_MultiPart_FormData($form_fields, $form_files)
    Local $content_type = 'Content-Type: ' & $FormDatas[0] & @CRLF
    _WinHttpSendRequest($hRequest, $content_type, $WINHTTP_NO_REQUEST_DATA, StringLen($FormDatas[1]))
    _WinHTTPWriteData($hRequest, StringToBinary($FormDatas[1]), 1)

    _WinHttpReceiveResponse($hRequest)
    Local $post[3] = ["", _WinHttpQueryHeaders($hRequest), _WinHttpQueryOption($hRequest, $WINHTTP_OPTION_URL)]
    If _WinHttpQueryDataAvailable($hRequest) Then

    EndIf
    ; Pour la gestion du refresh en attente du retour serveur sur le traitement du fichier
    _WinHttpCloseHandle($hRequest)
    _WinHttpCloseHandle($hConnect)
    _WinHttpCloseHandle($hOpen)

    ; Comme la page de free fais un refresh toute les 2 secondes
    ; je lui Donne l'adresse de la page au lieu du HTML source
    _IENavigate($oIE, $post[2])
    _Debug($post[1] & $post[2] & @LF)
EndFunc   ;==>_Post_Files
#Region ;============= Fonctions ==========================
#Region ;; GUIEvent
Func _GUIEvent_Quit()
    Exit
EndFunc   ;==>_GUIEvent_Quit

Func _GUIEvent_Resize()
    Local $Size = WinGetClientSize($hGUI, "")
    GUICtrlSetPos($hIE, 5, 5, $Size[0] - 10, $Size[1] - 10)
EndFunc   ;==>_GUIEvent_Resize

Func _IENavigateComplete($URL)
    _IENavigate($oIE, $URL)
    While Not $LoadComplete
        Sleep(10)
    WEnd
EndFunc   ;==>_IENavigateComplete

Func _My_WM_SIZE($hWnd, $iMsg, $iwParam, $ilParam)
    _GUIEvent_Resize()
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_My_WM_SIZE
#EndRegion
#Region ;; IEEvent
Func _IEEvent_BeforeNavigate2($pDisp, $vUrl, $vFlags, $vTargetFrameName, $vPostData, $vHeaders, $bCancel)
;~  _DebugPrint("_IEEvent_BeforeNavigate2(""" & $vUrl & """)")
    $LoadComplete = False
EndFunc   ;==>_IEEvent_BeforeNavigate2

Func _IEEvent_DocumentComplete($pDisp, $sURL)
    $LoadComplete = True
;~  _Debug("_IEEvent_DocumentComplete()")
EndFunc   ;==>_IEEvent_DocumentComplete

Func _IEEvent_DownloadComplete()
;~  _DebugPrint("_IEEvent_DownloadComplete()")
EndFunc   ;==>_IEEvent_DownloadComplete

Func _IEEvent_NavigateComplete2($pDisp, $sURL)
;~  _DebugPrint("_IEEvent_NavigateComplete2(""" & $sURL & """)")
    If StringInStr($sURL, "javascript&#058;") Then Return
    $URL = $sURL
EndFunc   ;==>_IEEvent_NavigateComplete2

Func _IEEvent_ProgressChange($Progress, $ProgressMax)
;~  _DebugPrint("_IEEvent_ProgressChange(""" & $Progress & ", " & $ProgressMax & """)")
    ConsoleWrite($Progress & ", " & $ProgressMax & " ")
    If $Progress = -1 Then
        ConsoleWrite("Chargement de la page terminé" & @LF)
    EndIf
    If $ProgressMax = 0 Then
        ConsoleWrite("Chargement de la page... " & @LF)
    EndIf
    Local $percent = Int(($Progress * 100) / $ProgressMax)
    If $Progress > 0 Then
        ConsoleWrite($percent & "%" & @LF)
    EndIf
EndFunc   ;==>_IEEvent_ProgressChange

Func _IEEvent_StatusTextChange($sText)
;~  _DebugPrint("_IEEvent_StatusTextChange(""" & $sText & """)")
    If $sText = "" Then $sText = "Prêt"
EndFunc   ;==>_IEEvent_StatusTextChange

Func _IEEvent_TitleChange($sText = "")
;~  _DebugPrint("_IEEvent_TitleChange(""" & $sText & """)")
    If $sText = "" Then $sText = _IEPropertyGet($oIE, "title")
    WinSetTitle($hGUI, "", $Titre_Appli & $sText)
EndFunc   ;==>_IEEvent_TitleChange
#EndRegion
#Region ;; Debug
Func _Debug($title, $line = @ScriptLineNumber, $scriptfile = @ScriptName)
    Local $debug
    $debug &= $title & @LF
    $debug &= _IEPropertyGet($oIE, "title") & "(" & _IEPropertyGet($oIE, "locationurl") & ")" & @LF
    _IEFrameGetCollection($oIE)
    $debug &= "Nb de frame: " & @extended & @LF
    _IEImgGetCollection($oIE)
    $debug &= "Nb d'image: " & @extended & @LF
    _IELinkGetCollection($oIE)
    $debug &= "Nb de lien: " & @extended & @LF

    Local $oForms = _IEFormGetCollection($oIE)
    $debug &= "Nb de formulaire: " & @extended & @LF
    For $oForm In $oForms
        Local $Items = _IEFormElementGetCollection($oForm)
        $debug &= @LF & "++Form: " & $oForm.name & " Action: " & $oForm.action & @LF
        For $Item In $Items
            $debug &= @TAB & "<" & $Item.type & "> Name: " & $Item.name
            If $Item.type = "file" Then
                $debug &= " file: désactivé non affiché " & $Item.value & @LF
            ElseIf $Item.type = "textarea" Then
                $debug &= " Value: textarea non affiché" & @LF
            Else
                $debug &= " Value=" & $Item.value & @LF
            EndIf
        Next
    Next
    _DebugPrint($debug, $line, $scriptfile)
EndFunc   ;==>_Debug

Func _DebugPrint($s_text, $line = @ScriptLineNumber, $scriptfile = @ScriptName)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            $scriptfile & "(" & $line & ",1) AutoIt " & @AutoItVersion & @LF & _
            "+======================================================" & @LF & _
            "" & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint
#EndRegion
#EndRegion ;===============================================

bonjour, puis-je savoir pourquoi il faut attendre au démarrage du navigateur ?

Bonjour,

J'ai tester votre application et elle fonctionne formidablement.

Merci à vous.
Dans le cadre de mon projet scolaire ( site internet en HTTPS ) j'aurais aimer utiliser la GUI avec le navigateur intégrer cependant, il n'arrive pas a afficher la page HTTPS , il bloque sur l'acceptation du certificat...

Avez-vous une solution ?

Merci par avance

Rere78 a écrit :mon projet scolaire

Si c'est un navigateur qu'il vous faut, tournez vous vers iSafari !

Bonjour,

Je ne critique en aucun cas , le travail réalisé qui est super.
Certes, un navigateur fait l'affaire cependant, j'aurais aimer utiliser cette petite GUI pour afficher les 6 petites pages du site. Je cherchais juste un moyen de passer ce HTTS.

Merci de pour votre réponse et désolé du dérangement alors.

Bonne Soirée

Hmm J'avais deja eu de gros problèmes avec https.

Le problème, c'est qu'on utilise une librairie _IE qui est en fait basée sur IE6, (et oui encore lui) dès que l'on utilise pas le navigateur installé (IE8 j'espère) en mode visible.

Quand on utilise le navigateur integré en passant par les objets donc, j'ai jamais reussi a passer un site protegé par https avec un certificat non validé par une autorité compétente( pour ne pas donner de nom: Verisign) (normalement il suffit de cliquer : Oui, aller sur ce site quand meme) mais ca se revele impossible.

Bref, je vois 2 solutions.
Soit, et alors vous ne pourrez plus utiliser le code de Gary, vous passez avec la bibliotheque _FF et ca risque d'etre plus dur car rien n'est en francais et il existe moins d'exemples, moins de personnes qui connaissent, etc...
L'avantage, c'est que vous n'aurez aucun problème de compabilité. L'inconveniant, c'est que ca ne marche que si FF est installé, et si vous comptez partager votre application elle risque d'etre incompatible avec pas mal de gens. (et en plus il faut MozRepl d'installé) Bref solution envisageable si le programme est seulement pour vous.

2eme solution, qui n'en est pas vraiment une, vous ouvrez iexplore.exe vous allez sur le site et dans les parametres vous vous "démerdez" (ici c'est le mot tellement c'est chiant) a lui faire accepter le certificat sans afficher de message, et alors votre script passera comme sur des roulettes.

3eme solution probable : Cherchez sur le forum anglais, a mon avis certains ont trouvé mieux que moi mais la pas le tps d'aller voir

Mais si j'ai IE8 est-ce qu'il utilise les Library IE 6 ? :O

Sinon sa saurait vraiment bien que vous ajoutiez des Onglets au Navigateur plus haut

Je suis sur que sa aiderait beaucoup de personne.

Bonsoir

j'ai pas retoucher à cette source qui est la juste pour démontrer comment utiliser Internet avec AutoIt.

Maintenant, je préfère utiliser FireFox pour mon surf.

Ceci dans le cadre d'une application , afficher une page web dans 1 GUI peut être utile.

Consulter une aide, mettre à jour des données sur un intranet etc...

Oui elle ma été très utile pour créer un Navigateur Web autrefois. Mais j'aimerais y ajouter des Onglets et il y a très peu de source sur sa

Donc c'est pour sa que je disais que sa saurait vraiment bien que quelqu'un y ajoute des onglets ce qui pourrait être très utiles à tout le monde

Alexward a écrit :Donc c'est pour sa que je disais que sa saurait vraiment bien que quelqu'un y ajoute des onglets ce qui pourrait être très utiles à tout le monde

Mouai, ca serait plus très utile pour vous (Si vous voyez ce que je veux dire, ja******) Vous avez déjà demandé a de multiples reprises la meme choses, essayez par vous meme non d'une pipe.

J'ai déjà posté/vu des exemples d'onglets, il suffit de créer autant d'objets internet (ObjCreate) que d'onglet, puis on se balade avec IE.au3 comme avant

Concernant votre demande précédente, on utilise ce qu'on appelle une API externe, ici celle de Internet explorer, et il se trouve que oui les 90% des fonctions sont les mêmes que dans IE6, ce qui est normal car après cette version il n'y a que le superflu et la securité qui changent, la base elle ne change pas.

AutoIt Français

[EX] Navigateur web intégrer, Acceder au forum, Upload files

[EX] Navigateur web intégrer, Acceder au forum, Upload files

Re: [EX] Navigateur web intégrer, acceder au forum

Re: [EX] Navigateur web intégrer, Acceder au forum, Upload files

Re: [EX] Navigateur web intégrer, Acceder au forum, Upload files

Re: [EX] Navigateur web intégrer, Acceder au forum, Upload files

Re: [EX] Navigateur web intégrer, Acceder au forum, Upload files

Re: [EX] Navigateur web intégrer, Acceder au forum, Upload files

Re: [EX] Navigateur web intégrer, Acceder au forum, Upload files

Re: [EX] Navigateur web intégrer, Acceder au forum, Upload files

Re: [EX] Navigateur web intégrer, Acceder au forum, Upload files

Re: [EX] Navigateur web intégrer, Acceder au forum, Upload files

Re: [EX] Navigateur web intégrer, Acceder au forum, Upload files