AutoIt Français

Voilà une très très grand merci à tout ceux qui ont prit le temps de m'aider dans mon entreprise, je suis partie de rien du tout et aucune connaissance en programmation et grâce à votre aide et vos conseil j'ai réussi à arrivé au résultat que je voulais. Spécial thanks à jbnh, SagePourpre, Tlem et sylvanie pour avoir tout expliqué comme à un noob ^^.

Voilà donc mon code, il est trois partie et ressemble à du bricolage, une hérésie de la programmation mais il fait ce que je voulais. Une courte présentation il est en trois morceaux qui s'appellent et se testent les uns les autres, si quelqu'un est motivé à l'optimiser et le modifier je serai curieux de suivre son évolution.

► Afficher le textePartie 1 :

Code : Tout sélectionner

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;DECLARATION DES VARIABLES                                              ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
dim $test1, $test3, $var1, $var2, $var3, $var4, $var5, $var6
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;COMPLETION DES VARIABLES                                                ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
$test1 = RegRead("HKEY_CURRENT_USER\Software\", "script1")
$test3 = RegRead("HKEY_CURRENT_USER\Software\", "script3")
$var1 = ('netsh interface ip set address "Connexion au réseau local" dhcp')
$var2 = ('netsh interface ip set dns "Connexion au réseau local" dhcp')
$var3 = ("ipconfig /release")
$var4 = ("ipconfig /renew")
$var5 = ("02.exe")
$var6 = ("exit")
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;TEST D'EXECUTION PRECEDENTE DES SCRIPTS 3 ET 1               ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
if $test3 = 00000001 then
    Exit
endif
if $test1 = 00000001 Then
    Run(@ComSpec & " /c " & "cmd.exe")  
    WinWaitNotActive("ConsoleWindowClass")
    send($var5 & "{enter}")
    WinWaitNotActive("ConsoleWindowClass")  
    send($var6 & "{enter}")
else
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;MODIFICATION DE LA CLE NUMERO 1                                      ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
regwrite("HKEY_CURRENT_USER\Software\", "script1", "REG_DWORD", "00000001")
sleep(1000)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;MISE EN DHCP                                                                   ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    Run(@ComSpec & " /c " & "cmd.exe")
    WinWaitNotActive("ConsoleWindowClass")
    send($var1 & "{enter}") 
    WinWaitNotActive("ConsoleWindowClass")
    send($var2 & "{enter}") 
    WinWaitNotActive("ConsoleWindowClass")
    send($var3 & "{enter}") 
    WinWaitNotActive("ConsoleWindowClass")
    send($var4 & "{enter}") 
    WinWaitNotActive("ConsoleWindowClass")
    send($var5 & "{enter}")
    WinWaitNotActive("ConsoleWindowClass")
    send($var6 & "{enter}")
    sleep(1000)
endif
exit

► Afficher le textePartie 2 :

Code : Tout sélectionner

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;DECLARATION DES VARIABLES                                                ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
dim $ip, $result, $num, $nom, $domaine, $user, $pwd, $dom, $test2, $var1, $var2, $var3, $var7
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;COMPLETION DES VARIABLES                                                 ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
$ip = @IPAddress1
$result = StringInStr($ip, ".", 0, 3)
$num = StringMid($ip, $result+1)
$nom = ("enq_"&$num)
$domaine = ("Edinstitut.com")
$user = ("Administrateur")
$pwd = ("****************")
$dom = ("edinstitut\Administrateur")
$test2 = RegRead("HKEY_CURRENT_USER\Software\", "script2")
$var1 = ("03.exe")
$var2 = ("exit")
$var3 = ("edinstitut")
$var7 = ("0")
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;TEST D'EXECUTION PRECEDENTE DU SCRIPT 2                          ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
if $test2 = 00000001 then
    Run(@ComSpec & " /c " & "cmd.exe")  
    WinWaitNotActive("ConsoleWindowClass")
    send($var1 & "{enter}")
    WinWaitNotActive("ConsoleWindowClass")  
    send($var2 & "{enter}")
Else
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;MODIFICATION DE LA CLE NUMERO 2                                       ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
sleep(1000)
regwrite("HKEY_CURRENT_USER\Software\", "script2", "REG_DWORD", "00000001")
sleep(1000)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;MISE EN RELATION AVEC LE DOMAINE                                    ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
While $var7 == ("0")    
    Run(@ComSpec & " /c " & "sysdm.cpl")
    WinWait("Propriétés système")
    send("{right}")
    sleep(2000)
    send("!d")
    sleep(2000)
    send($var3)
    sleep(2000)
    send("!f")
    sleep(2000)
    send($nom)
    sleep(2000)
    send("!d")
    sleep(2000)
    send("{tab}")
    sleep(2000)
    send($domaine)
    sleep(2000)
    send("{enter}")
    sleep(2000)
    send("{enter}")
    sleep(20000)                    
    winwait("Modification du nom d'ordinateur")
    sleep(2000)
    send($user)
    sleep(2000)
    send("!m")
    sleep(2000)
    send($pwd)
    sleep(2000)
    send("{ENTER}")
    sleep(2000)
    winwait("Modification du nom d'ordinateur")
    sleep(2000)
    send("{ENTER}")
    sleep(1000)
    winwait("Modification du nom d'ordinateur")
    sleep(1000)
    send("{enter}")
    sleep(1000)
    send("{tab}")
    sleep(2000)
    send("{ENTER}")
    sleep(2000)
    send("{right}")
    sleep(2000)
    send("{enter}")
    sleep(2000)
    $var7 = ("1")
    sleep(30000)
wend
    Run(@ComSpec & " /c " & "cmd.exe")  
    WinWaitNotActive("ConsoleWindowClass")
    send($var1 & "{enter}")
    send("exit" & "{enter}")
endif   
exit

► Afficher le textePartie 3 :

Code : Tout sélectionner

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;DECLARATION DES VARIABLES                                               ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
dim $test3, $var1, $ip, $result, $num, $nom
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;COMPLETION DES VARIABLES                                                ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
$ip = @IPAddress1
$result = StringInStr($ip, ".", 0, 3)
$num = StringMid($ip, $result+1)
$nom = ("enq_"&$num)
$test3 = RegRead("HKEY_CURRENT_USER\Software\", "script3")
$var1 = ("EDINSTITUT")
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;TEST D'EXECUTION PRECEDENTE DU SCRIPT 3                           ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
if $test3 = 00000001 then
    Exit
else
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;MODIFICATION DE LA CLE NUMERO 3                                       ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
sleep(1000)
regwrite("HKEY_CURRENT_USER\Software\", "script3", "REG_DWORD", "00000001")
sleep(1000)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;AJOUT D'UTILISATEUR                                                          ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    Run(@ComSpec & " /c " & "nusrmgr.cpl")
    sleep(1000)
    sleep(10000)
    send("!o")
    sleep(1000)
    WinWaitactive("Ajout d'un nouvel utilisateur")
    sleep(1000)
    send($nom)
    sleep(2000) 
    send("!d")
    sleep(2000)
    send($var1)
    sleep(2000)
    send("!s")
    sleep(2000)
    WinWaitactive("Ajout d'un nouvel utilisateur")
    send("{TAB}")
    send("{TAB}")
    send("{enter}")
    sleep(1000)
    send("{TAB}")
    send("{TAB}")
    send("{enter}")
    sleep(1000)
endif
Shutdown (2)

exit

Encore un super gros merci à tous, je serai de retour bientot :p

Ne connaissant pas les caractéristiques du programme 02.exe, voici un premier jet pour simplifier votre script N°1.
Faites un test et dite moi si ca fonctionne.

► Afficher le texte

Que sont 02.exe et 03.exe et à quoi servent-ils ???

Je ne suis pas sur d'avoir mis toutes les valeurs là ou il faut, mais dans l'ensemble, voici une forme d'optimisation du script qu'il faudra adapté bien sur :

► Afficher le texte

Code : Tout sélectionner

;DECLARATION VARIABLES
Dim $IP = StringSplit(@IPAddress1, ".")
Dim $Name = ("enq_" & $IP[4])
Dim $Domaine = ("Edinstitut.com")
Dim $UserAdm = ("Administrateur")
Dim $PwdAdm = ("****************")
Dim $Dom = ("edinstitut\Administrateur")
Dim $User = ("EDINSTITUT")
Dim $PwdUser = ("PASSWORD")

; On lance la config en DHCP (Script 1).
_DHCP()

; On renomme le PC (Script 2).
Computer_Rename($Name, $UserAdm, $PwdAdm)
; Ajout de la machine sur le domaine (Script 2).
Computer_AddToDomainOrWorkgroup($Domaine, $UserAdm, $PwdAdm)

; Ajout Utilisateur (Script 3).
_AddUser($Name, $PwdUser, $Domaine)


; ##########################   Fonctions  ##########################
; CONFIG DHCP (Script 1)
Func _DHCP()
    RunWait(@ComSpec & ' /c ' & 'netsh interface ip set address "Connexion au réseau local" dhcp', "", @SW_HIDE)
    RunWait(@ComSpec & ' /c ' & 'netsh interface ip set dns "Connexion au réseau local" dhcp', "", @SW_HIDE)
    RunWait(@ComSpec & ' /c ' & 'ipconfig /release', "", @SW_HIDE)
    RunWait(@ComSpec & ' /c ' & 'ipconfig /renew', "", @SW_HIDE)
EndFunc   ;==>_DHCP

; AJOUT UTILISATEUR (Script 3)
Func _AddUser($sUser, $sPwdUser, $sDomaine)
    RunWait(@ComSpec & ' /c ' & 'net user ' & $sUser & ' ' & $sPwdUser & ' /Add /' & $sDomaine, "", @SW_HIDE)
EndFunc   ;==>_AddUser


Func Computer_Rename($sComputerName, $sLocalUser, $sPassword)
    ;***************************************************************
    ; Function:     System_Computer_Rename
    ; Actions:      Renames the machine - from http://msdn2.microsoft.com/en-us/library/aa393056.aspx
    ; Parameters:   $sComputerName - new computer name
    ;               $sLocalUser - local admin username
    ;               $sPassword - local admin password
    ; Returns:      1 - success
    ;               0 - failure
    ; Requirements: none
    ; Author:       Justin Taylor
    ;***************************************************************
    
    Local $objWMIService, $objComputer, $sReturn
    
    ;Create a WMI object
    $objWMIService = ObjGet("Winmgmts:root\cimv2")

    ;Verify the object was created
    If IsObj($objWMIService) Then
        For $objComputer In $objWMIService.InstancesOf("Win32_ComputerSystem")
            ;Rename the computer
            $sReturn = $objComputer.rename($sComputerName, $sPassword, $sLocalUser)
            If $sReturn <> 0 Then
                If IsDeclared("sFileName") Then FileWriteLine($sFileName, "System_Computer_Rename: Unable to rename the computer, possible Error: " & $sReturn & ". - ScriptLine Number: " & @ScriptLineNumber)
                SetError(1)
                Return 0
                
            EndIf
            
        Next
        
    Else
        ;Object was not created
        If IsDeclared("sFileName") Then FileWriteLine($sFileName, "System_Computer_Rename: The WMI object was not created. - ScriptLine Number: " & @ScriptLineNumber)
        SetError(1)
        Return 0
        
    EndIf
    
    Return 1
    
EndFunc   ;==>Computer_Rename


Func Computer_AddToDomainOrWorkgroup($sDomain, $sDomainUsername, $sPassword)
    ;***************************************************************
    ; Function:     System_Computer_AddToDomainOrWorkgroup
    ; Actions:      Adds the local machine to the specified domain using the specified credentials - from http://msdn2.microsoft.com/en-us/library/aa392154.aspx
    ; Parameters:   $sDomain - domain to add computer to
    ;               $sDomainUsername - domain username with credentials to add machines to the domain
    ;               $sPassword - password
    ; Returns:      1 - success
    ;               0 - failure
    ; Requirements: none
    ; Author:       Justin Taylor
    ;***************************************************************
    
    Const $iJoin_Domain = 1
    Const $iAcct_Create = 2
    Const $iAcct_Delete = 4
    Const $iWin9X_Upgrade = 16
    Const $iDomain_Join_If_Joined = 32
    Const $iJoin_Unsecure = 64
    Const $iMachine_Password_Passed = 128
    Const $iDeffered_Spn_Set = 256
    Const $iInstall_Invocation = 262144
    
    Local $objNetwork, $sComputer, $objComputer, $sReturnValue
    
    ;Create a WMI object
    $objNetwork = ObjCreate("WScript.Network")
    
    ;Verify the object was created
    If IsObj($objNetwork) Then
        ;Retrieve the computer name
        $sComputer = $objNetwork.ComputerName
        
        ;Set impersonation
        $objComputer = ObjGet("winmgmts:{impersonationLevel=Impersonate}!\\" & $sComputer & "\root\cimv2:Win32_ComputerSystem.Name='" & $sComputer & "'")
        
        If IsObj($objComputer) Then
            ;Add the machine to the domain
            $sReturnValue = $objComputer.JoinDomainOrWorkGroup($sDomain, $sPassword, $sDomain & "\" & $sDomainUsername, "", $iJoin_Domain + $iAcct_Create)
            
        Else
            ;Object was not created
            If IsDeclared("sFileName") Then FileWriteLine($sFileName, "System_Computer_AddToDomainOrWorkgroup: The WMI object was not created - $objComputer. - ScriptLine Number: " & @ScriptLineNumber)
            SetError(1)
            Return 0
        EndIf
        
    Else
        ;Object was not created
        If IsDeclared("sFileName") Then FileWriteLine($sFileName, "System_Computer_AddToDomainOrWorkgroup: The WMI object was not created - $objNetwork. - ScriptLine Number: " & @ScriptLineNumber)
        SetError(2)
        Return 0
        
    EndIf
    
    Return 1
    
EndFunc   ;==>Computer_AddToDomainOrWorkgroup

AutoIt Français

[Ex] Script DHCP / Ajout domaine / ajout utilisateur

[Ex] Script DHCP / Ajout domaine / ajout utilisateur

Re: [M] Script DHCP / Ajout domaine / ajout utilisateur

Re: [M] Script DHCP / Ajout domaine / ajout utilisateur