AutoIt Français

Bonjour tout le monde

Apres avoir farfouillé tant sur le forum US que sur le notre, je n'ai aps trouvé ce que je voudrais.
Ce que je veux c'est pouvoir prendre un treeview par exemple tel que celui ci :

► Afficher le texte

Et faire en sorte que quand on clique sur un parent ca (dé)coche les enfants, et que quand on coche un enfant ca (dé)coche les ascendants.

J'ai trouvé des choses ressemblantes (je pense au shelltristate treeview par exemple, mais qui est dédié aux arborescences disques/fichiers), ou qui ne fonctionnent pas (en tout cas pas chez moi ni au bureau comme le tristate treeview du forum US), mais pas ce que je veux.

Donc voilà, si qqun a un tuyau, je suis preneur.
D'avance merci

bonjour

La seule piste qui me vient tout de suite à l'esprit, c'est de passer en mode
AutoItSetOption("GUIOnEventMode", 1)

Puis d'utiliser GUICtrlSetOnEvent sur chaque case à cocher, ce qui fait que tu pourras contrôler la coche des cases "filles" dans une fonction appelée par la coche des cases "mères"...

c'est pas l'implémentation qui pose probleme, c'est l'algo.
Je vois pas comment faire ca. Tous mes essais se sont soldés par des erreurs. soit ca gere mal les descedants, soit c'est les parents... bref, c'est la loose.

Hummm, j'avoue ne pas avoir l'esprit très alerte ce soir pour ce type de masturbation intellectuelle, mais grossièrement, je verrais un truc du genre :
- Si je clique un parent, alors j'utilise : _GUICtrlTreeView_GetFirstChild et GetNextChild en boucle récursive pour contrôler/modifier la totalité des enfants.

Si je clique un enfant pour le cocher, alors j'utilise _GUICtrlTreeView_GetParentHandle en boucle jusqu'à ce qu'il n'y ai plus de parent (Return Value 0) tout en cochant chaque parent.

Après, il reste des cas particuliers à gérer, tel que :
- Si je décoche un enfant et qu'il n'y à plus d'enfant coché, alors le parent doit-il être décoché ?

- Et probablement d'autres qui ne me viennent pas à l'esprit pour l'instant.

Bah c'est ce que j'ai éssayé... et ca marche pô.
Je crois que je vais aller titiller l'auteur de tristate treeview sur le forum US, histoire de voir pourquoi son bidule marche pas chez moi...

Hello

dis moi ce que tu penses de ça: (mis à part que c'est un peu anarchique comme programmation)

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>

#Include <Array.au3>


; Postulat : Sur un Niveau, on ne peut pas avoir plus de MAXLEGENDE boutons à cocher.
Const $MAXLEGENDE=5
Const $MAXNIV=4

; Dim $TreeViewItems[($MAXNIV^$MAXLEGENDE)+1][2] ; max théorique.
Dim $TreeViewItems[1][3] ; on va utiliser remdim pour ne pas déclarer un tableau immense pour rien.

; $TreeViewItems[0][0] : nombre d'élements graphiques enregistrés
; $TreeViewItems[x][0] : référence graphique du Xieme élément créé.
; $TreeViewItems[x][1] : chemin de parcours du Xieme élément créé. Exemple : 1_3_2
; $TreeViewItems[x][2] : légende du Xieme élément créé.

$TreeViewItems[0][0]=0

; légendes particulières. La règle veut qu'une case à cocher au Xieme rang d'un niveau donné implique qu'il existe des cases de 1 à X-1 pour ce niveau ( avec une légende par défaut)

Const $RACINE_LG="LG" ; racine des variables contenant des légendes particulières.

Const $LG_1="Niveau1, 1ere coche"
Const $LG_2_3="Niveau2, 3eme coche"
Const $LG_2_2="Niveau2, 2eme coche"
Const $LG_1_4_2_2="mon test au fond(1422)"
; voici le résultat de explore_legendes pour ces constantes définies.
;
;[0]|13||
;[1]|LG_2_3||Niveau2, 3eme coche
;[2]|LG_2_2||Niveau2, 2eme coche
;[3]|LG_2_1||..(LG_2_1)
;[4]|LG_2||..(LG_2)
;[5]|LG_1_4_2_2||mon test au fond(1422)
;[6]|LG_1_4_2_1||..(LG_1_4_2_1)
;[7]|LG_1_4_2||..(LG_1_4_2)
;[8]|LG_1_4_1||..(LG_1_4_1)
;[9]|LG_1_4||..(LG_1_4)
;[10]|LG_1_3||..(LG_1_3)
;[11]|LG_1_2||..(LG_1_2)
;[12]|LG_1_1||..(LG_1_1)
;[13]|LG_1||Niveau1, 1ere coche


AutoItSetOption("GUIOnEventMode", 1)



$Form1 = GUICreate("Form1", 314, 332, 192, 114)
$TreeView1 = GUICtrlCreateTreeView(8, 8, 297, 281, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
GUISetState(@SW_SHOW)
$button1=GUICtrlCreateButton("list",10,291,75,20)

GUISetOnEvent($GUI_EVENT_CLOSE, "gui_clic_close")


; on va remplir le tableau
explore_legendes($RACINE_LG,0)


Func explore_legendes($CHEMIN,$NIVEAU)
    ; remplissage du tableau des $TreeViewItems

    $CREER_CASE=0
    For $LEGENDE=$MAXLEGENDE To 1 Step -1
        $CHEM_TEST=$CHEMIN & "_" & $LEGENDE
        $TEST1=0 ; on veut savoir si le "fichier" actuel est également un "dossier".
        If $NIVEAU<$MAXNIV Then
            $TEST1=explore_legendes($CHEM_TEST,$NIVEAU+1)
        EndIf
        ; occupons nous maintenant du "fichier".
        $TEST2=eval($CHEM_TEST)
        If ($TEST2<>"") Or ($TEST1<>0) Then
            $CREER_CASE=1
        EndIf
        If $CREER_CASE Then
            ConsoleWrite("variable:" & $CHEM_TEST & "=" & $TEST2 & @CRLF)
            $TreeViewItems[0][0]+=1
            ReDim $TreeViewItems[$TreeViewItems[0][0] + 1][3]
            $TreeViewItems[$TreeViewItems[0][0]][0]=$CHEM_TEST
            If $TEST2="" Then
                $TreeViewItems[$TreeViewItems[0][0]][2]="..(" & $CHEM_TEST & ")" ; légende par défaut...
            Else
                $TreeViewItems[$TreeViewItems[0][0]][2]=$TEST2
            EndIf
        EndIf
    Next
    Return($CREER_CASE)
EndFunc



; maintenant, il suffit de relire la tableau en partant de la fin pour trouver quels sont les éléments graphiques à créér.
; voici le résultat de explore_legendes pour ces constantes définies.
;
;[0]|13||
;[1]|LG_2_3||Niveau2, 3eme coche
;[2]|LG_2_2||Niveau2, 2eme coche
;[3]|LG_2_1||..(LG_2_1)
;[4]|LG_2||..(LG_2)
;[5]|LG_1_4_2_2||mon test au fond(1422)
;[6]|LG_1_4_2_1||..(LG_1_4_2_1)
;[7]|LG_1_4_2||..(LG_1_4_2)
;[8]|LG_1_4_1||..(LG_1_4_1)
;[9]|LG_1_4||..(LG_1_4)
;[10]|LG_1_3||..(LG_1_3)
;[11]|LG_1_2||..(LG_1_2)
;[12]|LG_1_1||..(LG_1_1)
;[13]|LG_1||Niveau1, 1ere coche


For $CPT=$TreeViewItems[0][0] To 1 Step -1
    ; recherche du parent
    $PARENT=$TreeView1 ; par défaut..
    $TEST=StringTrimRight($TreeViewItems[$CPT][0],2)
    consolewrite("Début recherche parent(=" & $TEST & ") pour " & $TreeViewItems[$CPT][0] & @CRLF)
    If $TEST<>$RACINE_LG Then
        $TROUVE=0
        $IDGRAPH_PARENT=0
        $BIDON=""
        For $CPT2=$TreeViewItems[0][0] To $CPT+1 Step -1
            If $TEST=$TreeViewItems[$CPT2][0] Then
                $TROUVE=1
                $IDGRAPH_PARENT=$TreeViewItems[$CPT2][1]
                $BIDON=$TreeViewItems[$CPT2][0]
                ExitLoop
            EndIf
        Next
        If Not($TROUVE) Then
            ConsoleWriteError("Erreur interne de recherche du parent de " & $TreeViewItems[$CPT][0] & @CRLF)
        Else
            ConsoleWrite("parent de " & $TreeViewItems[$CPT][0] & "=" & $BIDON & @CRLF)
            $PARENT=$IDGRAPH_PARENT
        EndIf
    EndIf
    $TreeViewItems[$CPT][1] = GUICtrlCreateTreeViewItem($TreeViewItems[$CPT][2], $PARENT)
    GUICtrlSetOnEvent(-1,"cochecase")
Next

Func cochecase()
    ; recherche de quelle case a été touchée.
    $IDXCOCHE=1
    While (@GUI_CtrlId<>$TreeViewItems[$IDXCOCHE][1]) And ($IDXCOCHE<=$TreeViewItems[0][0])
        $IDXCOCHE+=1
    WEnd
    If $IDXCOCHE>$TreeViewItems[0][0] Then
        ConsoleWriteError("Erreur interne de recherche de la case à cocher" & @CRLF)
        Exit 8
    EndIf
    ; maintenant, on applique la même coche à tous les "enfants"
    ; remarque pour optimiser : les enfants sont forcément au dessus de l'élément qu'on vient de toucher.
    ; exemple : 1_3_2 est un enfant de 1_3, mais pas 1_2_3 ni 1_4_4
    For $CPT=1 To $IDXCOCHE-1
        If stringinstr($TreeViewItems[$CPT][0],$TreeViewItems[$IDXCOCHE][0])=1 Then
            GUICtrlSetState($TreeViewItems[$CPT][1],GUICtrlRead($TreeViewItems[$IDXCOCHE][1]))
        EndIf
    Next
    ;

EndFunc

Func gui_clic_close()
    ; cette fonction sert si on clique sur le X de fermeture de la fenetre,
    Exit
EndFunc   ;==>gui_clic_close




While 1
WEnd


;;;_ArrayDisplay($TreeViewItems)

A part ça, j'ai un bug d'affichage : le petit "+" qui est sensé s'afficher en face de la derniere case à cocher de niveau 1 ne s'affiche pas. Mais j'ai remarqué que t'as le bug aussi.

Cest gentil de t'etre penché sur mon probleme, et il faut bien avouer qu'a 48h pres, j'aurai surement employé ton code, mais j'ai fini par me dépatouiller. Au final j'ai fait un systeme ou les enfants héritent systématiquement du parent, et ou les parents héritent seulement du cochage de leur descendance (on peut décocher les enfants, les ascendants restent cochés)
Le tout bien sur quel que soit le niveau ou on (dé)coche.
pour un exemple 'en live' je te renvoie vers la dernière version de DirInstall que je viens de publier
Par contre je comprend mal ta dernière phrase.
"le petit "+" qui est sensé s'afficher en face de la derniere case à cocher de niveau 1 ne s'affiche pas"
Chez moi ca s'affiche tres bien...

Une petite capture d'écran valant mieux qu'un long discours, voici 2 captures d'écran : En haut à gauche, la form telle qu'elle apparait au début, et la 2eme capture, c'est après avoir coché la derniere case en bas.

je suis sous windows XP, thème "classique". Ceci explique peut-etre cela...

tiens oui c'est bizare, j'avais pas remarqué...
Sur mon seven a la maison j'ai aps le pb...

Bon, sinon au cas ou ca interesserait qqun, voici ma solution :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>

Global $idx = 0
Global $level = 0
Dim $TreeViewItems[$idx + 1]

global $hTreeView

$Form1 = GUICreate("Form1", 314, 332, 192, 114)
$TreeView1 = GUICtrlCreateTreeView(8, 8, 297, 281, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
$hTreeView = GUICtrlGetHandle($TreeView1) ; on prend le handle du treeview

GUISetState(@SW_SHOW)
$button1=GUICtrlCreateButton("list",10,291,75,20)

For $i = 1 To 2
    _FilltreeView($TreeView1)
Next
_GUICtrlTreeView_Sort($hTreeView) ; on trie le tableau (pour le pb de la petite croix)

GUIRegisterMsg($WM_NOTIFY, "_Check") ; on appelle la fonction qui gere les check boxes

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        case $button1
            DisplaySelected()

    EndSwitch
WEnd

Func DisplaySelected()
    Local $selectedlist
    For $i = 1 To $idx
        If _IsChecked($TreeViewItems[$i]) Then
            $selectedlist = $selectedlist & GUICtrlRead($TreeViewItems[$i], 1) & @CRLF
        EndIf
    Next
    MsgBox(0, '', $selectedlist)
EndFunc   ;==>DisplaySelected

Func _FilltreeView($parent)
    $level = $level + 1
    $idx = $idx + 1
    ReDim $TreeViewItems[$idx + 1]
    $TreeViewItems[$idx] = GUICtrlCreateTreeViewItem($level & " Item " & $idx, $parent)
    If $level < 3 Then
        _FilltreeView($parent)
        _FilltreeView($TreeViewItems[$idx])
    EndIf
    $level = $level - 1
EndFunc   ;==>_FilltreeView

Func _IsChecked($item)
    If BitAND(GUICtrlRead($item), $GUI_CHECKED) = $GUI_CHECKED Then
        Return True
    Else
        Return False
    EndIf
EndFunc   ;==>_IsChecked






; ici les 3 fonctions qui gèrent les checkboxes
; _check qui identifie la case en cours, et qui apelle _checkchild pour la descendance, et _checkparents pour les ascendants



Func _Check($hWnd, $Msg, $wParam, $lParam)
    Local $hWndFrom, $idFrom, $iCode, $tNMHDR = DllStructCreate("hwnd hwndFrom;int idFrom;int code", $lParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hwndFrom")
    $iCode = DllStructGetData($tNMHDR, "code")
    If $hWndFrom = $hTreeView Then
        Switch $iCode
            Case $NM_CLICK
                Local $tMPos = _WinAPI_GetMousePos(True, $hWndFrom), $tHit = _GUICtrlTreeView_HitTestEx($hWndFrom, DllStructGetData($tMPos, 1), DllStructGetData($tMPos, 2))
                Local $hItem = DllStructGetData($tHit, "Item"), $iFlags = DllStructGetData($tHit, "Flags")
                If $hItem <> 0 And BitAND($iFlags, $TVHT_ONITEMSTATEICON) Then
                    _CheckChildren($hWndFrom, $hItem, 1)
                    _CheckParents($hWndFrom, $hItem)
                EndIf
            Case $TVN_KEYDOWN
                Local $tNMTVKEY = DllStructCreate("hwnd;int;int;short key;uint", $lParam)
                Local $hSelected = _GUICtrlTreeView_GetSelection($hWndFrom)
                If DllStructGetData($tNMTVKEY, "key") = 0x20 And $hSelected Then ;;space
                    _CheckChildren($hWndFrom, $hSelected, 1)
                    _CheckParents($hWndFrom, $hSelected)
                EndIf
            Case Else
        EndSwitch
    EndIf
EndFunc   ;==>_Check

Func _CheckChildren($hWnd, $hItem, $fTop = 0)
    $Update = True
    Local $fChecked = _GUICtrlTreeView_GetChecked($hWnd, $hItem)
    If $fTop Then $fChecked = Not $fChecked
    If _GUICtrlTreeView_GetChildren($hWnd, $hItem) Then
        Local $hChild = _GUICtrlTreeView_GetFirstChild($hWnd, $hItem)
        Do
            _GUICtrlTreeView_SetChecked($hWnd, $hChild, $fChecked)
            If _GUICtrlTreeView_GetChildren($hWnd, $hChild) Then
                _CheckChildren($hWnd, $hChild)
            EndIf
            $hChild = _GUICtrlTreeView_GetNextChild($hWnd, $hChild)
        Until $hChild = 0
    EndIf
EndFunc   ;==>_CheckChildren

Func _CheckParents($hWnd, $hItem, $fTop = False)
    $Update = True
    Local $fChecked = False
    If $fTop = False Then $fChecked = _GUICtrlTreeView_GetChecked($hWnd, $hItem)
    If $fChecked = False Then
        Local $hParent = _GUICtrlTreeView_GetParentHandle($hWnd, $hItem)
        If $hParent <> GUICtrlGetHandle($hTreeView) Then
            _GUICtrlTreeView_SetChecked($hWnd, $hParent, True)
            _CheckParents($hWnd, $hParent, True)
        EndIf
    EndIf
EndFunc   ;==>_CheckParents

on trie le tableau (pour le pb de la petite croix)
Intéressant..

j'ai toujours été tres doué pour trouver des facons 'exotiques' de contourner un problème.

Ceci dit je garde dans un coin de ma tête qu'il ne faut pas finir un treeview avec un node a la racine. Ce qui en soit n'est pas hyper contraignant dans la mesure ou souvent je construit mes treeview en mettant les nodes d'abord, et les entrées simples ensuite...

AutoIt Français

[R] Comportement Treeview (parents / enfants)

[R] Comportement Treeview (parents / enfants)

Re: [..] Comportement Treeview (parents / enfants)

Re: [..] Comportement Treeview (parents / enfants)

Re: [..] Comportement Treeview (parents / enfants)

Re: [..] Comportement Treeview (parents / enfants)

Re: [..] Comportement Treeview (parents / enfants)

Re: [..] Comportement Treeview (parents / enfants)

Re: [R] Comportement Treeview (parents / enfants)

Re: [R] Comportement Treeview (parents / enfants)

Re: [R] Comportement Treeview (parents / enfants)

Re: [R] Comportement Treeview (parents / enfants)