AutoIt Français

Bonjour, à tous.

En poursuivant mon petit bonhomme de chemin sur autoit, je me suis heurté à un petit soucis.

Voici un exemple qu'un des membres du forum m'avait fournie il y a un petit moment.

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#region ; variables

$nNot = "(aucune)"


#Region ###
$GuiIntro = GUICreate("GuiIntro", 551, 289, 232, 164)
GUISetBkColor(0xA6CAF0)
GUICtrlCreateGroup("Champ introduction", 5, 2, 540, 78, $BS_CENTER)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Combo1 = GUICtrlCreateCombo("(Aucune)", 16, 29, 513, 25)
GUICtrlSetData(-1, "ESCALADE1|ESCALADE2|ESCALADE3|ESCALADE4")
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Cancel = GUICtrlCreateButton("Annuler", 10, 248, 100, 30, 0)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Continue = GUICtrlCreateButton("Continuer", 440, 248, 100, 30, 0)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
GUICtrlCreateGroup("Champ introduction 2", 5, 80, 540, 78, $BS_CENTER)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Combo2 = GUICtrlCreateCombo("(Aucune)", 16, 107, 513, 25)
GUICtrlSetData(-1, "ESCALADE1|ESCALADE2|ESCALADE3|ESCALADE4")
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Complément", 5, 156, 540, 78, $BS_CENTER)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Complement1 = GUICtrlCreateInput("", 16, 183, 513, 28)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
#EndRegion ### END Koda GUI section ###

GUISetState(@SW_SHOW, $GuiIntro)
GUICtrlSetState($Combo2, $GUI_DISABLE)
GUICtrlSetState($Complement1, $GUI_DISABLE)
;~ GUICtrlSetState($Continue, $GUI_DISABLE)

While 1
    $nMsg = GUIGetMsg(1)
    Select

        Case $nMsg[0] = $GUI_EVENT_CLOSE And $nMsg[1] = $GuiIntro
            Exit

        Case $nMsg[0] = $Combo1 And $nMsg[1] = $GuiIntro
            If GUICtrlRead($Combo1) = $nNot Then
                GUICtrlSetState($Combo2, $GUI_DISABLE)
            ElseIf GUICtrlRead($Combo1) <> $nNot Then
                GUICtrlSetState($Combo2, $GUI_ENABLE)
            EndIf

        Case $nMsg[0] = $Combo2 And $nMsg[1] = $GuiIntro
            If GUICtrlRead($Combo2) = $nNot Then
                GUICtrlSetState($Complement1, $GUI_DISABLE)
            ElseIf GUICtrlRead($Combo2) <> $nNot Then
                GUICtrlSetState($Complement1, $GUI_ENABLE)
            EndIf

;~      Case $nMsg[0] = $Complement1 And $nMsg[1] = $GuiIntro
;~          If GUICtrlRead($Complement1) = "" Then
;~              GUICtrlSetState($Continue, $GUI_DISABLE)
;~          ElseIf GUICtrlRead($Complement1) <> "" Then
;~              GUICtrlSetState($Continue, $GUI_ENABLE)
;~          EndIf



            Exit
    EndSelect
WEnd

Le but ici est d'activer le champ combo2 lorsque le champ combo1 contient une valeur différente de "(aucune)", représentée par la variable $nNot, de même pour le champs input $Complement1

Maintenant si je retire le commentaire sur les lignes

Code : Tout sélectionner

GUICtrlSetState($Continue, $GUI_DISABLE)

et

Code : Tout sélectionner

        Case $nMsg[0] = $Complement1 And $nMsg[1] = $GuiIntro
            If GUICtrlRead($Complement1) = "" Then
                GUICtrlSetState($Continue, $GUI_DISABLE)
            ElseIf GUICtrlRead($Complement1) <> "" Then
                GUICtrlSetState($Continue, $GUI_ENABLE)
            EndIf

Je tente d'activer le bouton représenté par la variable $Continue lorsque le champs input $Complement1 n'est pas vide, et là ...

... Cela ne fonctionne pas.

J'ai effectué quelque recherche dans l'aide afin de savoir si je doit utiliser plutot une fonction comme GUICtrlGetState ou bien un interpréteur de champ vide, sans succès.

Si quelqu'un a une idée ?

Si tu enlèves les commentaires d'ici :

Code : Tout sélectionner

;~      Case $nMsg[0] = $Complement1 And $nMsg[1] = $GuiIntro
;~          If GUICtrlRead($Complement1) = "" Then
;~              GUICtrlSetState($Continue, $GUI_DISABLE)
;~          ElseIf GUICtrlRead($Complement1) <> "" Then
;~              GUICtrlSetState($Continue, $GUI_ENABLE)
;~          EndIf

Alors tu dois les rajoutez ou enlever ces lignes :

Code : Tout sélectionner

        Case $nMsg[0] = $Combo2 And $nMsg[1] = $GuiIntro
            If GUICtrlRead($Combo2) = $nNot Then
                GUICtrlSetState($Complement1, $GUI_DISABLE)
            ElseIf GUICtrlRead($Combo2) <> $nNot Then
                GUICtrlSetState($Complement1, $GUI_ENABLE)
            EndIf

Cordialement Narmeke

Je craint ne pas saisir la nuance.

J'ai ajouté ces commentaire juste pour montrer ce qui fonctionne, et ce qui ne fonctionne pas.

Si je relie votre suggestion, cela ne fait pas avancer mon probleme.

En vous remerciant

Il faut utiliser GUIRegisterMsg() afin de lire la saisie dans l'InputBox car la boucle de message ne suffit pas.

Je sent poindre la grande question : Mais comment faire.

Et bien tout récemment, Yogui a proposer un code utilisant cette fonction afin de faire de 'l'Auto-Suggestion' dans un combo ...

En adaptant le code, cela donne quelque chose comme ceci :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#region ; variables
$nNot = "(aucune)"

#Region ###
$GuiIntro = GUICreate("GuiIntro", 551, 289, 232, 164)
GUISetBkColor(0xA6CAF0)
GUICtrlCreateGroup("Champ introduction", 5, 2, 540, 78, $BS_CENTER)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Combo1 = GUICtrlCreateCombo("(Aucune)", 16, 29, 513, 25)
GUICtrlSetData(-1, "ESCALADE1|ESCALADE2|ESCALADE3|ESCALADE4")
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Cancel = GUICtrlCreateButton("Annuler", 10, 248, 100, 30, 0)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Continue = GUICtrlCreateButton("Continuer", 440, 248, 100, 30, 0)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
GUICtrlCreateGroup("Champ introduction 2", 5, 80, 540, 78, $BS_CENTER)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Combo2 = GUICtrlCreateCombo("(Aucune)", 16, 107, 513, 25)
GUICtrlSetData(-1, "ESCALADE1|ESCALADE2|ESCALADE3|ESCALADE4")
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Complément", 5, 156, 540, 78, $BS_CENTER)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
$Complement1 = GUICtrlCreateInput("", 16, 183, 513, 28)
GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
#EndRegion ### END Koda GUI section ###

GUISetState(@SW_SHOW, $GuiIntro)
GUICtrlSetState($Combo2, $GUI_DISABLE)
GUICtrlSetState($Complement1, $GUI_DISABLE)
GUICtrlSetState($Continue, $GUI_DISABLE)


While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $Cancel
            Exit

        Case $Continue
            MsgBox(0, '', 'La Suite')

    EndSwitch
WEnd

Func _WM_COMMAND($hwnd, $msg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0xFFFF)

    Switch $nID
        Case $Combo1
            If GUICtrlRead($Combo1) = $nNot Then
                GUICtrlSetState($Combo2, $GUI_DISABLE)
            Else
                GUICtrlSetState($Combo2, $GUI_ENABLE)
            EndIf

        Case $Combo2
            If GUICtrlRead($Combo2) = $nNot Then
                GUICtrlSetState($Complement1, $GUI_DISABLE)
            Else
                GUICtrlSetState($Complement1, $GUI_ENABLE)
            EndIf

        Case $Complement1
            If GUICtrlRead($Complement1) = "" Then
                GUICtrlSetState($Continue, $GUI_DISABLE)
            Else
                GUICtrlSetState($Continue, $GUI_ENABLE)
            EndIf

    EndSwitch

EndFunc

Bonsoir,

Que puis-je dire ... Whaou !!!

je suppose que tout réside dans la partie

Code : Tout sélectionner

    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0xFFFF)

Je vais l'étudier en profondeur.

Dans l'immédiat, et comme j'ai un timing relativement serré, je vais me contenter d'un simple condition avec une msgbox (j'ai vu que cela marchait).

Merci tout de même Tlem.

Je clos le sujet.

Tout réside dans cette fonction : GUIRegisterMsg()

Lisez la doc et vous verrez tout ce qu'il est possible de faire ...
J'aurais pu me contenter de capturer la saisie du texte, mais je trouve le fait de gérer les événement comme je l'ai fait, tout aussi bien.

AutoIt Français

[R] Activer ou désactiver un bouton si un champs est vide

[R] Activer ou désactiver un bouton si un champs est vide

Re: [..]Activer ou desactiver un bouton si un champs est vide

Re: [..]Activer ou desactiver un bouton si un champs est vide

Re: [..] Activer ou désactiver un bouton si un champs est vide

Re: [..] Activer ou désactiver un bouton si un champs est vide

Re: [r] Activer ou désactiver un bouton si un champs est vide