AutoIt Français

Bonjour
J'ai recommencé à tâter Autoit il a 2 jours et je suis bloqué.

Je m'explique :

-J'ai créé une première GUI dont voici le code obtenu avec KODA :

► Afficher le texte

-Ensuite, je veux que, lorsque je clique sur un des 14 boutons, une fenêtre(GUI ?) spécifique à chaque bouton s'ouvre. Chose que j'arrive à faire pour un seul bouton et c'est là que le problème survient. Je clique sur le bouton "oreillette" et là j'ai une autre fenêtre qui s'ouvre, cependant lorsque je clique sur la croix rouge cette dernière fenêtre se ferme ainsi que la première avec les 14 boutons qui est censé restée ouverte pour me permettre de cliquer sur d'autre boutons etc ...

Voici le code de la fenêtre "oreillette":

► Afficher le texte

Et voici ce que j'ai écrit pour ouvrir la fenêtre "oreillette":

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\calculateur pb bouton.kxf
$Form1_1 = GUICreate("Calculateur", 547, 195, 345, 305)
$Button1 = GUICtrlCreateButton("Oreillette", 8, 8, 96, 21, $WS_GROUP)
$Button2 = GUICtrlCreateButton("Implant 1", 8, 32, 96, 21, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Implant 2", 8, 56, 96, 21, $WS_GROUP)
$Button4 = GUICtrlCreateButton("Poignets", 8, 80, 96, 21, $WS_GROUP)
$Button5 = GUICtrlCreateButton("Relique 1", 8, 104, 96, 21, $WS_GROUP)
$Button6 = GUICtrlCreateButton("Relique 2", 8, 128, 96, 21, $WS_GROUP)
$Button7 = GUICtrlCreateButton("Main principale", 8, 152, 96, 21, $WS_GROUP)
$Button8 = GUICtrlCreateButton("Casque", 112, 8, 96, 21, $WS_GROUP)
$Button9 = GUICtrlCreateButton("Torse", 112, 32, 96, 21, $WS_GROUP)
$Button10 = GUICtrlCreateButton("Mains", 112, 56, 96, 21, $WS_GROUP)
$Button11 = GUICtrlCreateButton("Ceinture", 112, 80, 96, 21, $WS_GROUP)
$Button12 = GUICtrlCreateButton("Jambières", 112, 104, 96, 21, $WS_GROUP)
$Button13 = GUICtrlCreateButton("Bottes", 112, 128, 96, 21, $WS_GROUP)
$Button14 = GUICtrlCreateButton("Main secondaire", 112, 152, 96, 21, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
case $Button1
  #include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\oreillette.kxf
$Form2 = GUICreate("Oreillette", 221, 164, 733, 345)
$Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
$Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
$Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
$Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
$Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
$Input1 = GUICtrlCreateInput("Input1", 128, 8, 80, 21)
$Input2 = GUICtrlCreateInput("Input2", 128, 32, 80, 21)
$Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
$Input3 = GUICtrlCreateInput("Input3", 128, 56, 80, 21)
$Input4 = GUICtrlCreateInput("Input4", 128, 80, 80, 21)
$Input5 = GUICtrlCreateInput("Input5", 128, 104, 80, 21)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit

EndSwitch
WEnd

EndSwitch
WEnd

Pouvez-vous corriger mon code, afin que seule la fenêtre "oreillette" se ferme en cliquant sur la croix rouge, laissant la fenêtre "calculateur" toujours active pour me permettre de cliquer sur les autres boutons.

Merci d'avance Miryhan

P.S : J'espère avoir correctement formater le message.

Quand tu cliques sur la croix, dans la boucle ça commande le 'Exit' => ferme le script
Il faut que ça commande uniquement la fermeture de la gui concernée

Code : Tout sélectionner

   Case $GUI_EVENT_CLOSE
       GuiDelete($Form2)
       Exitloop

Merci à toi problème résolu. J'ai pu faire qu'en cliquant sur un bouton, une fenêtre spécifique aux boutons s'ouvre et en cliquant sur la croix rouge la dite fenêtre se ferme, ceci pour les quatorze boutons.

Cependant seul le bouton "oreillette" me pose un problème :
Je n'arrive pas à rouvrir la fenêtre "oreillette" après l'avoir fermée. Alors que pour les 13 autres boutons aucun soucis. (Testé plusieurs fois)

Voici le code :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\calculateur swtor.kxf
$Form1 = GUICreate("Calculateur", 625, 376, 466, 299)
$Group1 = GUICtrlCreateGroup("Stats", 8, 184, 169, 185)
$Label1 = GUICtrlCreateLabel("Vigueur :", 16, 200, 46, 17)
$Label2 = GUICtrlCreateLabel("Présence :", 16, 224, 55, 17)
$Label3 = GUICtrlCreateLabel("Visée :", 16, 248, 36, 17)
$Label4 = GUICtrlCreateLabel("Astuce :", 16, 272, 43, 17)
$Label5 = GUICtrlCreateLabel("Endurance :", 16, 296, 62, 17)
$Label6 = GUICtrlCreateLabel("Volonté :", 16, 320, 46, 17)
$Label7 = GUICtrlCreateLabel("Expertise :", 16, 344, 53, 17)
$Label8 = GUICtrlCreateLabel("", 88, 200, 36, 17)
$Label9 = GUICtrlCreateLabel("", 88, 224, 36, 17)
$Label10 = GUICtrlCreateLabel("", 88, 248, 42, 17)
$Label11 = GUICtrlCreateLabel("", 88, 272, 42, 17)
$Label12 = GUICtrlCreateLabel("", 88, 296, 42, 17)
$Label13 = GUICtrlCreateLabel("", 88, 320, 42, 17)
$Label14 = GUICtrlCreateLabel("", 88, 344, 42, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup("Bonus", 184, 184, 193, 185)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Button1 = GUICtrlCreateButton("Oreillette", 8, 8, 96, 21, $WS_GROUP)
$Button2 = GUICtrlCreateButton("Implant 1", 8, 32, 96, 21, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Implant 2", 8, 56, 96, 21, $WS_GROUP)
$Button4 = GUICtrlCreateButton("Poignets", 8, 80, 96, 21, $WS_GROUP)
$Button5 = GUICtrlCreateButton("Relique 1", 8, 104, 96, 21, $WS_GROUP)
$Button6 = GUICtrlCreateButton("Relique 2", 8, 128, 96, 21, $WS_GROUP)
$Button7 = GUICtrlCreateButton("Main principale", 8, 152, 96, 21, $WS_GROUP)
$Button8 = GUICtrlCreateButton("Casque", 112, 8, 96, 21, $WS_GROUP)
$Button9 = GUICtrlCreateButton("Torse", 112, 32, 96, 21, $WS_GROUP)
$Button10 = GUICtrlCreateButton("Mains", 112, 56, 96, 21, $WS_GROUP)
$Button11 = GUICtrlCreateButton("Ceinture", 112, 80, 96, 21, $WS_GROUP)
$Button12 = GUICtrlCreateButton("Jambières", 112, 104, 96, 21, $WS_GROUP)
$Button13 = GUICtrlCreateButton("Bottes", 112, 128, 96, 21, $WS_GROUP)
$Button14 = GUICtrlCreateButton("Main secondaire", 112, 152, 96, 21, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
case $Button1
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\oreillette.kxf
   $Form2 = GUICreate("Oreillette", 221, 164, 856, 333)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form2)
         ExitLoop
   EndSwitch
   WEnd
Case $Button2
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\implant 1.kxf
   $Form3 = GUICreate("Implant 1", 221, 164, 851, 336)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form3)
         ExitLoop
   EndSwitch
   WEnd
Case $Button3
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\implant 2.kxf
   $Form4 = GUICreate("Implant 2", 221, 164, 852, 337)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form4)
         ExitLoop
   EndSwitch
   WEnd
case $Button4
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\poignets.kxf
   $Form5 = GUICreate("Poignets", 221, 164, 858, 351)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form5)
         ExitLoop
   EndSwitch
   WEnd
case $Button5
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\relique 1.kxf
   $Form6 = GUICreate("Relique 1", 221, 164, 859, 352)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form6)
         ExitLoop
   EndSwitch
   WEnd
case $Button6
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\relique 2.kxf
   $Form7 = GUICreate("Relique 2", 221, 164, 861, 354)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form7)
         ExitLoop
   EndSwitch
   WEnd
case $Button7
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\main principale.kxf
   $Form8 = GUICreate("Main principale", 221, 164, 861, 353)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form8)
         ExitLoop
   EndSwitch
   WEnd
case $Button8
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\oreillette.kxf
   $Form9 = GUICreate("Casque", 221, 164, 856, 333)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form9)
         ExitLoop
   EndSwitch
   WEnd
case $Button9
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\oreillette.kxf
   $Form10 = GUICreate("Torse", 221, 164, 856, 333)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form10)
         ExitLoop
   EndSwitch
   WEnd
case $Button10
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\oreillette.kxf
   $Form11 = GUICreate("Mains", 221, 164, 856, 333)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form11)
         ExitLoop
   EndSwitch
WEnd
case $Button11
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\oreillette.kxf
   $Form12 = GUICreate("Ceinture", 221, 164, 856, 333)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form12)
         ExitLoop
   EndSwitch
WEnd
case $Button12
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\oreillette.kxf
   $Form13 = GUICreate("Jambière", 221, 164, 856, 333)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form13)
         ExitLoop
   EndSwitch
WEnd
case $Button13
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\oreillette.kxf
   $Form14 = GUICreate("Bottes", 221, 164, 856, 333)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form14)
         ExitLoop
   EndSwitch
WEnd
case $Button14
   #include <ButtonConstants.au3>
   #include <EditConstants.au3>
   #include <GUIConstantsEx.au3>
   #include <StaticConstants.au3>
   #include <WindowsConstants.au3>
   #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\oreillette.kxf
   $Form15 = GUICreate("Main secondaire", 221, 164, 856, 333)
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Label3 = GUICtrlCreateLabel("Bonus 1 ", 8, 56, 46, 17)
   $Label4 = GUICtrlCreateLabel("Bonus 2 :", 8, 80, 49, 17)
   $Label5 = GUICtrlCreateLabel("Bonus 3 :", 8, 104, 49, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21)
   $Input3 = GUICtrlCreateInput("", 128, 56, 80, 21)
   $Input4 = GUICtrlCreateInput("", 128, 80, 80, 21)
   $Input5 = GUICtrlCreateInput("", 128, 104, 80, 21)
   $Button1 = GUICtrlCreateButton("Ok", 8, 128, 203, 25, $WS_GROUP)
   GUISetState(@SW_SHOW)
   #EndRegion ### END Koda GUI section ###

   While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
         GUIDelete($form15)
         ExitLoop
   EndSwitch
   WEnd
EndSwitch
WEnd

J'ai essayé plusieurs "truc" mais cela n'a rien donné.

Miryhan

Bonsoir Miryhan.

Votre code est bien long et complexe pour faire aussi peu de chose.
Tout d'abord la répétition des includes n'est pas nécessaire. Déclarez les une seule fois en début de script.

Ensuite, la déclaration de variables c'est bien, mais uniquement si elle sert à quelque chose. Là vous utilisez une variable pour vos labels alors que visiblement vous n'avez pas l'intention de les modifier.

Pour finir, je dirais que les boucles imbriquées on rarement fait bon ménage.
Au lieu d'utiliser une boucle pour chacune de vos fenêtres, utilisez plutôt le mode message avancé : GUIGetMsg(1)
Ou encore plus adapté à la situation, le mode événementiel.

Bonsoir

Bon à savoir pour les includes. Pour les variables, je sais que je vais les utiliser plus tard, mais dans l'immédiat elles ne servent à rien.
Les boucles imbriquées comme vous dites, sont le seul moyen que j'ai trouvé, avec mes connaissances actuelles, pour arriver à mes fins, mais je vais étudier tout ça.

Je met le sujet en résolu, le temps de comprendre le mode événementiel et je le rouvrirai au cas où.

En tout cas merci et bonne nuit, ou pas

Je viens de comprendre l'histoire des variables, certaines ne vont me servir à rien.

Voilà ce que j'ai pu sortir après avoir consulter votre lien. Ceci est la fonction "déclenchée" par pression du bouton "oreillette" :

► Afficher le texte

Elle fonctionne comme prévue, tout comme les autres. Une fonction EXIT a été faite et fonctionne comme attendue.

J'ai cependant quelques questions :
-Les commandes Opt("GUIOnEventMode", 0) et Opt("GUIOnEventMode", 1) de la fonction ci-dessus et ce qu'il y a entre, sont ce que j'ai trouvé pour faire fonctionner le tout. Est-ce qu'il existe une autre façon d'ouvrir et de fermée la fenêtre "oreillette" tout en laissant la première ouverte ? J'ai bien essayé avec Opt("GUIOnEventMode", 1), mais pas reussi.
-Est-ce que les #Region ### START Koda GUI section ### Form=e:\autoit\koda\forms\swtor\oreillette.kxf et #EndRegion ### END Koda GUI section ### sont utile au code ?

Merci d'avance

Bonjour Miryhan.
Les lignes de commentaires créées par Koda ne sont effectivement pas indispensable (ceci est valable pour toute ligne commençant par un point virgule car ce sont des lignes de commentaire).

Concernant le mode événementiel, il faut le voir différemment du mode normal, car vous devez déterminer explicitement l'action pour chaque élément de l'interface qui doit être utilisé. Lorsque vous construisez une interface graphique, chacun des éléments qui la compose (bouton, label, image, bouton de fermeture, bouton de réduction, etc ...) peut renvoyer un 'message' lorsqu'il est cliqué. Vous pouvez mettre Koda dans ce type de mode (Menu option, 'Générateur de code' puis cochez la case 'Générer le code événementiel').

Vous trouverez ci-dessous un code d'exemple qui utilise le mode événementiel ainsi que quelques indications sur la manière de construire un code dans ce mode :

► Afficher le texte

Code : Tout sélectionner

; On commence par déclarer les includes qui serviront pour la suite du code.
; Cette étape est très importante car elle va permettre à votre script de lire chaque fichier au3 déclaré
; comme include et donc d'initialiser les variables qui y sont déclarées.
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>

; Selon les besoins, on rajoute ici certains traitements nécessaires avant d'attaquer la déclaration de quoi que ce soit.
; On peux par exemple rajouter du code qui va vérifier que le script n'est lancé qu'une seule fois.
; Si le script existe déjà en mémoire, alors on referme le dernier lancé.
If _Singleton(@ScriptName, 1) = 0 Then Exit


; Ici, généralement on déclare les variables qui sont propres au script et qui serviront pour la suite du code.
; On déclare ces variables globalement afin qu'elles soient accessible de n'importe quelle partie du code.
Global $MaVariable = "Ma valeur"


; Selon les besoins, on rajoute ici certains traitements nécessaires avant d'attaquer l'interface graphique principale.
FileInstall("La ressource dont j'aurais besoins plus tard dans le code", "L'endroit ou je vais copier cette ressource")


; A partir d'ici on va attaquer la construction de l'interface graphique principale.
; Pour commencer, j'indique que je vais utiliser le mode événementiel :
Opt("GUIOnEventMode", 1)

; Puis je commence l'interface :
; Pour chaque élément utilisable dans l'interface, j'attribue une fonction (morceau de code qui fait ce qu'on lui dit de faire).
; Ci dessous, GUISetOnEvent permet de surveiller l'événement de fermeture de la GUI
; et lorsque cet événement arrive, c'est la fonction ClicFermetureGUI qui sera lancée.
Global $GUI1 = GUICreate("Ma GUI Principale", 283, 141, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "ClicFermetureGUI1")

; Je n'utilise pas de variable pour mémoriser l'ID de ce contrôle car je n'aurais jamais besoin de le modifier.
GUICtrlCreateLabel("Label1", 128, 30, 36, 17)
Global $GUI1_Btn1 = GUICtrlCreateButton("Bouton1", 40, 24, 75, 25)
GUICtrlSetOnEvent(-1, "ClicBouton1") ; Fonction attribuée à l'événement du clic sur le bouton 1.

; Je n'utilise pas de variable pour mémoriser l'ID de ce contrôle car je n'aurais jamais besoin de le modifier.
GUICtrlCreateLabel("Label2", 128, 62, 36, 17)
Global $GUI1_Btn2 = GUICtrlCreateButton("Bouton2", 40, 56, 75, 25)
GUICtrlSetOnEvent(-1, "ClicBouton2") ; Fonction attribuée à l'événement du clic sur le bouton 2.

; Puisque l'interface graphique est construite, on peux maintenant l'afficher.
GUISetState(@SW_SHOW)


; Ici nous avons la fameuse boucle d'attente. Bien que cela ne soit pas recommandé,
; il est possible de rajouter du code à l'intérieur de celle-ci (attention de ne pas rajouter un code bloquant).
While 1
    Sleep(50)
WEnd


;
; En fin de script, on regroupe les fonctions qui vont être utilisées dans le code.
;

; Fonction attachée à l'événement du clic sur le bouton 1.
Func ClicBouton1()
    ; On écrit ici le code qui doit être excécuté lors du clic sur le bouton 1.

    ; Construction de la GUI N°2
    ; Puisque les variables ci-dessous doivent être déclarée globalement, attention
    ; à ce quelles soient différentes de ce qui à déjà été utilisé !
    Global $GUI2 = GUICreate("Ma GUI N°2", 179, 119, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "ClicFermetureGUIs")

    Global $GUI2_Btn3 = GUICtrlCreateButton("Bouton1 de la GUI 2", 32, 40, 110, 25)
    GUICtrlSetOnEvent(-1, "ClicBtn1GUI2")

    GUICtrlCreateLabel("Label1 de la GUI 2", 32, 16, 110, 17)
    Global $GUI2_Inp1 = GUICtrlCreateInput("Input de la GUI2", 32, 80, 121, 21)

    ; Affichage de la GUI N°2
    GUISetState(@SW_SHOW, $GUI2)
EndFunc

; Fonction attachée à l'événement du clic sur le bouton 2.
Func ClicBouton2()
    ; On écrit ici le code qui doit être excécuté lors du clic sur le bouton 2.

    ; Construction de la GUI N°3
    ; Puisque les variables ci-dessous doivent être déclarée globalement, attention
    ; à ce quelles soient différentes de ce qui à déjà été utilisé !
    Global $GUI3 = GUICreate("Ma GUI N°3", 179, 119, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "ClicFermetureGUIs")

    Global $GUI3_Btn1 = GUICtrlCreateButton("Bouton1 de la GUI 3", 32, 40, 110, 25)
    GUICtrlSetOnEvent(-1, "ClicBtn1GUI3")

    GUICtrlCreateLabel("Label1 de la GUI 2", 32, 16, 110, 17)
    Global $GUI3_Inp1 = GUICtrlCreateInput("Input de la GUI 3", 32, 80, 121, 21)

    ; Affichage de la GUI N°2
    GUISetState(@SW_SHOW, $GUI3)
EndFunc

; Fonction attachée à l'événement du clic sur le bouton 1 de la GUI 2.
Func ClicBtn1GUI2()
    ; On écrit ici le code qui doit être excécuté lors du clic sur le bouton 3.
    MsgBox(64, "Btn", "Le bouton 1 de la GUI 2 a été cliqué." & @CRLF & @CRLF & "Le texte de l'input est : " & @CRLF & GUICtrlRead($GUI2_Inp1))
EndFunc

; Fonction attachée à l'événement du clic sur le bouton 1 de la GUI 3.
Func ClicBtn1GUI3()
    ; On écrit ici le code qui doit être excécuté lors du clic sur le bouton 3.
    MsgBox(64, "Btn", "Le bouton 1 de la GUI 3 a été cliqué.")
EndFunc

; Fonction attachée à l'événement de fermeture de la GUI principale.
Func ClicFermetureGUI1()
    ; On écrit ici le code qui doit être excécuté à la fermeture de la fenêtre principale.
    MsgBox(64, "Exit", "Le bouton de fermeture de la GUI principale a été cliqué.")
    Exit
EndFunc

; Fonction attachée à la fermeture de la GUI 2 et 3
; Cette fonction permet de détruire uniquement la GUI concernée.
; J'aurais pu regrouper ClicFermetureGUI1() et ClicFermetureGUIs() en une seule et même fonction, mais
; pour les besoins de la démonstration je ne l'ai pas fait.
Func ClicFermetureGUIs()
    ; @GUI_WINHANDLE est une variable interne qui renvoi le handle de la fenêtre concernée par le dernier événement.
    MsgBox(64, "Exit", "Le bouton de fermeture de la GUI dont le handle est " & @GUI_WINHANDLE & " a été cliqué.")
    GUIDelete(@GUI_WINHANDLE)
EndFunc

Vous trouverez ci-dessous pratiquement le même code que ci-dessus (j'ai supprimé le superflu), mais conçu différemment. Cette fois ci nous construisons toute l'interface (y compris les fenêtres secondaires) et on affiche uniquement ce dont on a besoin au moment voulu. Je profite de l'occasion pour vous montrer comment gérer plusieurs GUI avec la même fonction de fermeture

:

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1) ; Mode événementiel

; ###############################################################
; ##### Construction de toute la partie interface graphique #####

; Construction de la GUI N°1
Global $GUI1 = GUICreate("Ma GUI Principale", 283, 141, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "ClicFermetureGUIs")

GUICtrlCreateLabel("Label1", 128, 30, 36, 17)
Global $GUI1_Btn1 = GUICtrlCreateButton("Bouton1", 40, 24, 75, 25)
GUICtrlSetOnEvent(-1, "ClicBouton1")

GUICtrlCreateLabel("Label2", 128, 62, 36, 17)
Global $GUI1_Btn2 = GUICtrlCreateButton("Bouton2", 40, 56, 75, 25)
GUICtrlSetOnEvent(-1, "ClicBouton2")
; Fin de construction de la GUI N°1


; Construction de la GUI N°2
Global $GUI2 = GUICreate("Ma GUI N°2", 179, 119, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "ClicFermetureGUIs")

Global $GUI2_Btn3 = GUICtrlCreateButton("Bouton1 de la GUI 2", 32, 40, 110, 25)
GUICtrlSetOnEvent(-1, "ClicBtn1GUI2")

GUICtrlCreateLabel("Label1 de la GUI 2", 32, 16, 110, 17)
Global $GUI2_Inp1 = GUICtrlCreateInput("Input de la GUI2", 32, 80, 121, 21)
; Fin de construction de la GUI N°2


; Construction de la GUI N°3
Global $GUI3 = GUICreate("Ma GUI N°3", 179, 119, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "ClicFermetureGUIs")

Global $GUI3_Btn1 = GUICtrlCreateButton("Bouton1 de la GUI 3", 32, 40, 110, 25)
GUICtrlSetOnEvent(-1, "ClicBtn1GUI3")

GUICtrlCreateLabel("Label1 de la GUI 2", 32, 16, 110, 17)
Global $GUI3_Inp1 = GUICtrlCreateInput("Input de la GUI 3", 32, 80, 121, 21)
; Fin de construction de la GUI N°3

; ##### Fin de la construction de toute la partie interface graphique #####
; #########################################################################

; Affichage de la GUI principale (N°1)
GUISetState(@SW_SHOW, $GUI1)


While 1
    Sleep(50)
WEnd

Func ClicBouton1()
    GUISetState(@SW_HIDE, $GUI1) ; Masque la GUI principale
    GUISetState(@SW_SHOW, $GUI2) ; Affiche la GUI 2
EndFunc

Func ClicBouton2()
    GUISetState(@SW_HIDE, $GUI1) ; Masque la GUI principale
    GUISetState(@SW_SHOW, $GUI3) ; Affiche la GUI 2
EndFunc

Func ClicBtn1GUI2()
    MsgBox(64, "Btn", "Le bouton 1 de la GUI 2 a été cliqué." & @CRLF & @CRLF & "Le texte de l'input est : " & @CRLF & GUICtrlRead($GUI2_Inp1))
EndFunc

Func ClicBtn1GUI3()
    MsgBox(64, "Btn", "Le bouton 1 de la GUI 3 a été cliqué.")
EndFunc

Func ClicFermetureGUI1()
    MsgBox(64, "Exit", "Le bouton de fermeture de la GUI principale a été cliqué.")
    Exit
EndFunc

Func ClicFermetureGUIs()
    MsgBox(64, "Exit", "Le bouton de fermeture de la GUI dont le handle est " & @GUI_WINHANDLE & " a été cliqué.")

    ; Test si on à cliqué le bouton de fermeture de la GUI principale. Si oui, quitte le script.
    If WinGetHandle(@GUI_WINHANDLE) = $GUI1 Then Exit

    GUISetState(@SW_HIDE, @GUI_WINHANDLE) ; Cache la fenêtre qui renvoi l'événement
    GUISetState(@SW_SHOW, $GUI1) ; Ré-affiche la GUI principale
EndFunc

Opt("GUIOnEventMode", 1) doit être mis 1 seule fois en début de script
En mode évènementiel GUIGetMsg() ne marche pas
Les #Region peuvent très bien être virés

D'autre part, comme toutes les gui "filles" ont un contenu identique tu peux optimiser le code

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
Opt("GUIOnEventMode", 1)

Global $radio[3]   ; déclare le tableau des boutons radio
Global $item_gui, $titre="", $Input1, $Input2 

$gui = GUICreate("Calculateur", 200, 150, 100, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
$radio[0] = GUICtrlCreateRadio("Oreillette", 20, 40, 120, 20)
$radio[1] = GUICtrlCreateRadio("Poignets", 20, 58, 120, 20)
$radio[2] = GUICtrlCreateRadio("Main principale", 20, 76, 120, 20)
$Button = GUICtrlCreateButton("Configurer", 50, 100, 80, 25)
GUICtrlSetOnEvent($Button, "_Config")
GUISetState(@SW_SHOW)

While 1
   Sleep(10)
WEnd


Func _Config()
   If $titre<>"" Then GuiDelete($item_gui)
   For $i = 0 To 2        ; parcourt le tableau des boutons radio
      If _IsChecked($radio[$i]) Then $titre = GUICtrlRead($radio[$i], 1)  ; lit le texte du bouton radio coché
   Next
   $item_gui = GUICreate($titre)          ; donne ce nom à la gui
   GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
   $Label1 = GUICtrlCreateLabel("Vigueur :", 8, 8, 46, 17)
   $Label2 = GUICtrlCreateLabel("Endurance :", 8, 32, 62, 17)
   $Input1 = GUICtrlCreateInput("", 128, 8, 80, 21)
   $Input2 = GUICtrlCreateInput("", 128, 32, 80, 21) 
   $Button2 = GUICtrlCreateButton("Enregistrer", 50, 100, 80, 25)
   GUICtrlSetOnEvent($Button2, "_Enregistrer")
   GUISetState(@SW_SHOW)
EndFunc  

Func _Enregistrer()
   $valeur1 = GuiCtrlRead($Input1)
   $valeur2 = GuiCtrlRead($Input2)
   Msgbox(0,"", "Pour " & $titre &@crlf& "Vigueur = " & $valeur1 &@crlf& "Endurance = " & $valeur2)
   GuiDelete($item_gui)
EndFunc  

Func SpecialEvents()
    Switch @GUI_CtrlId    ; d'où vient le clic ?
        Case $GUI_EVENT_CLOSE    ; si clic sur la croix
              If @GUI_WinHandle =  $gui Then   ; si la gui d'origine du clic est la principale 
                   Exit          ; on ferme tout
              Else          ; sinon
                   GuiDelete(@GUI_WinHandle)   ; on ferme juste la gui concernée
              EndIf
    EndSwitch
EndFunc  

Func _IsChecked($iControlID)
    Return BitAND(GUICtrlRead($iControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked

Edit
J'avais pas vu ton message Thierry mais comme le code n'est pas réellement un doublon je le laisse

Bonjour
Merci à vous pour l'aide que vous m’avez apportée.

Je me suis servi du code de Mikell pour pouvoir rendre fonctionnel les 14 boutons radio. Du coup, je peux enfin clore le sujet.

Je sais que d'autre problèmes vont se poser. Cependant je préfère essayer de les résoudre par moi même avant

Miryhan

AutoIt Français

[R] Problème fermeture GUI

[R] Problème fermeture GUI

Re: [..] Problème fermeture GUI

Re: [..] Problème fermeture GUI

Re: [..] Problème fermeture GUI

Re: [..] Problème fermeture GUI

Re: [R] Problème fermeture GUI

Re: [..] Problème fermeture GUI

Re: [..] Problème fermeture GUI

Re: [..] Problème fermeture GUI