AutoIt Français

Bonjour,

Voilà je récupère les données d'un fichier pour les mettre dans une ListView.

Je voudrais que lorsque fichier est lu, s'il trouve le terme "NIO", il me mette la police en gras et en rouge...

Je fais:

Code : Tout sélectionner

If StringInStr($sString, "NIO") Then
_GUICtrlListView_SetTextColor($hListView, $CLR_RED)

mais ça ne fonctionne pas... ça me met tout mon texte en rouge...

Ci joint le code:

► Afficher le texte

Bonjour,
Le lien suivant devrait faire ce que tu cherches : http://www.autoitscript.com/forum/topic ... listviews/

Cdlt, FireFox.

Merci beaucoup.

Par contre j'arrive bien à le faire fonctionne dans un programme simple, mais dans mon application dans laquelle je veux l'intégrer ça ne fonctionne pas

Code OK:

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#include <FontConstants.au3>
#include <GuiListView.au3>
#include <WinAPI.au3>
#include <ButtonConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#Include <File.au3>
#include <Array.au3>
#include <SliderConstants.au3>
#include <ListviewConstants.au3>
#include <ScreenCapture.au3>
#include <GuiTreeView.au3>
#include <FTPEx.au3>
#include <String.au3>
#include <Date.au3>

#include <ArrayEx.au3>
#include <EditConstants.au3>

;Opt( "MustDeclareVars", 1 )

Global $hGui, $hLV, $hLVfont, $hLVfontBold, $aColors[1][1], $hListView2, $sString

MainFunc()

Func MainFunc()
    $hGui = GUICreate("ListView with a few colored and bold cells", 549, 310, 400, 200)

    ; Create ListView control
    Local $idLV = GUICtrlCreateListView("", 10, 10, 529, 290, $GUI_SS_DEFAULT_LISTVIEW, BitOR( $WS_EX_CLIENTEDGE, $LVS_EX_FULLROWSELECT))
    GUICtrlSetFont(-1, 8, 400, 0, "Tahoma")
    $hLV = ControlGetHandle($hGui, "", $idLV)
    _GUICtrlListView_AddColumn($hLV, "Column 0")

    local $File = FileRead("test.1")
    Local $aString = _StringToArray2D($File, @CRLF, ";", 1)
    ReDim $aColors[UBound($aString) - 1]
    For $i = 0 To UBound($aString) - 1
        Local $sString = ""
    For $j = 0 To UBound($aString, 2) - 1
        $sString &= " " & $aString[$i][$j]
    Next

    $sString = StringRegExpReplace($sString, "'", "" )
    If StringInStr($sString, "NIO") Or  StringInStr($sString, "nicht auswertbar") Then
        $aColors[$i] = ColorConvert(0xFF0000)
    EndIf

    _GUICtrlListView_AddItem($hLV, $sString)
Next

    Local $hDC = _WinAPI_GetDC($hLV)
    Local $hFont = _SendMessage($hLV, $WM_GETFONT)
    Local $hObject = _WinAPI_SelectObject($hDC, $hFont)
    Local $lvLOGFONT = DllStructCreate($tagLOGFONT)
    Local $aRet = DllCall('gdi32.dll', 'int', 'GetObjectW', 'ptr', $hFont, 'int', DllStructGetSize($lvLOGFONT), 'ptr', DllStructGetPtr($lvLOGFONT))
    _WinAPI_SelectObject($hDC, $hObject)
    _WinAPI_ReleaseDC($hLV, $hDC)
    $hLVfont = _WinAPI_CreateFontIndirect( $lvLOGFONT )
    Local $iWeight = BitOR( DllStructGetData( $lvLOGFONT, "Weight" ), $FW_BOLD )
    DllStructSetData( $lvLOGFONT, "Weight", $iWeight )
    $hLVfontBold = _WinAPI_CreateFontIndirect( $lvLOGFONT )
    _GUICtrlListView_SetColumnWidth($hLV, 0, $LVSCW_AUTOSIZE)
    ; Use WM_NOTIFY events to draw the cells
    GUIRegisterMsg( $WM_NOTIFY, "WM_NOTIFY" )

    ; Show GUI
    GUISetState( @SW_SHOW, $hGui )

    ; Message loop
    Local $iMsg
    While 1
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd
    GUIDelete( $hGui )
    Exit

EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom

        Case $hLV

            Switch $iCode

                Case $NM_CUSTOMDRAW
                    Local $tNMLVCUSTOMDRAW = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                    Local $dwDrawStage = DllStructGetData($tNMLVCUSTOMDRAW, "dwDrawStage")

                    Switch $dwDrawStage                                                 ; Holds a value that specifies the drawing stage

                        Case $CDDS_PREPAINT
                            ; Before the paint cycle begins
                            Return $CDRF_NOTIFYITEMDRAW                         ; Notify the parent window of any item-related drawing operations

                        Case $CDDS_ITEMPREPAINT
                            ; Before painting an item
                            Return $CDRF_NOTIFYSUBITEMDRAW                  ; Notify the parent window of any subitem-related drawing operations

                        Case BitOR( $CDDS_ITEMPREPAINT, $CDDS_SUBITEM )
                            ; Before painting a subitem
                            Local $dwItemSpec = DllStructGetData($tNMLVCUSTOMDRAW, "dwItemSpec")              ; Item index
                            Local $iSubItem = DllStructGetData($tNMLVCUSTOMDRAW, "iSubItem")                  ; Subitem index
                            Local $hDC = DllStructGetData($tNMLVCUSTOMDRAW, "HDC")                            ; Handle to the item's device context
                            If $aColors[$dwItemSpec] Then ;[$iSubItem]
                                _WinAPI_SelectObject($hDC, $hLVfontBold)                                        ; Bold font
                            Else
                                _WinAPI_SelectObject($hDC, $hLVfont)                                            ; Normal font
                            EndIF
                            DllStructSetData( $tNMLVCUSTOMDRAW, "ClrText", $aColors[$dwItemSpec])  ; Forecolor of item text[$iSubItem]
                            Return $CDRF_NEWFONT                                        ; $CDRF_NEWFONT must be returned after changing font or colors

                    EndSwitch

            EndSwitch

    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc

;RGB to BGR or BGR to RGB
Func ColorConvert($iColor)
    Return BitOR(BitAND($iColor, 0x00FF00), BitShift(BitAND($iColor, 0x0000FF), -16), BitShift(BitAND($iColor, 0xFF0000), 16))
EndFunc

Un bout de mon autre programme dans lequel je t'ente d'intégrer:

► Afficher le texte

Code : Tout sélectionner

Func _FillListViewer()
    Local $aString = _StringToArray2D($Display, @CRLF, ";", 1)
    If UBound($aString) - 1 < 0 Then Return

    ReDim $aColors[UBound($aString) - 1]
    $hLV = ControlGetHandle($MainGUI, "", $hListView2)

For $i = 0 To UBound($aString) - 1
    Local $sString = ""
    For $j = 0 To UBound($aString, 2) - 1
        $sString &= " " & $aString[$i][$j]
    Next
    $sString = StringRegExpReplace($sString, "'", "" )

    If StringInStr($sString, "NIO") Or StringInStr($sString, "nicht auswertbar") Then
        $aColors[$i] = ColorConvert(0xFF0000)
    Else

    EndIf

    _GUICtrlListView_AddItem($hListView2, $sString)
Next

    Local $hDC = _WinAPI_GetDC($hListView2)
    Local $hFont = _SendMessage($hListView2, $WM_GETFONT)
    Local $hObject = _WinAPI_SelectObject($hDC, $hFont)
    Local $lvLOGFONT = DllStructCreate($tagLOGFONT)
    Local $aRet = DllCall('gdi32.dll', 'int', 'GetObjectW', 'ptr', $hFont, 'int', DllStructGetSize($lvLOGFONT), 'ptr', DllStructGetPtr($lvLOGFONT))
    _WinAPI_SelectObject($hDC, $hObject)
    _WinAPI_ReleaseDC($hListView2, $hDC)
    $hListView2font = _WinAPI_CreateFontIndirect( $lvLOGFONT )
    Local $iWeight = BitOR( DllStructGetData( $lvLOGFONT, "Weight" ), $FW_BOLD )
    DllStructSetData( $lvLOGFONT, "Weight", $iWeight )
    $hListView2fontBold = _WinAPI_CreateFontIndirect( $lvLOGFONT )
    _GUICtrlListView_SetColumnWidth($hListView2, 0, $LVSCW_AUTOSIZE)

EndFunc

Func ColorConvert($iColor)
    Return BitOR(BitAND($iColor, 0x00FF00), BitShift(BitAND($iColor, 0x0000FF), -16), BitShift(BitAND($iColor, 0xFF0000), 16))
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $tInfo

    Local $hWndListView1 = $ListView1
    If Not IsHWnd($hWndListView1) Then $hWndListView1 = GUICtrlGetHandle($ListView1)
    Local $hWndListView3 = $ListView3
    If Not IsHWnd($hWndListView3) Then $hWndListView3 = GUICtrlGetHandle($ListView3)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hWndListView1
            Switch $iCode
                Case $NM_DBLCLK
                    If _GUICtrlListView_GetNextItem($ListView1) = -1 And _GUICtrlListView_GetItemText($ListView1, $IndexItemListView) = "" Then Return
                    If $fichierOK = True Then
                        GUIDelete($child)
                    EndIf
                        _EffacementListViewer()
                        $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    If _GUICtrlListView_GetNextItem($ListView1) = -1 And _GUICtrlListView_GetItemText($ListView1, $IndexItemListView) = "" Then
                        Return
                    Else
                        $IndexItemListView = _GUICtrlListView_GetNextItem($ListView1)
                        $FileToOpen = _GUICtrlListView_GetItemText($ListView1, $IndexItemListView)
                        _OpenAndLoadAll()
                    EndIf
            EndSwitch
        Case $hWndListView3
            Switch $iCode
                Case $NM_DBLCLK
                    If _GUICtrlListView_GetNextItem($ListView3) = -1 Then
                        Return
                    Else
                        $IndexItemListView = _GUICtrlListView_GetNextItem($ListView3)
                        $ParameterFrom = _GUICtrlListView_GetItemText($ListView3, $IndexItemListView)
                        _OpenCurveExe()
                    EndIf
                EndSwitch

        Case $NM_CUSTOMDRAW
            Local $tNMLVCUSTOMDRAW = DllStructCreate($tagNMLVCUSTOMDRAW, $ilParam)
            Local $dwDrawStage = DllStructGetData($tNMLVCUSTOMDRAW, "dwDrawStage")

            Switch $dwDrawStage                                                 ; Holds a value that specifies the drawing stage

                Case $CDDS_PREPAINT
                    ; Before the paint cycle begins
                    Return $CDRF_NOTIFYITEMDRAW                         ; Notify the parent window of any item-related drawing operations

                Case $CDDS_ITEMPREPAINT
                    ; Before painting an item
                    Return $CDRF_NOTIFYSUBITEMDRAW                  ; Notify the parent window of any subitem-related drawing operations

                    Case BitOR($CDDS_ITEMPREPAINT, $CDDS_SUBITEM)
                        ; Before painting a subitem
                        Local $dwItemSpec = DllStructGetData($tNMLVCUSTOMDRAW, "dwItemSpec")              ; Item index
                        Local $iSubItem = DllStructGetData($tNMLVCUSTOMDRAW, "iSubItem")                  ; Subitem index
                        Local $hDC = DllStructGetData($tNMLVCUSTOMDRAW, "HDC")                            ; Handle to the item's device context
                        If $aColors[$dwItemSpec] Then ;[$iSubItem]
                            _WinAPI_SelectObject($hDC, $hListView2fontBold)                                        ; Bold font
                        Else
                            _WinAPI_SelectObject($hDC, $hListView2font)                                            ; Normal font
                        EndIF
                        DllStructSetData($tNMLVCUSTOMDRAW, "ClrText", $aColors[$dwItemSpec])  ; Forecolor of item text[$iSubItem]
                        Return $CDRF_NEWFONT                                        ; $CDRF_NEWFONT must be returned after changing font or colors

                EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Merci.

Y'a du mieux... J'ai oublié de mettre

Code : Tout sélectionner

Case $hLV
            Switch $iCode

Gnéééé

Par contre phénomène bizarre... Ca colorie pas au moment de le génération de ma ListView mais ça change de couleur quand je clique sur le ligne qui devrais se colorier...

Hugues a écrit : Par contre phénomène bizarre... Ca colorie pas au moment de le génération de ma ListView mais ça change de couleur quand je clique sur le ligne qui devrais se colorier...

Essaye un _WinAPI_RedrawWindow en passant le handle de la listview.

Cdlt, FireFox.

Grrr Je tourne en rond... En plus vient se greffer un problème avec la ligne

Code : Tout sélectionner

If $aColors[$dwItemSpec] Then

.

Pfff please help...

C'est ben compliqué tout ça...

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <FontConstants.au3>
#include <WinAPI.au3>

Global $Font1 = _WinAPI_CreateFont(14, 0, 0, 0, $FW_BOLD), $test = "6"

$hGUI = GUICreate("Test", 300, 200, -1, 200)
$hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems|", 10, 10, 280, 180, $LVS_REPORT, $WS_EX_CLIENTEDGE)
_GUICtrlListView_SetExtendedListViewStyle($hListView, _ 
        BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
For $i = 1 To 10
    _GUICtrlListView_AddItem($hListView, "Item" & $i)
    _GUICtrlListView_AddSubItem($hListView, $i - 1, "SubItem1" & $i, 1)
    _GUICtrlListView_AddSubItem($hListView, $i - 1, "SubItem2" & $i, 2)
Next
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState()

Sleep(500)
$test = "3"
Msgbox(0,"", "maintenant on check le " & $test)
_WinAPI_RedrawWindow($hListView, "", "", BitOR($RDW_INVALIDATE, $RDW_UPDATENOW))

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

_WinAPI_DeleteObject($Font1)

;=====================================================

Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                    Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                    If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                    If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
                    Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                    Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                    Local $iColor, $hDC
                    $hDC = DllStructGetData($tCustDraw, "hdc")
            ; >>>>> check texte item ou subitem
                   $text = _GUICtrlListView_GetItemText($hListView, $iItem) ;, 1) 
             ; >>>>>>> condition
                   If StringInStr($text, $test) Then 
                          $iColor = RGB2BGR(0xff0000)
                          _WinAPI_SelectObject($hDC, $Font1)
                          DllStructSetData($tCustDraw, "clrText", $iColor)
                     EndIf
                    Return $CDRF_NEWFONT
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY


Func RGB2BGR($iColor)
    Return BitAND(BitShift(String(Binary($iColor)), 8), 0xFFFFFF)
EndFunc   ;==>RGB2BGR()

NB : Faut pas se tromper de Switch, Case $NM_CUSTOMDRAW teste un $iCode, pas un $hWndFrom

Je dois être franchement très c**

Je n'arrive pas à le faire fonctionner...

D'une part, dans mon code j'ai:

Code : Tout sélectionner

    $hListView2 = GUICtrlCreateListView("", 664, 8, 337, 529, BitOR($GUI_SS_DEFAULT_LISTVIEW, $LVS_NOCOLUMNHEADER), BitOR($WS_EX_CLIENTEDGE, $LVS_EX_FULLROWSELECT))

contre

Code : Tout sélectionner

$hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems|", 10, 10, 280, 180, $LVS_REPORT, $WS_EX_CLIENTEDGE)

Si je met _GUICtrlListView_Create() au lieu de GUICtrlCreateListView(), la mise en forme de ma ListView est complètement faussée... Pfff

Après je pense que mon programme doit être mal structuré pour que ça ne fonctionne pas...

► Afficher le texte

Code : Tout sélectionner

Func _BuildTheMainGui() ;==[Construction du GUI principal]====
    $MainGUI = GUICreate("", 1201, 700, 195, 70)
;==[ListView2]=====================
    $hListView2 = GUICtrlCreateListView("", 664, 8, 337, 529, BitOR($GUI_SS_DEFAULT_LISTVIEW, $LVS_NOCOLUMNHEADER), BitOR($WS_EX_CLIENTEDGE, $LVS_EX_FULLROWSELECT))   GUICtrlSetFont(-1, 8, 400, 0, "Tahoma")
 _GUICtrlListView_AddColumn($hListView2, "", 100)
EndFunc

;ICI JE REMPLIS MA LISTVIEW
Func _FillListViewer()
    Local $aString = _StringToArray2D($Display, @CRLF, ";", 1)
    ;If UBound($aString) - 1 < 0 Then Return

;   ReDim $aColors[UBound($aString) - 1]

For $i = 0 To UBound($aString) - 1
    Local $sString = ""
    For $j = 0 To UBound($aString, 2) - 1
        $sString &= " " & $aString[$i][$j]
    Next
    $sString = StringRegExpReplace($sString, "'", "")
    _GUICtrlListView_AddItem($hListView2, $sString)
Next
   _GUICtrlListView_SetColumnWidth($hListView2, 0, $LVSCW_AUTOSIZE)
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $tInfo

    Local $hWndListView1 = $ListView1
    If Not IsHWnd($hWndListView1) Then $hWndListView1 = GUICtrlGetHandle($ListView1)

    Local $hWndListView2 = $hListView2
    If Not IsHWnd($hWndListView2) Then $hWndListView2 = GUICtrlGetHandle($hListView2)

    Local $hWndListView3 = $ListView3
    If Not IsHWnd($hWndListView3) Then $hWndListView3 = GUICtrlGetHandle($ListView3)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hWndListView1
            Switch $iCode
                Case $NM_DBLCLK
                    If _GUICtrlListView_GetNextItem($ListView1) = -1 And _GUICtrlListView_GetItemText($ListView1, $IndexItemListView) = "" Then Return
                    If $fichierOK = True Then
                        GUIDelete($child)
                    EndIf
                        _EffacementListViewer()
                        $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    If _GUICtrlListView_GetNextItem($ListView1) = -1 And _GUICtrlListView_GetItemText($ListView1, $IndexItemListView) = "" Then
                        Return
                    Else
                        $IndexItemListView = _GUICtrlListView_GetNextItem($ListView1)
                        $FileToOpen = _GUICtrlListView_GetItemText($ListView1, $IndexItemListView)
                        _OpenAndLoadAll()
                    EndIf
            EndSwitch
        Case $hWndListView3
            Switch $iCode
                Case $NM_DBLCLK
                    If _GUICtrlListView_GetNextItem($ListView3) = -1 Then
                        Return
                    Else
                        $IndexItemListView = _GUICtrlListView_GetNextItem($ListView3)
                        $ParameterFrom = _GUICtrlListView_GetItemText($ListView3, $IndexItemListView)
                        _OpenCurveExe()
                    EndIf
                EndSwitch
;Rajout=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
        Case $hListView2
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $ilParam)
                    Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                    If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                    If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
                    Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                    Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                    Local $iColor, $hDC
                    $hDC = DllStructGetData($tCustDraw, "hdc")
                    If StringInStr($sString, "NIO") Or StringInStr($sString, "nicht auswertbar") Then
                          $iColor = RGB2BGR(0xff0000)
                          _WinAPI_SelectObject($hDC, $Font1)
                          DllStructSetData($tCustDraw, "clrText", $iColor)
                     EndIf
                    Return $CDRF_NEWFONT
            EndSwitch
;Fin Rajout=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Désolé de vous ennuyer par mon incompetence...

Nope, tu es juste un peu distrait

Et tu percutes toujours pas sur la différence entre id et handle
Alors bon, oblige-toi à utiliser cette syntaxe :

Code : Tout sélectionner

[color=#BF0000]$ListView[/color] est un [color=#BF0000]id[/color]
$ListView = GUICtrlCreateListView(...)
; [color=#BF0000]$hListView[/color] est un [color=#BF0000]handle[/color] et tu le repères à cause du [color=#BF0000]"h"[/color] de début 
$hListView = GuiCtrlGetHandle($ListView)
; tu remarqueras que _GUICtrlListView_Create retourne un handle
$[color=#BF0000]h[/color]ListView = _GUICtrlListView_Create(...)

Pas de "h" => c'est un id , Ya un "h" => c'est un handle
Tu fais ça à la création de ta listview :

Code : Tout sélectionner

$ListView = GUICtrlCreateListView(....)
$hListView = GuiCtrlGetHandle($ListView)
; suite du script

comme ça ensuite tu as la paix, tu utilises l'un ou l'autre selon ce que réclame (id ou handle) la fonction que tu emploies (bien lire la page concernée du fichier d'aide)

Exemple

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <FontConstants.au3>
#include <WinAPI.au3>

Global $Font1 = _WinAPI_CreateFont(14, 0, 0, 0, $FW_BOLD), $test = "6"

$hGUI = GUICreate("Test", 300, 200, -1, 200)
$ListView = GUICtrlCreateListView("Items|SubItems|", 10, 10, 280, 180, $LVS_REPORT, $WS_EX_CLIENTEDGE)
$hListView = GuiCtrlGetHandle($ListView)
_GUICtrlListView_SetExtendedListViewStyle($hListView, _
        BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
For $i = 1 To 10
    _GUICtrlListView_AddItem($hListView, "Item" & $i)
    _GUICtrlListView_AddSubItem($hListView, $i - 1, "SubItem1" & $i, 1)
    _GUICtrlListView_AddSubItem($hListView, $i - 1, "SubItem2" & $i, 2)
Next
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState()

Sleep(500)
$test = "3"
Msgbox(0,"", "maintenant on check le " & $test)
_WinAPI_RedrawWindow($hListView, "", "", BitOR($RDW_INVALIDATE, $RDW_UPDATENOW))

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

_WinAPI_DeleteObject($Font1)

;=====================================================

Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                    Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                    If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                    If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
                    Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                    Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                    Local $iColor, $hDC
                    $hDC = DllStructGetData($tCustDraw, "hdc")
            ; >>>>> check texte item ou subitem
                   $text = _GUICtrlListView_GetItemText($hListView, $iItem) ;, 1)
             ; >>>>>>> condition
                   If StringInStr($text, $test) Then
                          $iColor = RGB2BGR(0xff0000)
                          _WinAPI_SelectObject($hDC, $Font1)
                          DllStructSetData($tCustDraw, "clrText", $iColor)
                     EndIf
                    Return $CDRF_NEWFONT
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func RGB2BGR($iColor)
    Return BitAND(BitShift(String(Binary($iColor)), 8), 0xFFFFFF)
EndFunc   ;==>RGB2BGR()

Pfff, y arrive pas...

Je ne comprends vraiment pas ce qui ne fonctionne pas...

Ca me change mon item que lorsque je clique sur la ligne ou fait defiler avec les flèches mais pas au moment de la génération de ma ListView...

Ca doit vnir de ma fonction WM_NOTIFY mais où? Je suis sec...

► Afficher le texte

Code : Tout sélectionner

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $tInfo

    Local $hWndListView1 = $ListView1
    If Not IsHWnd($hWndListView1) Then $hWndListView1 = GUICtrlGetHandle($ListView1)

    Local $hWndListView3 = $ListView3
    If Not IsHWnd($hWndListView3) Then $hWndListView3 = GUICtrlGetHandle($ListView3)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        ;Rajout=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
        Case $hListView2
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $ilParam)
                    Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                    If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                    If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
                    Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                    Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                    Local $iColor, $hDC
                    $hDC = DllStructGetData($tCustDraw, "hdc")
                ;-> On test texte item ou subitem
                    $text = _GUICtrlListView_GetItemText($hListView2, $iItem)
                ;-> Condition
                    If StringInStr($text, "NIO") Or StringInStr($text, "nicht auswertbar") Then
                        $iColor = RGB2BGR(0xff0000)
                        _WinAPI_SelectObject($hDC, $Font1)
                        DllStructSetData($tCustDraw, "clrText", $iColor)
                    EndIf
                    Return $CDRF_NEWFONT
            EndSwitch
;Fin Rajout=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
        Case $hWndListView1
            Switch $iCode
                Case $NM_DBLCLK
                    If _GUICtrlListView_GetNextItem($ListView1) = -1 And _GUICtrlListView_GetItemText($ListView1, $IndexItemListView) = "" Then Return
                    If $fichierOK = True Then
                        GUIDelete($child)
                    EndIf
                        _EffacementListViewer()
                        $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    If _GUICtrlListView_GetNextItem($ListView1) = -1 And _GUICtrlListView_GetItemText($ListView1, $IndexItemListView) = "" Then
                        Return
                    Else
                        $IndexItemListView = _GUICtrlListView_GetNextItem($ListView1)
                        $FileToOpen = _GUICtrlListView_GetItemText($ListView1, $IndexItemListView)
                        _OpenAndLoadAll()
                    EndIf

            EndSwitch
        Case $hWndListView3
            Switch $iCode
                Case $NM_DBLCLK
                    If _GUICtrlListView_GetNextItem($ListView3) = -1 Then
                        Return
                    Else
                        $IndexItemListView = _GUICtrlListView_GetNextItem($ListView3)
                        $ParameterFrom = _GUICtrlListView_GetItemText($ListView3, $IndexItemListView)
                        _OpenCurveExe()
                    EndIf
                EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Hmmm
Essaie un

Code : Tout sélectionner

_WinAPI_RedrawWindow($hListView2, "", "", BitOR($RDW_INVALIDATE, $RDW_UPDATENOW))

juste après le remplissage de la listview2
Si ça ne marche pas, c'est probablement ailleurs dans le code et là pour pouvoir te répondre il faudrait que tu postes un script fonctionnel, seul moyen de trouver où ça chie

J'ai essayé

Code : Tout sélectionner

_WinAPI_RedrawWindow($hListView2, "", "", BitOR($RDW_INVALIDATE, $RDW_UPDATENOW))

, mais sans succès...

All right, sujet résolu.

Code : Tout sélectionner

_WinAPI_RedrawWindow($MainGui, "", "", BitOR($RDW_INVALIDATE, $RDW_UPDATENOW))

Merci Mikell pour ta précieuse aide!

AutoIt Français

[R] Changer la police ligne(s) ListView

[R] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView

Re: [..] Changer la police ligne(s) ListView