AutoIt Français

Bonjour à tous.

Voilà j'ai fait un script avec une interface utilisateur. Lorsque je lance le script, l'interface apparait et disparait aussitôt. Je n'arrive pas à voir mon erreur.
Je souhaite que ce soit l'utilisateur qui ferme la fenêtre lorsqu'il a fini. Vous trouverez le script ci-dessous pour m'aider à trouver mon erreur.
D'avance merci.

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <AD.au3>
#include <Array.au3>

_AD_Open()

#Region ### START Koda GUI section ### Form=Création de groupe dans Active Directory.kxf
GUICreate("Création de groupes Admin Locaux", 371, 476, 192, 124)
GUICtrlCreateGroup("", 32, 40, 305, 369)
GUICtrlCreateGroup("", -99, -99, 1, 1)

GUICtrlCreateLabel("Création de groupe Admin locaux", 40, 40, 160, 17)
GUICtrlCreateLabel("Groupe", 64, 86, 39, 17)
GUICtrlCreateLabel("Utilisateur", 64, 158, 50, 17)

; Déclaration des zones de saisies
Global $admingroup = GUICtrlCreateInput("", 64, 104, 241, 25) ; saisie du nom du groupe à créer
Global $utilisateur = GUICtrlCreateInput("", 64, 176, 241, 25) ; saisie du nom de l'utilisateur à ajouter à un groupe

;Déclaration des boutons radios
Global $radio0 = GUICtrlCreateRadio("Vérifier l'existance du groupe", 64, 256, 249, 17)
Global $radio1 = GUICtrlCreateRadio("Ajouter un compte à un groupe déjà exitant", 64, 280, 241, 17)
Global $radio2 = GUICtrlCreateRadio("Créer un groupe et y ajouter un compte utilisateur", 64, 304, 257, 17)

;déclaration des boutons à cliquer
Global $valider = GUICtrlCreateButton("Valider", 64, 368, 75, 25)
Global $annulation = GUICtrlCreateButton("Effacer", 232, 368, 75, 25)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Global $cgroupin = 'OU=Admin_Locaux,OU=Groupes,OU=ATC,DC=ENC92,DC=LOCAL' ;OU où se crée les groupes Admin Locaux
Global $dng = ("G_ADMINL_") ; Racine du Nom du Groupe
Global $sFQDN = _AD_SamAccountNameToFQDN() ;Compte utilisateur
Global $cgroupe = $dng & StringUpper(GUICtrlRead($admingroup)) ;Force la mise en majuscule du nom du groupe
Global $cutilisateur = GUICtrlRead($utilisateur)
Global $membres_du_groupe = _AD_GetGroupMembers($cgroupe)

While 1
    $msg = GUIGetMsg()
    Switch $msg
    Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $annulation
            ;Efface la saisie
            GUICtrlSetData($admingroup, "")
            GUICtrlSetData($utilisateur, "")

            ;Annule la sélection des boutons radio
            GUICtrlSetState($radio0, $GUI_UNCHECKED)
            GUICtrlSetState($radio1, $GUI_UNCHECKED)
            GUICtrlSetState($radio2, $GUI_UNCHECKED)

    Case $msg = $valider And BitAND(GUICtrlRead($radio0), $GUI_CHECKED) = $GUI_CHECKED
            _radio0()
        Case $msg = $valider And BitAND(GUICtrlRead($radio1), $GUI_CHECKED) = $GUI_CHECKED
            MsgBox(1, "Ajout de compte utilisateur :", "Vous allez ajouter le compte "&$cutilisateur&" au groupe "&$cgroupe)
            _radio1()
        Case $msg = $valider And BitAND(GUICtrlRead($radio2), $GUI_CHECKED) = $GUI_CHECKED
             MsgBox (1, "Création de Groupe Admin Locaux :", "Vous allez créer le groupe "&$cgroupe&" et y ajouter le compte "&$cutilisateur)
            _radio2()
    EndSwitch
WEnd


;Vérification de l'existence d'un groupe "Admin Locaux"
Func _radio0()

If _AD_ObjectExists($cgroupe) = 1 Then
    MsgBox(0, "Info :", "Le groupe "&$cgroupe&" existe déjà.")
    _ArrayDisplay($membres_du_groupe)
Else
    MsgBox(0, "Info :", "Le groupe "&$cgroupe&" n'existe pas.")
    EndIf
EndFunc


;Ajout de compte à un groupe "Admin Locaux"
Func _radio1()


If _AD_AddUserToGroup($cgroupe, $cutilisateur) = 1 Then
    MsgBox(0, "Info :",  "Le compte "&$cutilisateur&" a été ajouté au groupe "&$cgroupe&" avec succès")
Else
    If @error = 1 Then
    MsgBox(0, "Info :", "Le groupe "&$cgroupe&" n'existe pas.")
    Else
        If @error = 2 Then
            MsgBox(0, "Erreur :", "Le compte "&$cutilisateur&" n'existe pas dans l'AD.")
        Else
            If @error = 3 Then
                MsgBox (0, "Info :", "Le compte "&$cutilisateur&" est déjà membre du groupe "&$cgroupe)
            Else
                If @error = 4 Then
                    MsgBox(0, "Erreur", "Impossible d'ajouter le compte "&$cutilisateur&" "& @error, "Veullez contacter l'administrateur système")
                EndIf
            EndIf
        EndIf
    EndIf
EndIf
EndFunc

;Création du groupe "Admin Locaux" et ajout de compte utilisateur
Func _radio2()

If  _AD_CreateGroup($cgroupin, $cgroupe) = 1 Then ;Création d'un nouveau groupe
    If @error = 1 Then
        MsgBox(0, "Erreur :", "Le groupe "&$cgroupe&" existe déjà.")
    Else
        If @error = 3 Then
            MsgBox(0, "Erreur", "Impossible de créer le groupe "&$cgroupe&" "& @error, "Veullez contacter l'administrateur système")
        Else
            If @error = 0 Then

            _AD_AddUserToGroup($cgroupe, $cutilisateur) ;Ajout de l'utilisateur au groupe créé
            If @error = 0 Then
                MsgBox(0, "Info :", "Le compte "&$cutilisateur&" a été ajouté au groupe "&$cgroupe&" avec succès")
            Else
                If @error = 1 Then
                    MsgBox(0, "Info :", "Le groupe "&$cgroupe&" n'existe pas.")
                Else
                    If @error = 2 Then
                        MsgBox(0, "Erreur :", "Le compte "&$cutilisateur&" n'existe pas dans l'AD.")
                    Else
                        If @error = 3 Then
                            MsgBox (0, "Info :", "Le compte "&$cutilisateur&" est déjà membre du groupe "&$cgroupe)
                        Else
                            If @error = 4 Then
                                MsgBox(0, "Erreur", "Impossible d'ajouter le compte "&$cutilisateur&" "& @error, "Veullez contacter l'administrateur système")
                            EndIf
                        EndIf
                    EndIf
                EndIf
            EndIf
        EndIf
    EndIf
EndIf
EndIf
EndFunc
_AD_Close()

Exit

J'avoue ne pas trop avoir cherché pourquoi (pas le temps là) mais si tu mets le

Code : Tout sélectionner

    Case $msg = $GUI_EVENT_CLOSE

ailleurs dans la boucle il n'y a plus le problème

mikell a écrit :J'avoue ne pas trop avoir cherché pourquoi (pas le temps là) mais si tu mets le
Code : Tout sélectionner
    Case $msg = $GUI_EVENT_CLOSE
ailleurs dans la boucle il n'y a plus le problème

Merci pour l'info. Effectivement cela a changé la donne. L'interface reste ouverte après que j'ai déplacé le code "Case $msg = $GUI_EVENT_CLOSE" Comme vous me l'avez conseillé. Je l'ai mis un peu plus bas et mon problème est résolu.
Mais cela me crée un nouveau problème. Je n'arrive plus à remplir mon interface puisque la saisie ne fonctionne plus.

TIN quel con je fais, voilà ce que c'est quand on est pressé on voit pas l'évidence

Un petit indice : tu utilises un Switch et pas un Select....

mikell a écrit :

Un petit indice : tu utilises un Switch et pas un Select....

Oui effectivement j'utilise un switch car je souhaite utiliser que des fonctions dans mon script. Cela m'évitera d'écrire beaucoup de ligne ou me répéter. Et j'aimerais voir afficher les erreurs que remonte l'AD.
Créer des grouopes et y ajouter des comptes n'est pas chose simple avec AutoIt, surtout si on veut avoir une interface graphique. J'étudie toutes les possibiltés.

Encore merci pour votre aide et le temps que vous m'accordez.

Bonjour Thimmy,

Ce que Mikell veut dire, c'est que ton bloc switch ne devrait pas en être un.

Code : Tout sélectionner

Switch $msg
   Case $msg = "tartampion"

ne peut pas fonctionner. A la place soit tu dois faire

Code : Tout sélectionner

Switch $msg
   Case "tartampion"

soit autrement

Code : Tout sélectionner

Select
   Case $msg = "tartampion"

Car sinon, dans le premier cas, tu ne comparerais pas $msg à la valeur "tartampion", mais à son égalité la valeur "tartampion" (donc un peu comme si au lieu de $msg = "tartampion", tu avais $msg = ($msg = "tartampion") ^^)

A bientôt !

Merci à Mikell et à ZDS pour ces réponses constructives et précieuses.
J'ai bien suivi vos conseils et l'interface reste ouvert. Mais il est impossible de saisir du texte dans les "Input" et de cocher les boutons radio.
C'est le nouveau problème que j'ai. Le pire c'est que je ne vois pas où j'ai péché dans mon script. Je continue de chercher. En attendant, je vous laisse une copie si vous avez encore du temps à m'accorder.
D'avance merci.

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <AD.au3>
#include <Array.au3>

_AD_Open()

#Region ### START Koda GUI section ### Form=Création de groupe dans Active Directory.kxf
GUICreate("Création de groupes Admin Locaux", 371, 476, 192, 124)
GUICtrlCreateGroup("", 32, 40, 305, 369)
GUICtrlCreateGroup("", -99, -99, 1, 1)

GUICtrlCreateLabel("Création de groupe Admin locaux", 40, 40, 160, 17)
GUICtrlCreateLabel("Groupe", 64, 86, 39, 17)
GUICtrlCreateLabel("Utilisateur", 64, 158, 50, 17)

; Déclaration des zones de saisies
Global $admingroup = GUICtrlCreateInput("", 64, 104, 241, 25) ; saisie du nom du groupe à créer
Global $utilisateur = GUICtrlCreateInput("", 64, 176, 241, 25) ; saisie du nom de l'utilisateur à ajouter à un groupe

;Déclaration des boutons radios
Global $radio0 = GUICtrlCreateRadio("Vérifier l'existance du groupe", 64, 256, 249, 17)
Global $radio1 = GUICtrlCreateRadio("Ajouter un compte à un groupe déjà exitant", 64, 280, 241, 17)
Global $radio2 = GUICtrlCreateRadio("Créer un groupe et y ajouter un compte utilisateur", 64, 304, 257, 17)

;déclaration des boutons à cliquer
Global $valider = GUICtrlCreateButton("Valider", 64, 368, 75, 25)
Global $annulation = GUICtrlCreateButton("Effacer", 232, 368, 75, 25)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Global $cgroupin = 'OU=Admin_Locaux,OU=Groupes,OU=ATC,DC=ENC92,DC=LOCAL' ;OU où se crée les groupes Admin Locaux
Global $dng = ("G_ADMINL_") ; Racine du Nom du Groupe
Global $sFQDN = _AD_SamAccountNameToFQDN() ;Compte utilisateur
Global $cgroupe = $dng & StringUpper(GUICtrlRead($admingroup)) ;Force la mise en majuscule du nom du groupe
Global $cutilisateur = GUICtrlRead($utilisateur)
Global $membres_du_groupe = _AD_GetGroupMembers($cgroupe)

While 1
    $msg = GUIGetMsg()
    Switch $msg
    Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $annulation
            ;Efface la saisie
            GUICtrlSetData($admingroup, "")
            GUICtrlSetData($utilisateur, "")

            ;Annule la sélection des boutons radio
            GUICtrlSetState($radio0, $GUI_UNCHECKED)
            GUICtrlSetState($radio1, $GUI_UNCHECKED)
            GUICtrlSetState($radio2, $GUI_UNCHECKED)

    Case $valider And BitAND(GUICtrlRead($radio0), $GUI_CHECKED) = $GUI_CHECKED
            _radio0()
        Case $valider And BitAND(GUICtrlRead($radio1), $GUI_CHECKED) = $GUI_CHECKED
            MsgBox(1, "Ajout de compte utilisateur :", "Vous allez ajouter le compte "&$cutilisateur&" au groupe "&$cgroupe)
            _radio1()
        Case $valider And BitAND(GUICtrlRead($radio2), $GUI_CHECKED) = $GUI_CHECKED
             MsgBox (1, "Création de Groupe Admin Locaux :", "Vous allez créer le groupe "&$cgroupe&" et y ajouter le compte "&$cutilisateur)
            _radio2()
    EndSwitch
WEnd


;Vérification de l'existence d'un groupe "Admin Locaux"
Func _radio0()

If _AD_ObjectExists($cgroupe) = 1 Then
    MsgBox(0, "Info :", "Le groupe "&$cgroupe&" existe déjà.")
    _ArrayDisplay($membres_du_groupe)
Else
    MsgBox(0, "Info :", "Le groupe "&$cgroupe&" n'existe pas.")
    EndIf
EndFunc


;Ajout de compte à un groupe "Admin Locaux"
Func _radio1()


If _AD_AddUserToGroup($cgroupe, $cutilisateur) = 1 Then
    MsgBox(0, "Info :",  "Le compte "&$cutilisateur&" a été ajouté au groupe "&$cgroupe&" avec succès")
Else
    If @error = 1 Then
    MsgBox(0, "Info :", "Le groupe "&$cgroupe&" n'existe pas.")
    Else
        If @error = 2 Then
            MsgBox(0, "Erreur :", "Le compte "&$cutilisateur&" n'existe pas dans l'AD.")
        Else
            If @error = 3 Then
                MsgBox (0, "Info :", "Le compte "&$cutilisateur&" est déjà membre du groupe "&$cgroupe)
            Else
                If @error = 4 Then
                    MsgBox(0, "Erreur", "Impossible d'ajouter le compte "&$cutilisateur&" "& @error, "Veullez contacter l'administrateur système")
                EndIf
            EndIf
        EndIf
    EndIf
EndIf
EndFunc

;Création du groupe "Admin Locaux" et ajout de compte utilisateur
Func _radio2()

If  _AD_CreateGroup($cgroupin, $cgroupe) = 1 Then ;Création d'un nouveau groupe
    If @error = 1 Then
        MsgBox(0, "Erreur :", "Le groupe "&$cgroupe&" existe déjà.")
    Else
        If @error = 3 Then
            MsgBox(0, "Erreur", "Impossible de créer le groupe "&$cgroupe&" "& @error, "Veullez contacter l'administrateur système")
        Else
            If @error = 0 Then

            _AD_AddUserToGroup($cgroupe, $cutilisateur) ;Ajout de l'utilisateur au groupe créé
            If @error = 0 Then
                MsgBox(0, "Info :", "Le compte "&$cutilisateur&" a été ajouté au groupe "&$cgroupe&" avec succès")
            Else
                If @error = 1 Then
                    MsgBox(0, "Info :", "Le groupe "&$cgroupe&" n'existe pas.")
                Else
                    If @error = 2 Then
                        MsgBox(0, "Erreur :", "Le compte "&$cutilisateur&" n'existe pas dans l'AD.")
                    Else
                        If @error = 3 Then
                            MsgBox (0, "Info :", "Le compte "&$cutilisateur&" est déjà membre du groupe "&$cgroupe)
                        Else
                            If @error = 4 Then
                                MsgBox(0, "Erreur", "Impossible d'ajouter le compte "&$cutilisateur&" "& @error, "Veullez contacter l'administrateur système")
                            EndIf
                        EndIf
                    EndIf
                EndIf
            EndIf
        EndIf
    EndIf
EndIf
EndIf
EndFunc
_AD_Close()

Exit

Hello

Attendu qu'il manque une UDF on ne peut pas tester grand chose mais ça vient sans doute d'ici :

Code : Tout sélectionner

Case $valider And BitAND(GUICtrlRead($radio0), $GUI_CHECKED) = $GUI_CHECKED

Essaie plutôt quelle chose du style

Code : Tout sélectionner

        Case $valider
            If BitAND(GUICtrlRead($radio0), $GUI_CHECKED) = $GUI_CHECKED Then
                _radio0()
            EndIf

Un grand MERCI à vous tous, TopXm, ZDS et Mikell. Waou comment j'ai pu passer à côté de ça ?
Maintenant tout est bon dans le script, j'ai maintenant 80% de ce que je voulais. Je vais pouvoir finaliser mon petit utilitaire grâce à votre aide

.

AutoIt Français

[R] Garder l'interface utilisateur ouvert

[R] Garder l'interface utilisateur ouvert

Re: [..] Garder l'interface utilisateur ouvert

Re: [..] Garder l'interface utilisateur ouvert

Re: [..] Garder l'interface utilisateur ouvert

Re: [..] Garder l'interface utilisateur ouvert

Re: [..] Garder l'interface utilisateur ouvert

Re: [..] Garder l'interface utilisateur ouvert

Re: [..] Garder l'interface utilisateur ouvert

Re: [..] Garder l'interface utilisateur ouvert