AutoIt Français

[R] Bonjour à tous,

Je me casse la tête sur un petit soucis depuis quelques jours. Je n'arrive pas
à faire fonctionner le script suivant correctement. Quand on clic sur le listview,
pour sélectionner une ligne par exemple, ca provoque vraisemblablement un
refresh automatique de mon Listview et les items en rouge se rafraichissent avec
la valeur par défaut de ma variable qui détermine la couleur de mon item
( Enfin Si j'ai bien tout compris ). Je suis dans une impasse, si un superman
d'autoit avait une idée je serai bien content

Cordialement,

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <FontConstants.au3>
#include <WinAPI.au3>
#include <ButtonConstants.au3>


Global $Flag
Global Const $CDDS_SUBITEMPREPAINT = BitOR($CDDS_ITEM, $CDDS_SUBITEM, $CDDS_PREPAINT)

Global $Font1 = _WinAPI_CreateFont(14, 0, 0, 0, $FW_BOLD)
Global $Font2 = _WinAPI_CreateFont(14, 0, 0, 0, $FW_NORMAL, False, False, False, $DEFAULT_CHARSET, $OUT_DEFAULT_PRECIS, _
                                    $CLIP_DEFAULT_PRECIS, $DEFAULT_QUALITY, 0, "MS Sans Serif")

Global $Array1[6]
$Array1[0] = "JPM"
$Array1[1] = "Holger"
$Array1[2] = "Jon"
$Array1[3] = "Larry"
$Array1[4] = "Jeremy"
$Array1[5] = "Valik"
Global $Array2[6]
$Array2[0] = "JPM"
$Array2[1] = "HolgerX"
$Array2[2] = "Jon"
$Array2[3] = "LarryX"
$Array2[4] = "Jeremy"
$Array2[5] = "ValikX"
$hGUI = GUICreate("Test", 300, 300)
Global $hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems|", 10, 10, 280, 180, $LVS_REPORT, $WS_EX_CLIENTEDGE)

_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_INFOTIP))

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState(@SW_SHOW)

Remplir()

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
    Case $GUI_EVENT_CLOSE
        _WinAPI_DeleteObject($Font1)
        _WinAPI_DeleteObject($Font2)
        Exit

EndSwitch
WEnd
Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
     Local $tNMHDR, $hWndFrom, $iCode

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
     $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
     $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
         Case $hListView
             Switch $iCode
                 Case $NM_CUSTOMDRAW
                     Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                     Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                     If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                     If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
                     Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                     Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                     Local $iColor, $hDC
;~                      Switch $iItem
;~                          Case 5
                             $hDC = DllStructGetData($tCustDraw, "hdc")
                             If $iSubItem = 1 Then
                                if $Flag = True then
                                 $iColor = RGB2BGR(0x00ff00)
                                 _WinAPI_SelectObject($hDC, $Font2)
                                 DllStructSetData($tCustDraw, "clrText", $iColor)
                                Else
                                  $iColor = RGB2BGR(0xff0000)
                                 _WinAPI_SelectObject($hDC, $Font2)
                                 DllStructSetData($tCustDraw, "clrText", $iColor)
                                 Endif
                             EndIf
                             Return $CDRF_NEWFONT
;~                      EndSwitch
             EndSwitch
     EndSwitch
    Return $GUI_RUNDEFMSG
 EndFunc   ;==>WM_NOTIFY
Func RGB2BGR($iColor)
     Return BitAND(BitShift(String(Binary($iColor)), 8), 0xFFFFFF)
 EndFunc   ;==>RGB2BGR()[/
Func Remplir()
 For $i = 0 To 5
     _GUICtrlListView_AddItem($hListView, "Résultat :" & $i)
     If $Array1[$i] = $Array2[$i] Then
        $Flag = True
        _GUICtrlListView_AddSubItem($hListView, $i , "Egal" & $i+1, 1)
    Else
        $Flag = False
      _GUICtrlListView_AddSubItem($hListView, $i , "Pas Egal" & $i+1, 1)
     EndIf
 Next
 EndFunc

Bonjour à tous,

Bon je vais répondre tout seul à la moitier de ma question

J'ai trouvé un script qui permet de colorier de manière dynamique des lignes d'un Listview.
C'est pas encore le top, ca le fait que ligne à ligne et non pas par "subitem". On doit pouvoir
l'améliorer, mais là j' ai du mal à tout comprendre. Mais peut être un mozart d'autoit pourrait
le faire fonctionner par subitem !

Voici le code,
Cordialement,

bonne journée.

► Afficher le texte

Code : Tout sélectionner

#Include <GUIListView.au3>
#Include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiConstantsEx.au3>
#include <FontConstants.au3>
#include <WinAPI.au3>
#include <ButtonConstants.au3>

Global $Flag
Global $hGUI, $hListView
Global $Array1[6]
$Array1[0] = "JPM"
$Array1[1] = "Holger"
$Array1[2] = "Jon"
$Array1[3] = "Larry"
$Array1[4] = "Jeremy"
$Array1[5] = "Valik"
Global $Array2[6]
$Array2[0] = "JPM"
$Array2[1] = "HolgerX"
$Array2[2] = "Jon"
$Array2[3] = "LarryX"
$Array2[4] = "Jeremy"
$Array2[5] = "ValikX"


$hGUI = GUICreate('Test', 300, 200)
$hListView = _GUICtrlListView_Create($hGUI, 'Items|SubItems', 10, 10, 280, 180, $LVS_REPORT, $WS_EX_CLIENTEDGE)
_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_DOUBLEBUFFER, $LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $WS_EX_CLIENTEDGE))

Remplir()

GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')
GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func _GUICtrlListView_SetItemColor($hWnd, $iItem, $iColor, $fRedraw = 0)
    If _WinAPI_InProcess($hWnd, $_lv_ghLastWnd) Then
        If _GUICtrlListView_SetItemParam($hWnd, $iItem, BitOR(BitAND($iColor, 0x00FF00), BitShift(BitAND($iColor, 0x0000FF), -16), BitShift(BitAND($iColor, 0xFF0000), 16))) Then
            If $fRedraw Then
                _GUICtrlListView_RedrawItems($hWnd, $iItem, $iItem)
            EndIf
            Return 1
        EndIf
    EndIf
    Return 0
EndFunc   ;==>_GUICtrlListView_SetItemColor

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    Local $hWndFrom = DllStructGetData($tNMHDR, 'hWndFrom')
    Local $iCode = DllStructGetData($tNMHDR, 'Code')

    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_CUSTOMDRAW

                    Local $tNMLVCD = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                    Local $iDrawStage = DllStructGetData($tNMLVCD, 'dwDrawStage')

                    Switch $iDrawStage
                        Case $CDDS_PREPAINT
                            Return $CDRF_NOTIFYITEMDRAW
                        Case $CDDS_ITEMPREPAINT
                            Return $CDRF_NOTIFYSUBITEMDRAW
                        Case BitOR($CDDS_ITEMPREPAINT, $CDDS_SUBITEM)
                            DllStructSetData($tNMLVCD, 'clrText', _GUICtrlListView_GetItemParam($hWndFrom, DllStructGetData($tNMLVCD, 'dwItemSpec')))
                            Return $CDRF_NEWFONT
                    EndSwitch
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY
Func Remplir()



     For $i = 0 To 5
     _GUICtrlListView_AddItem($hListView, "Résultat :" & $i)
     If $Array1[$i] = $Array2[$i] Then
;~      $Flag = True
        _GUICtrlListView_AddSubItem($hListView, $i , "Egal" & $i, 1)
        _GUICtrlListView_SetItemColor($hListView, $i, 0xFF8800, 0)
    Else
;~      $Flag = False
      _GUICtrlListView_AddSubItem($hListView, $i , "Pas Egal" & $i, 1)
      _GUICtrlListView_SetItemColor($hListView, $i, 0x0000C0, 0)
     EndIf


Next
EndFunc

Pour que ça marche il faut définir dans le NOTIFY une caractéristique de l'item pour pouvoir poser la condition de couleur

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <FontConstants.au3>
#include <WinAPI.au3>
#include <ButtonConstants.au3>

Global $Flag, $n
Global Const $CDDS_SUBITEMPREPAINT = BitOR($CDDS_ITEM, $CDDS_SUBITEM, $CDDS_PREPAINT)

Global $Array1[6]
$Array1[0] = "JPM"
$Array1[1] = "Holger"
$Array1[2] = "Jon"
$Array1[3] = "Larry"
$Array1[4] = "Jeremy"
$Array1[5] = "Valik"
Global $Array2[6]
$Array2[0] = "JPM"
$Array2[1] = "Holger"
$Array2[2] = "JonX"
$Array2[3] = "LarryX"
$Array2[4] = "Jeremy"
$Array2[5] = "ValikX"
$hGUI = GUICreate("Test", 300, 300)
Global $hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems|", 10, 10, 280, 180, $LVS_REPORT, $WS_EX_CLIENTEDGE)

_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_INFOTIP))
$btn = GuiCtrlCreateButton("test", 100, 200, 40, 25)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState(@SW_SHOW)

Remplir()

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
    Case $GUI_EVENT_CLOSE
         Exit
    Case $btn
         _GUICtrlListView_SetItemText($hListView, 1, "Not Egal2", 1)
         _GUICtrlListView_SetItemText($hListView, 2, "Egal3", 1)
EndSwitch
WEnd


Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
     Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
     $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
     $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
         Case $hListView
             Switch $iCode
                 Case $NM_CUSTOMDRAW
                     Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                     Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                     If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                     If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
                     Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                     Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                     Local $iColor

                     If $iSubItem = 1 Then
                          $hDC = DllStructGetData($tCustDraw, "hdc")
                          $text = _GUICtrlListView_GetItemText($hListView, $iItem, 1)
                          If stringInStr($text, "Pas") Then
                                $iColor = RGB2BGR(0xff0000)
                          ElseIf stringInStr($text, "Not") Then
                                $iColor = RGB2BGR(0x0000ff)
                          Else
                                $iColor = RGB2BGR(0x00ff00)
                          EndIf
                          DllStructSetData($tCustDraw, "clrText", $iColor)
                          Return $CDRF_NEWFONT
                    Endif
             EndSwitch
     EndSwitch
    Return $GUI_RUNDEFMSG
 EndFunc   ;==>WM_NOTIFY

Func RGB2BGR($iColor)
     Return BitAND(BitShift(String(Binary($iColor)), 8), 0xFFFFFF)
 EndFunc   ;==>RGB2BGR()


Func Remplir()
 For $i = 0 To 5
     _GUICtrlListView_AddItem($hListView, "Résultat :" & $i)
     If $Array1[$i] = $Array2[$i] Then
        $Flag = True
        _GUICtrlListView_AddSubItem($hListView, $i , "Egal" & $i+1, 1)
    Else
        $Flag = False
      _GUICtrlListView_AddSubItem($hListView, $i , "Pas Egal" & $i+1, 1)
     EndIf
 Next
 EndFunc

donc si tu travailles avec une variable true/false il faut l'attacher à l'item

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <FontConstants.au3>
#include <WinAPI.au3>
#include <ButtonConstants.au3>


Global $Flag, $items[6][2]
Global Const $CDDS_SUBITEMPREPAINT = BitOR($CDDS_ITEM, $CDDS_SUBITEM, $CDDS_PREPAINT)

Global $Array1[6]
$Array1[0] = "JPM"
$Array1[1] = "Holger"
$Array1[2] = "Jon"
$Array1[3] = "Larry"
$Array1[4] = "Jeremy"
$Array1[5] = "Valik"
Global $Array2[6]
$Array2[0] = "JPM"
$Array2[1] = "Holger"
$Array2[2] = "JonX"
$Array2[3] = "LarryX"
$Array2[4] = "Jeremy"
$Array2[5] = "ValikX"
$hGUI = GUICreate("Test", 300, 300)
Global $hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems|", 10, 10, 280, 180, $LVS_REPORT, $WS_EX_CLIENTEDGE)

_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_INFOTIP))
$btn = GuiCtrlCreateButton("test", 100, 200, 40, 25)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState(@SW_SHOW)

Remplir()

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
    Case $GUI_EVENT_CLOSE
         Exit
    Case $btn
          $items[1][1] = false
         _GUICtrlListView_SetItemText($hListView, 1, "Not Egal2", 1)
          $items[2][1] = true
       _GUICtrlListView_SetItemText($hListView, 2, "Egal3", 1)
EndSwitch
WEnd


Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
     Local $tNMHDR, $hWndFrom, $iCode

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
     $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
     $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
         Case $hListView
             Switch $iCode
                 Case $NM_CUSTOMDRAW
                     Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                     Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                     If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                     If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
                     Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                     Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                     Local $iColor

                     If $iSubItem = 1 Then
                          $hDC = DllStructGetData($tCustDraw, "hdc")
                       Switch $items[$iItem][1]
                           Case true
                                 $iColor = RGB2BGR(0x00ff00)
                           Case Else
                                $iColor = RGB2BGR(0xff0000)
                       EndSwitch
                          DllStructSetData($tCustDraw, "clrText", $iColor)
                          Return $CDRF_NEWFONT
                    Endif
             EndSwitch
     EndSwitch
    Return $GUI_RUNDEFMSG
 EndFunc   ;==>WM_NOTIFY

Func RGB2BGR($iColor)
     Return BitAND(BitShift(String(Binary($iColor)), 8), 0xFFFFFF)
 EndFunc   ;==>RGB2BGR()

Func Remplir()
 For $i = 0 To 5
     $items[$i][0] = _GUICtrlListView_AddItem($hListView, "Résultat :" & $i)
     If $Array1[$i] = $Array2[$i] Then
        $items[$i][1] = True  ; $Flag = True
        _GUICtrlListView_AddSubItem($hListView, $i , "Egal" & $i+1, 1)
    Else
        $items[$i][1] = False ; $Flag = False
      _GUICtrlListView_AddSubItem($hListView, $i , "Pas Egal" & $i+1, 1)
     EndIf
 Next
 EndFunc

Bonjour à tous,

Super,excellent ca fonctionne bien ... Merci pour le coup de main, à bientôt,

Cordialement,

AutoIt Français

[R] Refresh Listview avec couleur dynamique

[R] Refresh Listview avec couleur dynamique

Re: [..] Refresh Listview avec couleur dynamique

Re: [..] Refresh Listview avec couleur dynamique

Re: [..] Refresh Listview avec couleur dynamique