AutoIt Français

Bonjours,
est ce que vous connaissez une func qui donne le "PostScript name" à partir du nom de la police retourné par _Choosefont() ?
merci.

C'est quoi le PostScript name ?

le "PostScript name" est une des propriété des polices.
pour que je puisse choisir une police pour Photoshop (à travers autoit) il faut que je lui indique le "PostScript name".
j'ai essayé de contourner le prob. mais pas moyen.
j'ai cherché sur le net et j'ai trouvé ça:

► Afficher le texte

Code : Tout sélectionner

Func _RH_TTF_GetInfo($bBinary)
    Local $tBinary = DllStructCreate("byte[" & BinaryLen($bBinary) & "]")
    DllStructSetData($tBinary, 1, $bBinary)
    Local $pBinary = DllStructGetPtr($tBinary)
    Local $pPointer = $pBinary
    Local $tTT_OFFSET_TABLE = DllStructCreate("word MajorVersion;" & _
            "word MinorVersion;" & _
            "word NumOfTables;" & _
            "word SearchRange;" & _
            "word EntrySelector;" & _
            "word RangeShift;", _
            $pPointer)
    $pPointer += 12
    If DllStructGetData($tTT_OFFSET_TABLE, "MajorVersion") <> 256 And DllStructGetData($tTT_OFFSET_TABLE, "MinorVersion") <> 0 Then
        Return SetError(1, 0, 0)
    EndIf
    Local $iNumOfTables = 265 * BitAND(DllStructGetData($tTT_OFFSET_TABLE, "NumOfTables"), 0xF) + BitShift(DllStructGetData($tTT_OFFSET_TABLE, "NumOfTables"), 8)
    Local $iOffset
    Local $tTT_TABLE_DIRECTORY
    For $i = 1 To $iNumOfTables
        $tTT_TABLE_DIRECTORY = DllStructCreate("char Tag[4];" & _
                "dword CheckSum;" & _
                "dword Offset;" & _
                "dword Length;", _
                $pPointer)
        $pPointer += 16
        If DllStructGetData($tTT_TABLE_DIRECTORY, "Tag") == "name" Then
            $iOffset = _RH_BigEndianToInt(DllStructGetData($tTT_TABLE_DIRECTORY, "Offset"), 4)
            ExitLoop
        EndIf
    Next
    If Not $iOffset Then Return SetError(2, 0, 0)
    $pPointer = $pBinary + $iOffset
    Local $pDir = $pPointer
    Local $tTT_NAME_TABLE_HEADER = DllStructCreate("word FSelector;" & _
            "word NRCount;" & _
            "word StorageOffset;", _
            $pPointer)
    $pPointer += 6
    Local $iNRCount = _RH_BigEndianToInt(DllStructGetData($tTT_NAME_TABLE_HEADER, "NRCount"), 2)
    Local $iStorageOffset = _RH_BigEndianToInt(DllStructGetData($tTT_NAME_TABLE_HEADER, "StorageOffset"), 2)
    Local $aInfo[28][3] = [["Copyright notice"],["Font Name"],["Subfamily Name"],["Identifier"],["Full Font Name"],["Version"],["Postscript Name"],["Trademark"],["Manufacturer"],["Designer"],["Description"],["URL Vendor"], _
            ["URL Designer"],["License Description"],["License Info URL"],["Reserved Field "],["Preferred Family"],["Preferred Subfamily"],["Compatible Full"],["Sample text"],["PostScript CID Findfont Name"],["WWS Family Name"],["WWS Subfamily Name"]]
    Local $tTT_NAME_RECORD, $bString, $iNameID, $iPlatform
    Local $iLangID = -1
    For $i = 1 To $iNRCount
        $tTT_NAME_RECORD = DllStructCreate("word PlatformID;" & _
                "word EncodingID;" & _
                "word LanguageID;" & _
                "word NameID;" & _
                "word StringLength;" & _
                "word StringOffset;", _
                $pPointer)
        $pPointer += 12 ; size of $tTT_NAME_RECORD
        $bString = DllStructGetData(DllStructCreate("byte[" & _RH_BigEndianToInt(DllStructGetData($tTT_NAME_RECORD, "StringLength"), 2) & "]", $pDir + $iStorageOffset + _RH_BigEndianToInt(DllStructGetData($tTT_NAME_RECORD, "StringOffset"), 2)), 1)
        $iNameID = _RH_BigEndianToInt(DllStructGetData($tTT_NAME_RECORD, "NameID"), 2)
        $iPlatform = _RH_BigEndianToInt(DllStructGetData($tTT_NAME_RECORD, "PlatformID"), 2)
        If $iNameID < 23 Then
            If $iPlatform = 1 Then
                $aInfo[$iNameID][1] = _RH_FormatStringEllipsis(BinaryToString($bString), 100)
            ElseIf $iPlatform = 3 Then
                If $iLangID = -1 And $iNameID = 0 Then $iLangID = _RH_BigEndianToInt(DllStructGetData($tTT_NAME_RECORD, "LanguageID"), 2)
                If _RH_BigEndianToInt(DllStructGetData($tTT_NAME_RECORD, "LanguageID"), 2) = $iLangID Then $aInfo[$iNameID][2] = _RH_FormatStringEllipsis(BinaryToString($bString, 3), 100)
            EndIf
        EndIf
    Next
    Return $aInfo
EndFunc   ;==>_RH_TTF_GetInfo

Func _RH_BigEndianToInt($iValue, $iSize = 2)
    Return Dec(Hex(BinaryMid($iValue, 1, $iSize)))
EndFunc   ;==>_RH_BigEndianToInt

Func _RH_FormatStringEllipsis($sString, $iNumChars)
    Local $iLen = StringLen($sString)
    If $iLen <= $iNumChars Then Return $sString
    Return StringLeft($sString, $iNumChars - 3) & "..."
EndFunc   ;==>_RH_FormatStringEllipsis

quiu me fournit le fameux "Postscript name"

Code : Tout sélectionner

Global $sFontData = FileRead("C:\WINDOWS\Fonts\GOUDYSTO.TTF") ; <- your font here (full path maybe)
$aArray = _RH_TTF_GetInfo($sFontData)
_ArrayDisplay($aArray)

les Prob avec ce bout de code:
- il faut indiquer le dossier de la police. donc si l'utilisateur n'a pas Windows le dossier ne sera plus le meme. et je ne sais pas comment c'est avec les autre sys d'exploitation.
- le func "_ChooseFont()" ne me retourne pas le véritable nom de la police
- la func "_RH_TTF_GetInfo($bBinary)" n'est compatible qu'avec les police TrueType (et aussi Opentype) donc il me reste les police *.FON mais c'est pas vraiment grave.

Hum tu es sûr que Photoshop ne se contenterait pas du chemin + nom de fichier de la police ?
J'avais ça dans mes tiroirs (pour ttf seulement)

► Afficher le texte

Code : Tout sélectionner

; http://www.autoitscript.com/forum/topic/124231-extract-the-font-family-name-from-a-truetype-10-font/page__view__findpost__p__862778
;==============================================================

#Include <Array.au3>
#Include <File.au3>

$font_folder = _WinAPI_ShellGetSpecialFolderPath(0x0014) ;$CSIDL_FONTS = 0x0014
Global $FileList = _FileListToArray($font_folder, '*.ttf', 1)
Global $FontList[UBound($FileList) - 1][2]

For $i = 1 To $FileList[0]
    $FontList[$i - 1][1] = $FileList[$i]
    $FontList[$i - 1][0] = _WinAPI_GetFontResourceInfo($FileList[$i], 1)

    If $FontList[$i - 1][0] = "Comic Sans MS" Then Exitloop   ; exemple
Next

Msgbox(0,"", $FontList[$i - 1][0] &"  :  "& $font_folder &"\"&  $FontList[$i - 1][1])

;_ArrayDisplay($FontList)



;================================================================
; extraits de WinAPIEx.au3 :
;=====================

Func _WinAPI_ShellGetSpecialFolderPath($CSIDL, $fCreate = 0)
    Local $tPath = DllStructCreate('wchar[1024]')
    Local $Ret = DllCall('shell32.dll', 'int', 'SHGetSpecialFolderPathW', 'hwnd', 0, 'ptr', DllStructGetPtr($tPath), 'int', $CSIDL, 'int', $fCreate)
    If (@error) Or (Not $Ret[0]) Then
        Return SetError(1, 0, '')
    EndIf
    Return DllStructGetData($tPath, 1)
EndFunc  

Func _WinAPI_GetFontResourceInfo($sFont, $fForce = 0)
    If $fForce Then
        If Not _WinAPI_AddFontResourceEx($sFont, 0x20) Then   ;$FR_NOT_ENUM = 0x20
            Return SetError(1, 0, '')
        EndIf
    EndIf
    Local $tData = DllStructCreate('wchar[1024]')
    Local $Ret = DllCall('gdi32.dll', 'int', 'GetFontResourceInfoW','wstr', $sFont, 'dword*', 1024, 'ptr', DllStructGetPtr($tData), 'dword', 0x01)
    If (@error) Or (Not $Ret[0]) Then
        $Ret = 0
    EndIf
    If $fForce Then
        _WinAPI_RemoveFontResourceEx($sFont, 0x20)   ;$FR_NOT_ENUM = 0x20
    EndIf
    If Not IsArray($Ret) Then
        Return SetError(1, 0, '')
    EndIf
    Return DllStructGetData($tData, 1)
EndFunc  

Func _WinAPI_AddFontResourceEx($sFont, $iFlag = 0, $fNotify = 0)
    Local $Ret = DllCall('gdi32.dll', 'int', 'AddFontResourceExW', 'wstr', $sFont, 'dword', $iFlag, 'ptr', 0)
    If (@error) Or (Not $Ret[0]) Then
        Return SetError(1, 0, 0)
    EndIf
    If $fNotify Then
        DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', 0xFFFF, 'uint', 0x001D, 'int', 0, 'int', 0)
    EndIf
    Return $Ret[0]
EndFunc  

Func _WinAPI_RemoveFontResourceEx($sFont, $iFlag = 0, $fNotify = 0)
    Local $Ret = DllCall('gdi32.dll', 'int', 'RemoveFontResourceExW', 'wstr', $sFont, 'dword', $iFlag, 'ptr', 0)
    If (@error) Or (Not $Ret[0]) Then
        Return SetError(1, 0, 0)
    EndIf
    If $fNotify Then
        DllCall('user32.dll', 'int', 'SendMessage', 'hwnd', 0xFFFF, 'uint', 0x001D, 'int', 0, 'int', 0)
    EndIf
    Return 1
EndFunc

Merci pour le func "_WinAPI_ShellGetSpecialFolderPath"
mais je doit avoir le "Postscript name"
voila la soluce: http://www.autoitscript.fr/forum/viewto ... =21&t=9529
Sujet résolu.

AutoIt Français

[R] Font name to PostScript name

[R] Font name to PostScript name

Re: [..] Font name to PostScript name

Re: [..] Font name to PostScript name

Re: [..] Font name to PostScript name

Re: [R] Font name to PostScript name