AutoIt Français

Bonjour!

J'aimerai savoir si c'est possible d'integrer un compte a rebour dans une GUI, qui s'active après avoir cliqué sur un Label ? Si oui c'est possible que ce compte a rebour continu meme en ayant fermer le programme (en laissant un fichier texte qui indique l'heure de debut par exemple)?

P'tit bout de code pour exemple:

Code : Tout sélectionner

#include <GUIConstants.au3>

GUICreate("blabla", 400, 280)
GUICtrlCreatePic("C:\Users\Administrateur\Desktop\Images\Capturer.jpg",0,0, 400,280)

$Button_1 = GUICtrlCreateButton ("test",  10, 30, 100)
GUICtrlSetCursor(-1, 0)
$Button_2 = GUICtrlCreateLabel("Compte a rebour", 340, 250, 45, 18)
GUICtrlSetColor(-1, 0xff0000)
GUICtrlSetCursor(-1, 0)

GUISetState ()      

; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $Button_1
            Run('Notepad.exe')    
        Case $msg = $Button_2
            MsgBox(0, 'Testing', 'Button 2 was pressed') 
    EndSelect
Wend

Merci

astaroth a écrit :J'aimerai savoir si c'est possible d'integrer un compte a rebour dans une GUI, qui s'active après avoir cliqué sur un Label ?

Oui

astaroth a écrit :Si oui c'est possible que ce compte a rebours continu même en ayant fermer le programme (en laissant un fichier texte qui indique l'heure de début par exemple)?

Non

Pour ce genre de manipulation, il vous faudra passer par un second script, car quand vous fermer le programme, le code s'arrête et donc pas de compte à rebours possible.

Pour la première partie, indépendement de l'aspect fermeture du programme, il faudra passer par un adlibenable.

Pourquoi ?
parce que la gestion d'un compte à rebours consiste à attendre une seconde, updater un compteur et reboucler jusqu'à 0.
Grossièrement

Code : Tout sélectionner

for $i=30 to 0 step -1
 sleep(1000)
Next

Or le problème ici est que pendant 30 secondes, on va rester prisonnier de cette boucle, et tout tes contrôles seront inutilisables (fermeture, autre bouton ...)

donc pour éviter ceci, il faut écrire une fonction qui ne fait que retrancher 1 à une variable de compteur, updater le label et tester si la variable est tomber à 0 pour arr^ter le compteur. Puis lancer cette fonction (nommons la toto) via adlibenable("toto",1000) lors du click du label
Ceci va déclancher un faux mini thread qui va exécuter toto toutes les 1000 ms, mais qui va surtout rendre tout de suite la main au script pour ne pas bloquer.

A la fin du compte à rebours, il faudra faire un adlibdisable() pour arrêter ce petit thread.

Heu..

Un petit exemple?

J'ai repris ton code en y mettant la fonctionnalité suivante sur le label :
1 - lance le cpt à rebours si il n'est pas déjà lancé
2 - demande si on veut l'arrêter sinon

comme ça on verra un exple de suspension et reprise
j'ai fait plusieurs petites fonctions pour les "routines", pour améliorer la visibilité, concept du diviser pour mieux reigner.

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>

GUICreate("blabla", 400, 280)
GUICtrlCreatePic("logo.jpg",0,0, 400,300)
;;;; =========== ici on fait un disable de l'image de fond pour ne pas géner les focus des autres contrôles
GUICtrlSetState(-1,$GUI_DISABLE)
$Button_1 = GUICtrlCreateButton ("test",  10, 30, 100)
GUICtrlSetCursor(-1, 0)
$Button_2 = GUICtrlCreateLabel("Compte a rebour", 340, 250, 45, 36)
;;;; ============= transparence du label
GUICtrlSetBkColor(-1,$GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetColor(-1, 0xff0000)
GUICtrlSetCursor(-1, 0)

;================ création du labl qui affichera le compte à rebours
$label_cpt_rebours = GUICtrlCreateLabel("", 340, 230, 45, 18)
GUICtrlSetBkColor(-1,$GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetColor(-1, 0x000000)

;=========creation d'une globale qui permettra de savoir si le compte à rebours est en cours de fonction
$compteur_actif=0
;========globale devaleur du compteur max de référence (30 sec par exple)
$Nb_seconde=30
;=======globale de compteur courrant
Dim $en_cours

GUISetState ()      

; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $Button_1
            Run('Notepad.exe')    
        Case $msg = $Button_2
            Interroge_compteur()
    EndSelect
Wend


;;======= fonction qui lance le compte à rebours si il n'est pas déjà lancé
;; ====== demande si on veut l'arrêter sinon
Func Interroge_compteur()
    If Not $compteur_actif Then
        Init_compteur($Nb_seconde)
        AdlibEnable("Update_compteur",1000) ; lancement du refres du cpt à rebours dans un "mini thread" qui se lance toute les secondes et rends de suite la main au script
    Else
        ;on demande si il faut arrêter le compteur en cours, mais avant il faut suspendre le compteur pour qu'il ne continue pas
        AdlibDisable()
        $rep=MsgBox(4,"Interruption","Voulez vous stopez le compteur en cours ?")
        If $rep=6 Then ; oui
            Reset_compteur()
        Else ; non ou fermeture du popup par croix
            ;on réactive le compteur
            AdlibEnable("Update_compteur",1000)
        EndIf
    EndIf
EndFunc


;====== Fonction d'initialisation du compteur
Func Init_compteur($Nb_sec)
    $compteur_actif=1 ; on bascule le booléen sur true
    $en_cours=$Nb_sec ; init de la valeur qui sera prise pour le décompte
    Update_label($en_cours);on met le nombre de seconde dans le label
    
EndFunc

;===== Fonction de reset du compteur
Func Reset_compteur()
    $compteur_actif=0  ; on bascule le booléen à false
    Update_label(); on nettoie le label
EndFunc

;Fonction d'update du label du compte à rebours; si on ne passe pas de paramètres, alors "" est pris par défaut
Func Update_label($param_string="")
    GUICtrlSetData($label_cpt_rebours,$param_string)
EndFunc


;==== Fonction principale de gestion du compteur
Func Update_compteur()
    $en_cours-=1 ; on retranche 1 seconde à la globale
    Update_label($en_cours);on met le nombre de seconde dans le label
    ; on test si on est à la fin
    If $en_cours=0 Then
        ;on arrête le mini faux thread adlibenable
        AdlibDisable()
        MsgBox(0,"Fin","c'est fini !")
        ; on reset le compteur ainsi que son état
         Reset_compteur()
    EndIf
EndFunc

Merci beaucoup Sylvanie !

AutoIt Français

[R] Compte a rebour

[R] Compte a rebour

Re: [...] Compte a rebour

Re: [..] Compte a rebour

Re: [..] Compte a rebour

Re: [..] Compte a rebour

Re: [..] Compte a rebour