AutoIt Français

Salutations ici,
Je voulais savoir si il était possible de recuperer l'info d'un GuiCtrlCreateDate autrement que par du text, pour faire une comparaison entre deux date.
En gros, j'aimerais entrer une date de naissance et une autre date afin d'obtenir un age, mais GUICtrlRead me retourne une chaine de caracteres

Voila, merci d'avance ^^

Edit : j'aimerais avoir les années/mois/jours soustré directement afin d'avoir un age humainement compréenssible :
année1-année2 = xans
mois1-mois2 = xmois
jours1-jours2 = xjours

Mais aussi la difference entre les deux dates en jour, afin de calculer l'age en nombre de semaines !

Edit2: encore une question, que entrer dans un GUICtrlSetData pour choisir une date ? (aujourd'hui, ou une date prédéfinit)

1 - Par quoi d'autre voulez-vous remplacer l'info du GUICtrlCreateDate ?
La date est écrite, donc je ne vois pas ce que vous attendez d'autre ...

2 - Pour calculer ce genre de chose, il faut tout simplement décomposer les dates en plusieurs variables (Jour, Mois, Année) puis utiliser la fonction _DateDiff comme il ce doit en mettant en forme les date pour calculer la différence.

3 - Pourquoi voulez-vous utiliser quelque chose en particulier pour entrer une date dans un GUICtrlSetData alors que vous avez la fonction GUICtrlCreateDate qui est faite pour ça ...

roh ben, je voulais juste apprendre a utiliser les date, pas demander a ce qu'on me fasse tout ^^ mais bon, ca revient au meme comme je suis un peu totalement perdu...
Donc je vais tout expliquer bien :

En fait, il me fallait un programme pour enter la date de naissance d'un de mes rat, et qu'il me resorte son age accutel (en "anné/mois/jour", mais aussi en nombre de semaines). Seulement, comme je voulais généraliser le programme, voila a quoi cela devait ressembler :

: autoitexemple.JPG (7.02 Kio) Vu 4296 fois

Donc choix d'une date (ou d'un rat dont la date serait deja entré)
Choix d'une deuxieme date (un bouton "aujourd'hui" pour reinitialiser facilement la seconde date)
l'age années/mois/jours - l'age semaine/jours

M'aurait aussi fallu un bouton pour ajouter des rats prédéfinit.

---

Je sais a peut pre tout faire, si ce n'est :
-recuperer les date dans un format exploitable
-modifier une date d'un qualendrier
(la doc d'autoit dit :"For Date : date or time depending the style of the control" :/ ben merci... ca m'aide beaucoup)

J'ai entendu dire que en informatique, les dates étaient tout sous la forme d'un nombre de seconde depuis heu... 1970 ou je sais plus quoi (et que ca fera un bug de l'an 2000 en 2034 ou quelque chose du genre). Autoit ne fonctionne pas ainsi ?

Voila, encore merci de votre aide.

edit : j'ai decouvert qu'il fallait entrer les dates au format américain @YEAR&"/"&@MON&"/"&@MDAY

edit2: bon ben, j'ai tout fait, me reste plus qu'a trouver comment comparer des date ^^'

Petit up pour une demande qui a changée ;

j'ai maintenant mes deux dates en 3 variables chaqu'une :
(années/mois/jours)
$ca1 $cm1 $cj1 (date de naissance)
$ca2 $cm2 $cj2 (date de comparaison)

donc, comment obtenir le nombres de jour les separant ainsi que la diference en années/mois/jours ?

Merci encore

Edit : je me suis débrouillé avec un

Code : Tout sélectionner

$ca=$ca2-$ca1
$cm=$cm2-$cm1
$cj=$cj2-$cj1
            
If $cj <0 Then
$cj=$cj+30
$cm=$cm-1
EndIf
            
If $cm <0 Then
$cm=$cm+12
$ca=$ca-1
EndIf

GUICtrlSetData ($age, $ca&"an(s) "&$cm&"mois "&$cj&"jour(s)")

pour le nombre de temps en années/mois/jours, et un

Code : Tout sélectionner

$nbj=(365*$ca)+(30*$cm)+$cj
GUICtrlSetData ($age2, $cj&" - "&Int($cj/7)&"s")

pour le nombre aproximatif de jours/semaines

Comment avoir le nombre exacte de jours ? je ne voie vraiment pas comment faire:/

J'aurais pu mâcher le boulot jusqu'au bout, mais bon, il faut bien que je vous en laisse un peux ...

► Afficher le texteCode

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GuiComboBox.au3>
#include <DateTimeConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Date.au3>

#Region ### START Koda GUI section ### Form=C:\Documents and Settings\Tlem\Bureau\Test_Rat.kxf
$Form1 = GUICreate("Form1", 361, 176, -1, -1)
$Date1 = GUICtrlCreateDate("", 16, 32, 186, 21, $DTS_SHORTDATEFORMAT)
$Date2 = GUICtrlCreateDate("", 16, 96, 186, 21, $DTS_SHORTDATEFORMAT)
$Label1 = GUICtrlCreateLabel("Date de naissance du rat :", 16, 15, 129, 17)
$Label2 = GUICtrlCreateLabel("Date de comparaison :", 16, 79, 111, 17)
$Rats = GUICtrlCreateCombo("", 224, 32, 121, 25, BitOR($CBS_DROPDOWNLIST,$CBS_AUTOHSCROLL))
$Aujourdhui = GUICtrlCreateButton("Aujourdhui", 232, 96, 115, 25, 0)
$Label3 = GUICtrlCreateLabel("Age du rat :", 16, 144, 85, 24)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
$Age = GUICtrlCreateLabel("", 104, 144, 120, 24)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")

; Ici je détermine les valeurs des divers contrôles.
GUICtrlSetData($Date1, _NowCalc())
GUICtrlSetData($Date2, _NowCalc())
GUICtrlSetData($Rats, "Rat Prédéfinit|Rat_1|Rat_2|Rat_3|Rat_4|Rat_5", "Rat Prédéfinit")

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        
        Case $Aujourdhui
            GUICtrlSetData($Date2, _NowCalc())
            _GetAge()

        Case $Date1
            _GetAge()
            
        Case $Date2
            _GetAge()
            
        Case $Rats
            $Index = _GUICtrlComboBox_GetCurSel($Rats)
            MsgBox(0,"Info","Ici vous déterminez l'index du combo (" & $Index & "), et attribuez la valeur qu'il faut." & @CRLF & _
            "à partir d'un tableau que vous aurez créé et chargé au préalable.")
            
            
    EndSwitch
WEnd

Func _GetAge()
    $CD1 = StringSplit(GUICtrlRead($Date1), "/")
    $CD2 = StringSplit(GUICtrlRead($Date2), "/")
    
    $iDateCalc = _DateDiff( 'D',$CD1[3] & "/" & $CD1[2] & "/" &$CD1[1], $CD2[3] & "/" & $CD2[2] & "/" &$CD2[1])
    GUICtrlSetData($Age, $iDateCalc & " Jour(s)")
EndFunc

Haaaa, j'aime bien les ptits rats de laboratoire.
Sans eux, nous n'aurions pas grand chose en médoc, crèmes divers, etc ..

Merci bien ^^ je vais regarder ca... longtemps... tres longtemps... enfin, le temps de comprendre quoi :/

pour info, mon code actuel "terminé, mais ca pourrait etre mieux"

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.2.10.0
 Author:         Damian Iste

 Script Function:
    Template AutoIt script.

#ce ----------------------------------------------------------------------------

; Script Start - Add your code below here

#include <GuiConstants.au3>




GuiCreate("Age des rats", 380, 190)
$date1=GuiCtrlCreateDate("", 5, 0, 200, 20,$DTS_RIGHTALIGN )
GuiCtrlCreateLabel("Date de naissance du rat", 10, 20, 200, 20)
$button1=GuiCtrlCreatecombo("Rat predefinit", 250, 00, 120, 100)


$date2=GuiCtrlCreateDate("", 5, 40, 200, 20,$DTS_RIGHTALIGN )
GuiCtrlCreateLabel("Date de  comparaison", 10, 60, 200, 20)
$button2=GuiCtrlCreateButton("Aujourd'hui", 250, 40, 120, 20)

$button3=GuiCtrlCreateButton("Ajouter rats", 250, 80, 120, 20)
$no=GuiCtrlCreateInput("Nom", 250, 100, 120, 20)
$an=GuiCtrlCreateInput("Année (AAAA)", 250, 120, 120, 20)
$mo=GuiCtrlCreateInput("Mois (MM)", 250, 140, 120, 20)
$jo=GuiCtrlCreateInput("Jour (JJ)", 250, 160, 120, 20)

$button4=GuiCtrlCreateButton("Calculer", 10, 100, 200, 20)
$age=GuiCtrlCreateInput("Age du rat", 10, 120, 150, 20)
$age2=GuiCtrlCreateInput("Nb jours", 160, 120, 50, 20)
IniWriteSection ( "c:\agedesrats","","")
GuiCtrlCreateLabel("http://sita-rats.fr", 10, 170, 200, 20)

$irat=IniReadSectionNames ( "c:\agedesrats" )
For $i = 1 To $irat[0]
    GUICtrlSetData ($button1, $irat[$i])
Next



GuiSetState()
While 1
    $button = GUIGetMsg()
    Select
        Case $button = $GUI_EVENT_CLOSE
            ExitLoop
        Case $button = $button2
            GUICtrlSetData($date2,@YEAR&"/"&@MON&"/"&@MDAY)
        Case $button = $button1
            GUICtrlSetData ( $date1, (IniRead ( "c:\agedesrats", (GUICtrlRead ($button1)), "ddn", "0000/00/00" )))
        Case $button = $button3
            IniWriteSection ( "c:\agedesrats", (GUICtrlRead ($no)), "ddn="&(GUICtrlRead ($an))&"/"&(GUICtrlRead ($mo))&"/"&(GUICtrlRead ($jo)))
            GUICtrlSetData ($button1, (GUICtrlRead ($no)))
        Case $button = $button4
            $ca1=StringRight((StringLeft((GUICtrlRead ($date1)), 10)), 4)
            $cm1=StringRight((StringLeft((GUICtrlRead ($date1)), 5)), 2)
            $cj1=StringRight((StringLeft((GUICtrlRead ($date1)), 2)), 2)
            
            $ca2=StringRight((StringLeft((GUICtrlRead ($date2)), 10)), 4)
            $cm2=StringRight((StringLeft((GUICtrlRead ($date2)), 5)), 2)
            $cj2=StringRight((StringLeft((GUICtrlRead ($date2)), 2)), 2)
            
            $ca=$ca2-$ca1
            $cm=$cm2-$cm1
            $cj=$cj2-$cj1
            
            If $cj <0 Then
                $cj=$cj+30
                $cm=$cm-1
            EndIf
            
            If $cm <0 Then
                $cm=$cm+12
                $ca=$ca-1
            EndIf
            
            $nbj=((365*$ca)+(30*$cm)+$cj)
            
            GUICtrlSetData ($age, $ca&"an(s) "&$cm&"mois "&$cj&"jour(s)")
            GUICtrlSetData ($age2, $nbj&" - "&Int($nbj/7)&"s")

    EndSelect
    

WEnd

edit : correction de "bug" mineur

Le code que je vous ai donné, est 100% fonctionnel, il ne reste que la partie Rat prédéfinit à compléter.

Pour vous donner la direction, créez un fichier dans ce genre là :

Code : Tout sélectionner

Shaiya#01/07/2008
FLS Laïa#01/08/2008
Nima#01/09/2008
Icône#01/11/2008
Klebox#01/11/2008

Ensuite lisez le dans un tableau (_FileReadToArray ) et utilisez les variables (StringSplit pour séparer les éléments) pour compléter vos champs.

oui, j'ai vu que ca marchait super bien ^^ (j'ai juste posté ce que j'avais deja fait a ce moment là)
j'ai reussit a le comprendre, et la, je suis en train de tout mettre tout beau comme je veux :p

Je pense que je vais m'en sortir

Encore merci pour ce gros coup de main !

AutoIt Français

[R] Temps entre deux date

[R] Temps entre deux date

Re: [..] Temps entre deux date

Re: [..] Temps entre deux date

Re: [..] Temps entre deux date

Re: [..] Temps entre deux date

Re: [..] Temps entre deux date

Re: [..] Temps entre deux date

Re: [..] Temps entre deux date