AutoIt Français

Bonjour à tous,

je souhaiterai avoir un ptit script (exe) qui se lance en tache de fond, pour changer le titre d'une fenêtre. je vous explique...
J'utilise un logiciel de CAO (CATIA) sous 2 versions. Le probleme c'est qu'une fois lancer, il n'y a aucune difference visible sur la version lancée. Donc j'ai pensé a un changement du titre de la fenetre. Actuellement, le titre est "CATIA V5" et je souhaiterai "CATIA V5.16" ou "CATIA V5.18". La version se trouve dans les proprietes de l'executable 'version du fichier'.

Est-ce possible de faire ca ?

Il faudrait que tu trouve la version dans les fichiers d'installation, elle doit etre ecrite quelque part, dans un fichier log ou install ou config,ou alors dans le registre.

Après, pour changer le titre, tu peux utiliser:

WinSetTitle()

C'est parfait... on ne peut pas recuperer les proprietes d'un fichier (commentaire, entreprise, langue, version du produit...) ?

FileGetversion( "filename" [,"stringname"] )

Stringname = Comments, InternalName, ProductName, CompanyName, LegalCopyright, ProductVersion, FileDescription, LegalTrademarks, PrivateBuild, FileVersion, OriginalFilename, SpecialBuild

Exemple
$version = FilegetVersion("Explorer.exe","ProductVersion")
Msgbox(64,"Info", $version)

Exemple-Bis

Code : Tout sélectionner

MsgBox(64,"Info",_Propriet("explorer.exe"))

Func _Propriet($Fichier)
DIm $indice,$Version = ""
Local $String[12] = ["Comments", "InternalName", "ProductName", "CompanyName", "LegalCopyright", "ProductVersion", "FileDescription", "LegalTrademarks", "PrivateBuild", "FileVersion", "OriginalFilename", "SpecialBuild"]

For $indice = 0 to UBound($String)-1
    $Version &= $string[$indice] & " : " & FileGetVersion($Fichier,$String[$indice]) & @LF
Next
Return $Version
EndFunc

Le titre du ^post n'est plus trop en relation avec votre question.

Bonne continuation

Merci pour l'info...

Ben je pensais que je pouvais trouver un lien entre la fenetre et le fichier exe du logiciel. Donc si javais cette relation, j'aurai pu changer le titre de la fenetre avec les info de version de son fichier exe d'origine.

mais je ne trouve aucune relation entre la fenetre et l'exe donc...

j'ai cherche une relation entre les fenetres avec l'outil Au3Info.exe.
le titre des fenetres sont identiques, les class, handle... change tout le temps...
je ne sais pas trop comment faire...

y'a til un lien entre un PID et le chemin de l'exe ?

Je crois que j'ai trouvé mon bonheur

► Afficher le texte

Code : Tout sélectionner

Opt("MustDeclareVars", 1)
WinWaitActive("CATIA")
Local $ret = _GetActiveWinEXEPath("cnext.exe", "CATIA V5")
Local $version = FilegetVersion($ret,"ProductVersion")
WinSetTitle("CATIA", "", "CATIA V" & $version)

Func _GetActiveWinEXEPath($filename, $title = ""); filename and title substring(optional)
    ; Returns the executable path of the active program window
    ; where more than one instance of program with same exe name is running.
    ; Parameters:
    ; $filename = Executable name, i.e "notepad.exe" without path
    ; $title    = substring of window title, i.e. "Notepad" or "Untitled"
    ; Return:
    ; On Success:   Exe path of active window and @error set to 0
    ; On Error:  ""  and @error set to 1
    ; large chunk of code in this script from post by PerryRaptor
    ; code from this post nicely replaces my WMI code in first version
    ; http://www.autoitscript.com/forum/index.php?showtopic=56280
    
    Local $hWnd, $aWinList, $aProcList, $mode, $pid, $hProc, $stHMod, $stCB, $resEnum, $resPath, $err
    If Not ProcessExists($filename) Then
        SetError(1)
        Return ""
    EndIf
    $mode = Opt("WinTitleMatchMode", 2) ; Match any substring in the title
    If $title <> "" Then
        $aWinList = WinList($title, "")
    Else
        $aWinList = WinList()
    EndIf
    Opt("WinTitleMatchMode", $mode)
    $aProcList = ProcessList($filename)
    For $i1 = 1 To $aWinList[0][0]
        If $aWinList[$i1][0] <> "" Then
            For $i2 = 1 To $aProcList[0][0]
                $pid = $aProcList[$i2][1]
                $hProc = DllCall("kernel32.dll", "int", "OpenProcess", "int", _
                        0x0410, "int", False, "int", $pid)
                $err = @error
                If $err Then
                    If $hProc[0] Then DllCall("kernel32.dll", 'int', 'CloseHandle', 'int', $hProc[0])
                    SetError($err, @extended, 0)
                    Return ""
                EndIf
                If $hProc[0] Then
                    $stHMod = DllStructCreate("int hMod")
                    $stCB = DllStructCreate("dword cbNeeded")
                    $resEnum = DllCall("psapi.dll", "int", "EnumProcessModules", _
                            "int", $hProc[0], "ptr", DllStructGetPtr($stHMod), "dword", _
                            DllStructGetSize($stHMod), "ptr", DllStructGetPtr($stCB, 1))
                    $err = @error
                    If $err Then
                        DllCall("kernel32.dll", 'int', 'CloseHandle', 'int', $hProc[0])
                        SetError($err, @extended, 0)
                        Return ""
                    EndIf
                    If $resEnum[0] Then
                        $resPath = DllCall("psapi.dll", "int", "GetModuleFileNameEx", _
                                "int", $hProc[0], "int", DllStructGetData($stHMod, 1), _
                                "str", "", "dword", 32768)
                        $err = @error
                        DllCall("kernel32.dll", 'int', 'CloseHandle', 'int', $hProc[0])
                        If $err Then
                            SetError($err, @extended, 0)
                            Return ""
                        EndIf
                        If WinGetProcess($aWinList[$i1][1]) = $pid Then
                            $hWnd = $aWinList[$i1][1]
                            If BitAND(WinGetState($hWnd, ""), 8) Then
                                If FileExists($resPath[3]) Then
                                    SetError(0)
                                    Return $resPath[3]
                                Else
                                    SetError(1)
                                    Return ""
                                EndIf
                            EndIf
                        EndIf
                    EndIf
                    $stHMod = 0
                    $stCB = 0
                    If $hProc[0] Then DllCall("kernel32.dll", 'int', 'CloseHandle', 'int', $hProc[0])
                    If @error Then
                        SetError(@error, @extended, 0)
                        Return ""
                    EndIf
                EndIf
            Next
        EndIf
    Next
    SetError(1)
    Return ""
EndFunc   ;==>_GetActiveWinEXEPath

Il faut juste que je trouve comment laisser le script en route tout le temps dans le systray...

Rappel : Un outil de recherche est disponible sur le forum
Donc en recherchant "boucle infinie" tu aurais trouvé sa : (..) Planifier un dl et automatiser sa décompression

La boucle est :

Code : Tout sélectionner

While 1
Sleep(100)
Wend

Mais je ne posais pas une question... et d'ailleurs j'ai trouvé dans l'aide d'autoit

Si tu as trouvé la solution a ton problème, édite ton 1er post et marque [R] a la place de [..] je pense que tu le sais. Profite-en aussi pour nous indiquer le script entier qui t'as permi de résoudre ton problème.

AutoIt Français

[R] Changement de titre de fenêtre

[R] Changement de titre de fenêtre

Re: [..] Changement de titre de fenêtre

Re: [..] Changement de titre de fenêtre

Re: [..] Changement de titre de fenêtre

Re: [..] Changement de titre de fenêtre

Re: [..] Changement de titre de fenêtre

Re: [..] Changement de titre de fenêtre

Re: [..] Changement de titre de fenêtre

Re: [..] Changement de titre de fenêtre