AutoIt Français

Salut tout le monde.

J'essaie de faire un script supportant le drag & drop et je n'y arrive pas.
J'ai fait des recherches et les quelques pistes trouvées ne m'ont pas aidé à résoudre
le problème, ni le fichier d'aide. Voilà donc pourquoi je me tourne vers vous.

Je veux qu'un "input" soit capable de recevoir un nom de fichier et qu'il l'affiche. Hélas,
la fonction nommée gracieusement "test" ne semble point se déclencher lorsque le
fichier est déposé dans le champ texte. Je passe donc très certainement à côté d'un
détail d'une importance capitale à la réalisation de ce script. Mais lequel ?

Voilà mon code

► Afficher le texte

Code : Tout sélectionner

#include <EditConstants.au3>
#include <GUIConstants.au3>
#include<misc.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)
Global $opt, $meth, $exe, $savedir, $methode


$dir = @ScriptDir & "\launcher\"
$ini = $dir & "launcher.ini"
If _IsPressed("10") Then ; Shift   Save but don't play
    $opt = 1
ElseIf _IsPressed("11") Then ; Ctrl
    $opt = 2
Else
    $opt = 0
EndIf

If Not FileExists($dir) Then
    DirCreate($dir)
EndIf

If Not FileExists($ini) Then
    Form()
EndIf














; Fonctions reliées au form.

Func Form()
    
    $Form1 = GUICreate("Form1", 268, 311, 193, 125, Default, $WS_EX_ACCEPTFILES)
    GUISetOnEvent($GUI_EVENT_CLOSE, "quit")
    GUISetOnEvent($GUI_EVENT_DROPPED, "test")

    $Label1 = GUICtrlCreateLabel("Éxécutable à surveiller", 32, 16, 137, 17)
    GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
    $exe = GUICtrlCreateInput(@ScriptDir & "\", 32, 40, 145, 21, $GUI_SS_DEFAULT_INPUT, $WS_EX_ACCEPTFILES)
    GUICtrlSetState($exe, $GUI_DROPACCEPTED)
    $Button1 = GUICtrlCreateButton("...", 184, 40, 41, 17, 0)
    GUICtrlSetOnEvent(-1, "input_exe")

    $Label2 = GUICtrlCreateLabel("Répertoire par défaut de la sauvegarde", 32, 72, 227, 17)
    GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
    $savedir = GUICtrlCreateInput("", 32, 96, 145, 21, $GUI_SS_DEFAULT_INPUT, 0x00000010)
    $Button2 = GUICtrlCreateButton("...", 184, 96, 41, 17, 0)
    GUICtrlSetOnEvent(-1, "input_save")
    GUICtrlSetState($savedir, $GUI_DROPACCEPTED)


    $Label4 = GUICtrlCreateLabel("Méthode de fonctionnement", 32, 121, 162, 17)
    GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
    $methode = GUICtrlCreateCombo("0", 32, 144, 73, 25, 0x0003)
    GUICtrlSetData(-1, "1", "0")
    GUICtrlSetOnEvent($methode, "methode")
    $description = GUICtrlCreateLabel("0 = Récupère la sauvegarde lorsque vous" & @CRLF & "quitterez l'application." & @CRLF & @CRLF & "1 = Récupère la sauvegarde au lancement " & @CRLF & "de l'application", 32, 170)

    $Button3 = GUICtrlCreateButton("Sauvergarder les modifications", 32, 264, 161, 41, 0)
    GUICtrlSetOnEvent(-1, "save")

    $Button4 = GUICtrlCreateButton("À propos", 208, 264, 57, 41, 0)
    GUICtrlSetOnEvent(-1, "about")
    GUISetState(@SW_SHOW)


    While 1
        Sleep(100)
    WEnd
EndFunc   ;==>Form

Func test()
    GUICtrlSetData($savedir, @GUI_DragFile)
    ConsoleWrite('-@GUI_DROPID = ' & @GUI_DropId & @CRLF)
    ConsoleWrite('-@GUI_DragID = ' & @GUI_DragId & @CRLF)
    ConsoleWrite('-@GUI_DragFile = ' & @GUI_DragFile & @CRLF)

EndFunc   ;==>test
Func input_exe()
    $fsf = FileSelectFolder("Veuillez sélectionner l'exécutable de l'application", @ScriptDir, 7)
    GUICtrlSetData($exe, $fsf)
EndFunc   ;==>input_exe

Func input_save()
    $fsf = FileSelectFolder("Veuillez sélectionner le répertoire où l'application effectue sa sauvegarde", "", 7)
    GUICtrlSetData($savedir, $fsf)
EndFunc   ;==>input_save

Func methode()
    $meth = GUICtrlRead($methode)
    
    
EndFunc   ;==>methode

Func save()
    
EndFunc   ;==>save

Func about()
EndFunc   ;==>about


Func quit()
    Exit
EndFunc   ;==>quit

Donc... Ce que j'ai retenu de mon exploration sur le sujet.

Lors de la création du formulaire, la ligne suivante est importante.

Code : Tout sélectionner

GUISetOnEvent($GUI_EVENT_DROPPED, "test")

Je dois également utiliser le style $WS_EX_ACCEPTFILES dans mon gui ainsi que
dans le contrôle recevant le fichier.

Normalement, cela devrait suffire au bon fonctionnement de la fonction mais le fait est que non. Une idée ?

Faut retirer des input ceux-ci = $WS_EX_ACCEPTFILES
Faudrai aussi faire une vérification au niveau de l'exe, si tu drop un *.lnk faut lire la valeur de la cible.

bonne continuation

Merci !

J'ai pas mal cherché sur le forum anglais, mais pas trouvé ou il y a une erreur dans ton code...
Peut etre un bug d'Autoit?
On verra quand les manitous passeront par là

y a pas de bug tim

l'aide nous dit concernant le ws_ex_acceptfiles et on tombe sur un exemple avec le input

If you want to drag & drop a filename onto this control just add the WS_EX_ACCEPTFILES extended style on the GUICreate() and set the state to $GUI_DROPACCEPTED.

Si vous voulez drag & drop un nom de fichier a l'intérieur d'un controle faut juste ajouter l'extention de style WS_EX_ACCEPTFILES a GuiCreate() et dy ajouter à l'état (guionevent) $GUI_DROPACCEPTED

la traduction c'est grosomodo version ani ^__^'

bonne continuation

Pour sur Ani, mais dans le code de SagePourpre, il y a ecrit:

$Form1 = GUICreate("Form1", 268, 311, 193, 125, Default, $WS_EX_ACCEPTFILES)

J'avais deja verifié ce detail...

Je ne sasi vraiment pas d'ou vient le Marche-pas

timmalos a écrit :Pour sur Ani, mais dans le code de SagePourpre, il y a ecrit:

$Form1 = GUICreate("Form1", 268, 311, 193, 125, Default, $WS_EX_ACCEPTFILES)

J'avais deja verifié ce detail...

Je ne sasi vraiment pas d'ou vient le Marche-pas

En fait, comme ani l'a mentionner en haut, le problème, dans mon script, était
le $WS_EX_ACCCEPTFILES que j'avais mis dans mes input alors que je ne devais le mettre
que dans guicreate() et nulle part ailleurs.

Depuis que j'ai retiré les $WS_EX_ACCEPTFILES des input, ça marche à merveilles.

Gné ! Y'avait pas ce message quand j'ai repondu tout a l'heure

Ani a fait un tour de passe-passe?

AutoIt Français

[R] Problème de Drag & Drop.

[R] Problème de Drag & Drop.

Re: [...] Problème de Drag & Drop.

Re: [R] Problème de Drag & Drop.

Re: [...] Problème de Drag & Drop.

Re: [...] Problème de Drag & Drop.

Re: [..] Problème de Drag & Drop.

Re: [..] Problème de Drag & Drop.

Re: [R] Problème de Drag & Drop.