AutoIt Français

Code : Tout sélectionner

#include <GUIConstants.au3>

Global Const $TCM_SETIMAGELIST = 0x1303
Global Const $TCM_SETITEM = 0x1306

; Disable visual styles for controls
;DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 1)

Global $hImageList = 0


$main_GUI = GUICreate("Tab Sample", 400, 300, -1, -1);, BitOr($GUI_SS_DEFAULT_GUI,$WS_CLIPSIBLINGS))
$ok_button = GUICtrlCreateButton("OK", 110, 270, 70, 20)
$cancel_button = GUICtrlCreateButton("Cancel", 220, 270, 70, 20)
GUISetState()

; Creates the first child window that is implemented into the main GUI
$child1 = GUICreate("", 370, 215, 15, 40, BitOr($WS_CHILD,$WS_TABSTOP), -1, $main_GUI)
;GUISetBkColor(0x257788); just for dimensing the child
$child1_tab = GUICtrlCreateTab(0, 0, 370, 215)
$child1_tabitem1 = GUICtrlCreateTabItem("Child1Tab1")
$child1_tabitem2 = GUICtrlCreateTabItem("Child1Tab2")
$child1_tabitem3 = GUICtrlCreateTabItem("Child1Tab3")
GUICtrlCreateTabItem("")

GUISetState()

; Creates the second child window that is implemented into the main GUI
$child2 = GUICreate("", 370, 215, 15, 40, BitOr($WS_CHILD,$WS_TABSTOP), -1, $main_GUI)
;GUISetBkColor(0x257788); just for dimensing the child

$child3 = GUICreate("", 210, 220, 158, 0, BitOr($WS_CHILD,$WS_TABSTOP), -1, $child2)
;GUISetBkColor(0x257788)
$listview = GUICtrlCreateListView("Col1|Col2", 0, 2, 210, 211, BitOr($LVS_NOSORTHEADER,$LVS_SHOWSELALWAYS,$WS_TABSTOP), $WS_EX_CLIENTEDGE)
GUICtrlCreateListViewItem("ItemLong1|ItemLong2", $listview)
GUICtrlCreateListViewItem("ItemLong3|ItemLong4", $listview)
GUICtrlCreateListViewItem("ItemLong5|ItemLong6", $listview)
GUISetState()

GUISwitch($child2)
$child2_tab = GUICtrlCreateTab(0, 0, 156, 215)
$child2_tabitem1 = GUICtrlCreateTabItem("Child2Tab1")
$child2_tabitem2 = GUICtrlCreateTabItem("Child2Tab2")
GUICtrlCreateTabItem("")

; Switch back the main GUI and create the tabs
GUISwitch($main_GUI)
$main_tab = GUICtrlCreateTab(10, 10, 380, 250)
$main_tabitem1 = GUICtrlCreateTabItem("MainTab1")
$main_tabitem2 = GUICtrlCreateTabItem("MainTab2")
GUICtrlCreateTabItem("")
GUICtrlSetState($main_tabitem1,$GUI_SHOW)

Bind_ImageList($main_tab)

While 1
$msg = GUIGetMsg(1)
Select
Case $msg[0] = $GUI_EVENT_CLOSE Or $msg[0] = $cancel_button
ExitLoop

Case $msg[0] = $main_tab
$tabidx = GUICtrlRead($main_tab)
Select 
Case $tabidx = 0
GUISetState(@SW_HIDE, $child2)
GUISetState(@SW_SHOW, $child1)

Case $tabidx = 1
GUISetState(@SW_HIDE, $child1)
GUISetState(@SW_SHOW, $child2)
EndSelect
EndSelect
WEnd

DllCall("comctl32.dll", "int", "ImageList_Destroy", "hwnd", $hImageList)
Exit



Func ImageList_Create()
$hImageList = DllCall("comctl32.dll", "hwnd", "ImageList_Create", "int", 16, "int", 16, "int", 0x0021, "int", 0, "int", 1)
$hImageList = $hImageList[0]
Return $hImageList
EndFunc


Func Bind_ImageList($nCtrl)
$hImageList = ImageList_Create()
GUICtrlSendMsg($nCtrl, $TCM_SETIMAGELIST, 0, $hImageList)

$szIconFile = "shell32.dll"

$tcitem = DllStructCreate("uint;dword;dword;ptr;int;int;int")
DllStructSetData($tcitem, 1, 0x0002)
DllStructSetData($tcitem, 6, 0)
AddImageToTab($nCtrl, 0, $tcitem, $szIconFile, 12)

DllStructSetData($tcitem, 6, 1)
AddImageToTab($nCtrl, 1, $tcitem, $szIconFile,21)


EndFunc


Func AddImageToTab($nCtrl, $nTabIndex, $nItem, $szIconFile, $nIconID)
$hIcon = DllStructCreate("int")
$result = DllCall("shell32.dll", "int", "ExtractIconEx", "str", $szIconFile, "int", $nIconID, "hwnd", 0, "ptr", DllStructGetPtr($hIcon), "int", 1)
$result = $result[0]
If $result > 0 Then
DllCall("comctl32.dll", "int", "ImageList_AddIcon", "hwnd", $hImageList, "hwnd", DllStructGetData($hIcon,1))
DllCall("user32.dll", "int", "SendMessage", "hwnd", ControlGetHandle($main_GUI, "", $nCtrl), "int", $TCM_SETITEM, "int", $nTabIndex, "ptr", DllStructGetPtr($nItem))
DllCall("user32.dll", "int", "DestroyIcon", "hwnd", $hIcon)
EndIf


EndFunc
 

Code : Tout sélectionner

#include <GuiConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


$Gui = GuiCreate("Parent Gui", 500, 500)

GUISetState()

$Help = GuiCtrlCreateTab(10, 40, 480, 450)
GuiCtrlCreateTabItem("First Tab Item")
GuiCtrlCreateTabItem("Help")

$HelpGui = GuiCreate("Help", 400, 200, -1,-1, $WS_POPUPWINDOW, -1, $Gui)
$ssHelp = GuiCtrlCreateTab(10, 10, 250, 150)
    GuiCtrlCreateTabItem("First ss Tab Item")
    GUICtrlCreateButton("Test1",30,50)
    GuiCtrlCreateTabItem("Second ss Tab Item")
    GUICtrlCreateButton("Test2",50,50)
While 1
    $Msg = GUIGetMsg()
    Select
        Case $Msg = $Help
            If GUICtrlRead($Help) = 1 Then
                GUISetState(@SW_SHOW, $HelpGui)
            Else
                GUISetState(@SW_HIDE, $HelpGui)
            EndIf
        Case $Msg = -3
            Exit
    EndSelect
WEnd
 

Code : Tout sélectionner

#include <GUIConstants.au3>

$MainGui = GUICreate("test2tab", 460, 640, (@DesktopWidth - 460) / 2, (@DesktopHeight - 640) / 2); , $WS_EX_STATICEDGE) ; Crée une frame de 460x640 au centre de l'écran

$tab = GUICtrlCreateTab(0, 15, 462, 540) ; Crée le système d'onglet

GUISetState()

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;     TAB 1

$tab0 = GUICtrlCreateTabItem("1er tab")

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;     TAB 2
$tab1 = GUICtrlCreateTabItem("2eme tab")
GUICtrlSetState(-1, $GUI_SHOW); Premier onglet a être activé

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;     TAB 2.1

$HardGui = GUICreate("2 eme fenetre de tab", 460, 514, (@DesktopWidth - 456) / 2, (@DesktopHeight - 508) / 2, $WS_POPUPWINDOW, $WS_EX_APPWINDOW, $MainGui)
$SSHard = GUICtrlCreateTab(10, 10, 442, 494)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;     TAB 2.1.1

GUICtrlCreateTabItem("1er tab de 2")


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;     TAB 2.1.2

GUICtrlCreateTabItem("2eme tab de 2")



GUISetState()
WinSetTrans($HardGui, "", 255)
While 1
    $wpm = WinGetPos($MainGui)
    $x = $wpm[0] + 2
    $y = $wpm[1] + 66
    WinMove($HardGui, "", $x, $y)
    $Msg = GUIGetMsg()
    If $Msg = -3 Or $Msg = -1 Then ExitLoop
    Select
        Case $Msg = $tab
            If GUICtrlRead($tab) = 1 Then
                GUISetState(@SW_SHOW, $HardGui)
            Else
                GUISetState(@SW_HIDE, $HardGui)
            EndIf
    EndSelect
WEnd
Exit