AutoIt Français

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

;Lecture de la liste des serveurs
Local $hFile = FileOpen(@scriptdir & "\servers.txt")
Local $sliste = ""

; création du menu déroulant
While 1
    $line = FileReadLine($hFile)
    If @error = -1 Then ExitLoop
    $aData = stringsplit($line,"|")
    $sServer = $aData[1] & " / " & $aData[2] & " / " & $aData[3]; [1]=Ville [2]=SiteName [3]=ID
    $sliste = $sliste & $sServer & "|"
WEnd
FileClose($hFile)


#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("SpeedTest GUI", 371, 176, 192, 124)
$Combo1 = GUICtrlCreateCombo("", 16, 24, 241, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData($Combo1, $sliste, "Massy / TestDebit.info / 2231")
$Label1 = GUICtrlCreateLabel("Choisir serveur", 16, 8, 73, 16)
$Button1 = GUICtrlCreateButton("Lancer !", 288, 24, 65, 25)
$Edit1 = GUICtrlCreateEdit("", 16, 64, 337, 97,$ES_WANTRETURN)
GUICtrlSetData(-1, "")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button1
            $sSelection = GUICtrlRead($Combo1) ; on lit la selection
            $aServeur = stringsplit($sSelection,"/")
            $sServeur = $aServeur[3] ; on récupère l'ID du serveur

            GUICtrlSetState($Button1, $GUI_DISABLE) ; On désactive le bouton durant l'exécution
            GUICtrlSetData($Edit1,"Speedtest en cours....")

            ; Execution de la commande
            runwait(@ComSpec & " /c " & 'speedtest.exe -s ' & $sServeur & '>result.txt', "", @SW_HIDE)

            ; On lit le résultat dans le fichier
            $hFile = FileOpen(@scriptdir & "\result.txt")
            $sFile = FileRead($hFile)

            ; On récupère les données qui nous interessent
            $aPing = StringRegExp($sFile, 'Ping \(Lowest\): (.*?)\|', 3)
            $aDownload = StringRegExp($sFile, 'Download \(Max\): (.*?)\|', 3)
            $aUpload = StringRegExp($sFile, 'Upload \(Max\): (.*?)Mbps', 3)

            ; On formate le résultat pour l'affichage
            $result = "Serveur : " & $sSelection & @CRLF & _
                      "Ping : " & $aPing[0] & @CRLF & _
                      "Download : " & $aDownload[0] & @CRLF & _
                      "Upload : " & $aUpload[0] & "Mbps"
            FileClose($hFile)
            FileDelete(@scriptdir & "\result.txt")

            GUICtrlSetData($Edit1,$result) ; On affiche le résultat
            GUICtrlSetState($Button1, $GUI_ENABLE) ; On réactive le bouton

    EndSwitch
WEnd

Code : Tout sélectionner

            $chemin = @ScriptDir & '\speedtest.exe -l'
            $ecoute = run( $chemin, @WorkingDir, @SW_HIDE, $STDOUT_CHILD)
    Local $data = ""
   While True
       $data &=   StdoutRead($ecoute)

        If @error Then ExitLoop
        Sleep(25)

    WEnd

Code : Tout sélectionner

#Include <Array.au3>
#include <WinHTTP.au3>

SplashTextOn ("", "Chargement de la liste des serveurs ...", 380, 55, -1, 300, 49)
$txt = BinaryToString(InetRead("http://c.speedtest.net/speedtest-servers-static.php", 1))
SplashTextOn ("", "Tri des serveurs français ...", 380, 55, -1, 300, 49)
$a = StringRegExp($txt, '<server url="([^"]+).*?name="([^"]+).*?cc="FR.*?sponsor="([^"]+)', 3)
SplashOff()
; _ArrayDisplay($a)
$oHTTP = ObjCreate("Microsoft.XMLHTTP")
Local $bestindex, $latency = 1000
For $i = 0 to UBound($a)-1 step 3
   SplashTextOn ("", "      Test du serveur :    " & $a[$i+1], 350, 55, -1, 300, 53)
   $tmp = _test($a[$i])
   If $tmp < $latency Then
      $bestindex = $i
      $latency = $tmp 
   EndIf
Next
SplashOff()
$bestserver = StringReplace($a[$bestindex], "/speedtest/upload.php", "")
$name = $a[$bestindex+1]
$sponsor = $a[$bestindex+2]
Msgbox(0,"", "meilleur serveur :  " & $name & " (" & $sponsor & ")" &@crlf& $bestserver &@crlf& $latency)

;===========================================

$UserAgent = "Mozilla/5.0 (Windows NT 5.1; rv:14.0) Gecko/20100101 Firefox/14.0.1"
$s = ""
$chars = '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
For $i = 1 to 16000
  $s &= $chars
Next
$sPD = Binary($s)   ; 500 Ko environ

SplashTextOn ("", "Test de débit montant ...", 380, 55, -1, 300, 49)
$upspeed = _Upld($bestserver, "speedtest/upload.php", $sPD) 
Sleep(100)
SplashTextOn ("", "Test de débit descendant ...", 380, 55, -1, 300, 49)
$dwspeed = _Dwld($bestserver, "speedtest/random2500x2500.jpg")  ; 12 Mo
SplashOff()

Msgbox(0,"", "descendant =  " & $dwspeed &@crlf&  "montant =  " & $upspeed)

;=============================================
Func _Upld($server, $page, $data) 
$server = StringReplace($server, "http://", "")
$hHttpOpen = _WinHttpOpen($UserAgent)
$hHttpConnect = _WinHttpConnect($hHttpOpen, $server)
$hHttpRequest = _WinHttpOpenRequest($hHttpConnect, "POST", $page)
_WinHttpSendRequest($hHttpRequest, Default, $sPD, BinaryLen($sPD))
$begin = TimerInit()
_WinHttpReceiveResponse($hHttpRequest)
$time = Floor(TimerDiff($begin) )
Global $sReturned
If _WinHttpQueryDataAvailable($hHttpRequest) Then
    Do
        $sReturned &= _WinHttpReadData($hHttpRequest)
    Until @error
EndIf
$sHeader = _WinHttpQueryHeaders($hHttpRequest)
$size = StringLen($UserAgent) + BinaryLen($sPD) + StringLen($sHeader) + StringLen($sReturned)
_WinHttpCloseHandle($hHttpRequest)
_WinHttpCloseHandle($hHttpConnect)
_WinHttpCloseHandle($hHttpOpen)
$moysize = ($size*8)/1000
$moytime = ($time/1000)
Return Round($moysize/$moytime, 1)
EndFunc

Func _Dwld($server, $sTarget) 
$server = StringReplace($server, "http://", "")
$hHttpOpen = _WinHttpOpen($UserAgent)
$hHttpConnect = _WinHttpConnect($hHttpOpen, $server)
$hHttpRequest = _WinHttpOpenRequest($hHttpConnect, "GET", $sTarget)  
;_WinHttpAddRequestHeaders($hHttpRequest, $RequestHeaders)
_WinHttpSendRequest($hHttpRequest)
$begin = TimerInit()
_WinHttpReceiveResponse($hHttpRequest)
Local $bChunk, $bData = Binary(""), $hFile, $error
If _WinHttpQueryDataAvailable($hHttpRequest) Then
    While 1
        $bChunk = _WinHttpReadData($hHttpRequest, 2, 4096) ;  binary
        If @error Then ExitLoop
        $bData &= $bChunk
    WEnd
   $time = Floor(TimerDiff($begin) )
Else
    MsgBox(48, "", "erreur de connection ou d'identification")
    $error = 1
EndIf
$headers = _WinHttpQueryHeaders($hHttpRequest)
$size = StringRegExp($headers, 'Content-Length\D*(\d+)', 3)[0]
$size += StringLen($headers)
$size += StringLen($UserAgent)
_WinHttpCloseHandle($hHttpRequest)
_WinHttpCloseHandle($hHttpConnect)
_WinHttpCloseHandle($hHttpOpen)
If $error = 1 Then Return "tilt"
$moysize = ($size*8)/1000
$moytime = ($time/1000)
Return Round($moysize/$moytime, 1)
EndFunc   ;==>_Dwld

Func _test($url)
  $oHTTP.Open("GET", $url, 0)
  $begin = TimerInit()
  $oHTTP.Send()
  If $oHTTP.readystate = 4 Then 
      $time = TimerDiff($begin)
      Return ($time > 150) ? 1000 : $time
  EndIf
;  If $oHTTP.Status = 200 Then Return ($time > 150) ? 1000 : $time
EndFunc
 

Code : Tout sélectionner

$ipLocation = BinaryToString (InetRead("http://ip-api.com/json"))
$lat = StringRegExp($ipLocation, '"lat":(-?\d+(?:.\d+)?)', 1)[0]
$lon = StringRegExp($ipLocation, '"lon":(-?\d+(?:.\d+)?)', 1)[0]
ConsoleWrite("latitude=" & $lat & "; longitude=" & $lon & @CRLF)
$txt = BinaryToString(InetRead("http://www.speedtest.net/speedtest-servers.php", 0))

$a = StringRegExp($txt, 'url="([^"]+)" lat="([^"]+)" lon="([^"]+)" name="([^"]+)".+?cc="FR" sponsor="([^"]+)"', 3)

$iPlusProche = 0
$iIndexPlusProche = 0
For $i = 0 To UBound($a) - 1 Step 5
    $distLat = $lat - $a[$i + 1]
    $distLon = $lon - $a[$i + 2]
    $dist = Sqrt( ($distLat ^2)  + ($distLon ^2) )
    If $iPlusProche = 0 Then
        $iPlusProche = $dist
    ElseIf $dist < $iPlusProche Then
        $iPlusProche = $dist
        $iIndexPlusProche = $i
    EndIf
Next

MsgBox(0, "", "Serveur le plus proche : " & @CRLF & "URL=" & $a[$iIndexPlusProche] & @CRLF & "Name=" & $a[$iIndexPlusProche + 3] & @CRLF & "Sponsor=" & $a[$iIndexPlusProche + 4] )