AutoIt Français

Code : Tout sélectionner

#include <Array.au3>

$Users = _SystemUsers(0)
_ArrayDisplay($Users)

#cs ===============================================================================
    Function:      _SystemUsers($AccountType = 0)
    Description:   Return an array with the local or domain username
    Parameter(s):  $AccountType: Local, domain or both username
        0 = Local and Domain usernames
        1 = Local usernames only
        2 = Domain usernames only
    Returns:       An array with the list of usernames - Succeeded
        @error 1 - Didn't query any username
        @error 2 - Failed to create Win32_SystemUsers object
        @error 3 - Invalid $AccountType

    Author(s):  Danny35d
#ce ===============================================================================
Func _SystemUsers($AccountType = 0)
    Local $aSystemUsers
    Local $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20
    Local $colItems = "", $strComputer = "localhost"

    If Not StringRegExp($AccountType, '[012]') Then Return SetError(3, 3, '')
    $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\CIMV2")
    $colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_SystemUsers", "WQL", _
            $wbemFlagReturnImmediately + $wbemFlagForwardOnly)

    If IsObj($colItems) Then
        For $objItem In $colItems
            $Output = StringSplit($objItem.PartComponent, ',')
            If IsArray($Output) Then
                $Temp = StringReplace(StringTrimLeft($Output[2], StringInStr($Output[2], '=', 0, -1)), '"', '')
                If $AccountType = 0 Or ($AccountType = 1 And @ComputerName = $Temp) Then
                    $aSystemUsers &= StringReplace(StringTrimLeft($Output[1], StringInStr($Output[1], '=', 0, -1)), '"', '') & '|'
                ElseIf $AccountType = 2 And @ComputerName <> $Temp Then
                    $aSystemUsers &= StringReplace(StringTrimLeft($Output[1], StringInStr($Output[1], '=', 0, -1)), '"', '') & '|'
                EndIf
            EndIf
        Next
        $aSystemUsers = StringTrimRight($aSystemUsers, 1)
        If $aSystemUsers = '' Then Return(SetError(1, 1, $aSystemUsers))
        Return(SetError(0, 0, StringSplit($aSystemUsers, '|')))
    Else
        $aSystemUsers = ''
        Return(SetError(2, 2, $aSystemUsers))
    EndIf
EndFunc   ;==>_SystemUsers

 

Code : Tout sélectionner

#include <Security.au3>
#include <Array.au3>
 
$aProfiles = _GetUserProfileList()
_ArrayDisplay($aProfiles)
 
 
 
; #FUNCTION# ====================================================================================================================
; Name ..........: _GetUserProfileList
; Description ...: Returns an array containing the users profiles
; Syntax ........: _GetUserProfileList()
; Parameters ....: None
; Return values .: A 2D array :
;                    $aArray[0][0] - Number of profiles
;                    $aArray[1][0] - 1st domain\username of the account associated to the profile
;                    $aArray[1][1] - 1st profile path
;                    $aArray[1][2] - 1st user SID
;                    $aArray[n][0] - nth username
;                    ...
; Author ........: jguinch
; ===============================================================================================================================
Func _GetUserProfileList()
    Local $sKey = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList"
    Local $iCount = 0, $sSubKey, $sProfileImagePath, $aAccountInfos
 
    Local $aReturn[1][3]
 
    While 1
        $iCount += 1
        $sSubKey = RegEnumKey($sKey, $iCount)
        If @error Then ExitLoop
 
 
        If StringRegExp($sSubKey, "(?i)S-1-5-21-(\d+-){3}\d+") Then
            $sProfileImagePath = StringReplace( _ExpandEnvStrings ( RegRead($sKey & "\" & $sSubKey, "ProfileImagePath") ), "::", ":")
            If FileExists($sProfileImagePath) Then
                Redim $aReturn[ UBound($aReturn) + 1][3]
 
                $aAccountInfos = _Security__LookupAccountSid($sSubKey)
                If IsArray($aAccountInfos) Then $aReturn[ UBound($aReturn) - 1][0] = $aAccountInfos[1] & "\" & $aAccountInfos[0]
                $aReturn[ UBound($aReturn) - 1][1] = $sProfileImagePath
                $aReturn[ UBound($aReturn) - 1][2] = $sSubKey
            EndIf
        EndIf
    WEnd
    $aReturn[0][0] = UBound($aReturn) - 1
 
    Return $aReturn
EndFunc ; ===> _GetUserProfileList
 
 
 
Func _ExpandEnvStrings($sString)
    Local $aVars = StringRegExp($sString, "%([^%]+)%", 3)
    Local $iCount = 0
 
    If IsArray($aVars) Then
        For $i = 0 To UBound($aVars) - 1
            $sVal = EnvGet($aVars[$i])
            If $sVal <> "" Then
                $sString = StringReplace($sString, "%" & $aVars[$i] & "%", $sVal )
                $iCount += 1
            EndIf
        Next
        SetExtended( $iCount )
    Else
        SetExtended(0)
    EndIf
 
    Return $sString
EndFunc