AutoIt Français

Bonsoir je me permet de re-post car une partie de premier post n'a pas été entièrement résolue.
Donc je voudrais qu'il s’exécute à une heure au hasard , 4 fois en tout avec 2 h d'intervalle entre chaque exécution en 1 jour , puis on reprend le jours prochain j'ai plusieurs idée mais je bloque :
- Pour cela le temps aléatoire doit être > au temps réel @HOUR & @MIN pour moi , j'ai essayer :

Code : Tout sélectionner

Const $Temps_aleatoire = Random(0000,24.00,0000)
$Time = @HOUR

Do
    If ( $Temps_aleatoire > $Time ) Then
MsgBox(0, " Tritre " , " Le temps aléatoire est supérieur au temps " ) ; j'ai remplacer mon action par MsgBox pour me faire une idée 


Else
    MsgBox(0,"titre" , " le temps aléatoire est mauvais " ) 

EndIf
Until ($Temps_ aleatoire > $Time )

Je ne sais pas comment dire de prendre une autre chiffre aléatoire
Mais je pense qu'il y a un MOYEN de générer un nombre aléatoire avec Random > ou < a un nombre , pour mon car > à @HOUR du genre :

Code : Tout sélectionner

 $Exemple = Random(>@HOUR,max 24h

Je ne sais toujours pas en quelle unité il sont les heures , moi je vois de 0 à 24 pour @HOUR , 0 à 2400 pour @HOUR & @MiN , etc ...

Ensuite il me faut un moyen de faire un genre de compte à rebours ( 4 exécution par jour ) : 1er exécution à 13h46 , plus que 3 . 2eme exécution à 16h09 plus que 2 , etc ... Pour ça je n'ai vraiment aucune idée

Pour finir exécuter le programme toutes les 2 h minimum , je pense pas que cela ai un rapport avec TimerInit et TimerDiff

Petite idée de conclusion

Si ont a pas déjà exécuter le programme plus de 4 fois en 24 alors
On l'exécute si la dernière exécution a eut lieu il y a plus de 2 heures

Si vous avez d'autre genre d'idée pour l 'IA , n'hésitez pas a les proposer .

PS : Je c'est que tout ceci est très difficile ( pour moi , je débute tout juste et peut être même pour vous ) , mais j'aimerais bien que les personnes ayant de l’expérience
puissent m'aider à configurer correctement mon IA

Je vous remercie d'avoir lu ce post , en espérant des réponses

Cordialement ; Sharz

-

Voila ma méthode

► Afficher le texte

Code : Tout sélectionner

#NoTrayIcon
#include <Date.au3> ; Pour _NowCalc()

Global $__g_iTimerDebut = 0, $__g_iTimerProchaineExecution = 0, $__g_iTimerDerniereExecution = 0
Global $__g_iNbrExecutions = 0

Global $__g_iDelaiMinimumEntreExecutions = 2 * 60 * 60 * 1000 ; 2h
Global $__g_iDelaiMaximumEntreExecutions = 6 * 60 * 60 * 1000 ; 6h
;~ Vous ne l'avez pas spécifier, mais cette variable est essentielle pour définir un délai aléatoire (Random)
;~ Si vous voulez que le délai aléatoire puisse être supérieur à 6h, il suffit de changer la valeur de cette variable
;~ PS: J'ai choisi 6h, car il y a 4x 6h dans 24h

Global $__g_iDelaiAvantProchaineExecution = 0
; ---

$__g_iTimerDebut = TimerInit()
ConsoleWrite("Lancement: " & _NowCalc() & @CRLF)

While 1
    ; Définit le delai avant la prochaine exécution
    ; ---
    ; Si aucun délai avant une prochaine exécution n'est défini, alors on en définit un
    If $__g_iDelaiAvantProchaineExecution = 0 Then
        $__g_iDelaiAvantProchaineExecution = Random($__g_iDelaiMinimumEntreExecutions, $__g_iDelaiMaximumEntreExecutions, 1)
        $__g_iTimerProchaineExecution = TimerInit()
        ; ---
        ConsoleWrite("Prochaine exécution dans: " & $__g_iDelaiAvantProchaineExecution & " ms (" & _MsToTime($__g_iDelaiAvantProchaineExecution) & ")" & @CRLF)
    EndIf
    ; ---
    ; On test si le délai avant la prochaine exécution est passé
    If $__g_iDelaiAvantProchaineExecution <> 0 And TimerDiff($__g_iTimerProchaineExecution) >= $__g_iDelaiAvantProchaineExecution Then
        _Execute()
        ; ---
        ; Remise à zéro
        $__g_iDelaiAvantProchaineExecution = 0
        $__g_iTimerProchaineExecution = 0
    EndIf
    ; ---
    ; Vérifie si 24h sont passées
    If TimerDiff($__g_iTimerDebut) >= 86400000 Then ; Nombre de milisecondes en une journée
        ; Si aucune exécution dans les 24h passées ET délai depuis la dernière exécution est > 2h, alors on exécute
        ConsoleWrite("24h sont passées ..." & @CRLF)
        If $__g_iNbrExecutions = 0 And TimerDiff($__g_iTimerDerniereExecution) >= 7200000 Then
            ConsoleWrite("Aucune exécution en 24h => " & @CRLF)
            _Execute()
        EndIf
        ; ---
        ; Remise à zéro du timer, du compteur d'exécutions, et du délai de prochaine exécution
        ConsoleWrite("... Remise à zéro" & @CRLF)
        $__g_iTimerDebut = TimerInit()
        $__g_iNbrExecutions = 0
        ; ---
        $__g_iDelaiAvantProchaineExecution = 0
        $__g_iTimerProchaineExecution = 0
    EndIf
WEnd

Func _Execute()
    ConsoleWrite("Exécution: " & _NowCalc() & @CRLF)
    $__g_iTimerDerniereExecution = TimerInit()
EndFunc

Func _MsToTime($iMs)
    Local $iH, $iM, $iS
    _TicksToTime($iMs,  $iH, $iM, $iS)
    Return  $iH & ":" & $iM & ":" & $iS
EndFunc

Ce script doit être considéré comme appartenant à l'IA ?

Merci beaucoup Matwachish , beau code ^^

En 2013 il y avait déja de l'IA style chatbot Bonatnation AI ? Je ne savais pas désolé de déterrer le topic mais ca m'intrigue.

Bonjour,
Tout dépend de ce qu'on appelle IA. Si c'est faire de magnifique image de personne avec 6 doigts, bof !
Si c'est la super gestion de bases de données, bof !
Si c'est faire rouler une voiture sans écraser quelqu'un, bof !
Pour moi, IA c'est un programme qui s'auto-corrige. Si il y a bug, il le repère et modifie son programme. Il me semble qu'on en soit loin ! Mais bon, c'est un avis personnel

Il est de bon ton de parler de l'IA dès que l'informatique innove mais l'IA dans sa définition suppose l’absence de l'action de l'être humain...

En tout cas en ce qui concerne ce sujet, il illustre parfaitement le nombre invraisemblable de situations où le terme "Intelligence Artificielle" a été fort abusivement utilisé, juste pour qualifier un programme légèrement plus "intelligent" que les autres - comprendre : un peu mieux foutu que les autres

Edit
Les chatbots de l'époque puisaient (comme encore maintenant d'ailleurs) dans un stock de réponses préprogrammées, en réagissant (ou pas) sur des mots-clé écrits dans la question, une sorte de FAQ online
Mais à présent évidemment ils vont de plus en plus utiliser l'IA

AutoIt Français

[R] Configuration de mon Intelligence Artificielle

[R] Configuration de mon Intelligence Artificielle

Re: [..] Configuration de mon Intelligence Artificielle

Re: [..] Configuration de mon Intelligence Artificielle

Re: [R] Configuration de mon Intelligence Artificielle

Re: [R] Configuration de mon Intelligence Artificielle

Re: [R] Configuration de mon Intelligence Artificielle

Re: [R] Configuration de mon Intelligence Artificielle