AutoIt Français

Voici un petit UDF intéressent, qui vous permettra d'intégrer un fichier directement dans le code source de votre script.
Ce code fonctionne pour tous types de fichiers sans exception (attention toutefois à la taille de ceux-ci).
Cette fonction ne remplace en rien l'utilisation de la commande FileInstall(), ou l'ajout des ressources directement à l'exécutable par le biais de directive ou l'utilisation de ResHacker, mais elle ajoute une portée différente à l'intégration d'un fichier ou d'une ressource à votre code.

Description :
Le fichier est inscrit sous forme de chaînes binaires de 128 caractères dans une fonction pour être utilisé plus tard en tant que chaîne unique.

Pour re-générer le fichier, il suffit de lancer la fonction (Pour ce faire, dé-commenté la deuxième ligne du script généré et lancez le script).
Vous devrez aussi modifier le chemin et le nom du fichier, sinon le nom d'origine est utilisé et le fichier sera donc re-généré en lieu et place du fichier d'origine.

Voici l'UDF en question, adapté de l'UDF original ConvertImageToBinary.au3.
J'ai rajouter le code pour re-générer le fichier et modifier la manière dont est géré le nom de la fonction.

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version(s)  : 3.2.12.0 - 3.3.2.0
 Auteur             : Tlem

 Fonction du Script :
    Script adapté de l'UDF ConvertImageToBinary.au3 qui permet de transformer
    un fichier en code binaire qui peut être inclus tel quel dans un code AutoIt.
    L'appel de la fonction permet de re-générer le fichier.

#ce ----------------------------------------------------------------------------

$file = FileOpenDialog("Fichier à convertir", @DesktopDir, "All Files (*.*)")
If @error Then Exit

$Fname = StringTrimLeft($file, StringInStr($file, "\", 1, -1))
$Path = StringTrimRight($file, StringLen($Fname))

$f = FileOpen($file, 16)
$t = FileRead($f)
FileClose($f)
$z = StringRegExp($t, "(.{1,128})", 3)
$Ubound = UBound($z)
$FuncName = StringReplace($Fname, ".", "_")
$FuncName = StringRegExpReplace($FuncName, '[^\w]', '')
$FuncName = StringRegExpReplace($FuncName, '[^\D]', '')

$String = '; Décommenté la ligne si dessous pour re-générer le fichier (vous pouvez ajuster le nom et le chemin).' & @CRLF
$String &= '; ' & $FuncName & '("' &  $Path & $Fname& '")' & @CRLF & @CRLF


If $Ubound = 1 Then
    $String &= 'Func ' & $FuncName & '($Name)' & @CRLF & '   $FileBin = "' & $z[0] & '"'
ElseIf $Ubound > 1 Then
    $String &= 'Func ' & $FuncName & '($Name)' & @CRLF & '   $FileBin = "' & $z[0] & '"' & @CRLF
    For $i = 1 To $Ubound - 2 Step 1
        $String &= '   $FileBin &= "' & $z[$i] & '"' & @CRLF
    Next
    $String &= '   $FileBin &= "' & $z[$Ubound - 1] & '"' & @CRLF
EndIf

If $Ubound > 0 Then
    $String &= @CRLF
    $String &= '   $hFile = FileOpen($Name, 17)' & @CRLF
    $String &= '   If $hFile = -1 Then' & @CRLF
    $String &= '     MsgBox(0, "Erreur", "Impossible de re-créer le fichier.")' & @CRLF
    $String &= '     Exit' & @CRLF
    $String &= '   EndIf' & @CRLF
    $String &= '   FileWrite($hFile, $FileBin)' & @CRLF
    $String &= '   FileClose($hFile)' & @CRLF & @CRLF
    $String &= 'EndFunc'
EndIf

FileDelete(@TempDir & "\FicTmp.au3")
FileWrite(@TempDir & "\FicTmp.au3", $String)
ShellExecute(@TempDir & "\FicTmp.au3", '', '', "edit")

Voici un exemple de fichier créé :

► Afficher le texte

Pour re-généré ce fichier, vous n'avez qu'à dé-commenter la deuxième ligne puis à lancer le script.
Le fichier C:\_FileToBinaryFunction_Demo.txt sera re-généré avec son contenu.
Sinon il vous suffira d'appeler la fonction _FileToBinaryFunction_Demo_txt() (fonction générée dynamiquement avec le nom du fichier d'origine), en précisant en argument le nom et le cas échéant le chemin du fichier de sortie.

Edition du 17/06/2011 :
Voici une version beaucoup plus simple et qui génère une simple fonction dont le rôle est de créer une variable qui contiendra le code binaire de votre fichier. Ensuite, libre à vous de faire ce que vous voulez avec cette variable (écriture de fichier ou utilisation directe à partir de la mémoire).

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version(s)  : 3.3.6.1
 Auteur             : Tlem

 Fonction du Script :
    Script adapté de l'UDF ConvertImageToBinary.au3 qui permet de transformer
    un fichier en code binaire qui peut être inclus tel quel dans un code AutoIt.
    L'appel de la fonction permet de recupérer le fichier sous forme binaire
    afin de le recréer ou de l'utiliser tel quel à partir de la mémoire.

#ce ----------------------------------------------------------------------------

$file = FileOpenDialog("Fichier à convertir", @DesktopDir, "All Files (*.*)")
If @error Then Exit

$Fname = StringTrimLeft($file, StringInStr($file, "\", 1, -1))
$Path = StringTrimRight($file, StringLen($Fname))

$f = FileOpen($file, 16)
$t = FileRead($f)
FileClose($f)
$z = StringRegExp($t, "(.{1,512})", 3) ; Longeur de ligne (512)
$Ubound = UBound($z)
$FuncName = StringReplace($Fname, ".", "_")
$FuncName = StringRegExpReplace($FuncName, '[^\w]', '')
$FuncName = StringRegExpReplace($FuncName, '[^\D]', '')

Global $String

If $Ubound = 1 Then
    $String &= 'Func ' & $FuncName & '()' & @CRLF & '   Local _' & @CRLF & '   $FileBin = "' & $z[0] & '"'
ElseIf $Ubound > 1 Then
    $String &= 'Func ' & $FuncName & '()' & @CRLF & '   Local _'& @CRLF & '   $FileBin = "' & $z[0] & '"' & @CRLF
    For $i = 1 To $Ubound - 2 Step 1
        $String &= '   $FileBin &= "' & $z[$i] & '"' & @CRLF
    Next
    $String &= '   $FileBin &= "' & $z[$Ubound - 1] & '"' & @CRLF
EndIf

If $Ubound > 0 Then
    $String &= '   Return Binary($FileBin)' & @CRLF
    $String &= 'EndFunc'
EndIf

FileDelete(@TempDir & "\FicTmp.au3")
FileWrite(@TempDir & "\FicTmp.au3", $String)
ShellExecute(@TempDir & "\FicTmp.au3", '', '', "edit")

Mise à jour du premier message.

Code :
- Ajout du contrôle du nom de la fonction générée dynamiquement (avant certains caractère parasite pouvaient rendre la fonction inopérante).
- Suppression de l'Include Array.au3 totalement inutile.
- Suppression de la valeur par défaut de l'argument de la fonction.

Message :
- Ajout de certaines précisions (type de fichiers, fonctionnement).
- Ajout d'un exemple de fichier résultant.

Faudrait penser à créer une fonction de double binarisation : le fichier sera plus léger sûrement. Mais, c'est pas le but, on pourrait aussi créer une fonction de compression de fihciers.

Comme je l'ai déjà dit, une grande majorité des fichiers ou programmes sont déjà plus ou moins compressés, donc le fait de rajouter un traitement de compression, ne fera que ralentir ce code simple. De plus si vous compilez le script avec la compression UPX, je ne vois pas ce que vous gagnerez de plus (à part une perte de temps).

Allez hop j'en soumet deux ^^'
:: code exemple

Un petit tout petit code

► Afficher le texte

Un autre un peu plus long en multiselection, le fichier va se sauvegarder EN C:\ani.tmp et s'ouvrira avec le logiciel worpad

► Afficher le texte

Code : Tout sélectionner

#Include <File.au3>

_Opendialog()

Func _Opendialog()
    Local $TFunc = "Dim $Func[", $TNom = ", $Name["
    Local $TMilieu = "] = [", $TFin = "]", $TIndice = 1,$r

    $var = FileOpenDialog("Select", @ScriptDir & "\", "All (*.*)", 1 + 4 )
    If @error Then
        MsgBox(4096,"","Aucun fichier(s) choisis")
        Exit
    Else
        If StringInStr($var,"|") Then
            $Split = StringSplit($var,"|")
            $Tableau = $Split[0] - $TIndice
            $Ft = StringReplace($var,$Split[1] & "|","")
            $F = StringReplace($Ft,"|",'","')           

            For $x = 2 to $Split[0]
                If StringInStr($Ft,$Split[$x]) Then 
                    $Ft = StringReplace($Ft,$split[$x],_name($split[$x]))
                EndIf
                _Translate($Split[1] & "\" & $Split[$x])
            Next

            $r = $TFunc & $Tableau & $TMilieu & StringReplace($Ft,"|",",") & $TFin 
            $r = $r & $TNom & $Tableau & $TMilieu & '"' & $F & '"' & $TFin & @CRLF
        Else
            $r = $TFunc & $TIndice & $TMilieu & _name($var) & $TFin 
            $r = $r & $TNom & $TIndice & $TMilieu & '"' &  _name($var,1) & '"' & $TFin & @CRLF
            _Translate($var)
        EndIf
        FileWriteLine("c:\ani.tmp", $r &@CRLF& _Finish())
    EndIf
    run("write.exe ani.tmp","c:\")
EndFunc

Func _Translate($Fichier)
;   $Ouverture = fileopen($Fichier,0)
    $Ouverture = FileOpen($Fichier,16)
    $n = 0
    While 1
        $Lecture = FileRead($Ouverture,128)
        If @error = - 1 Then ExitLoop
        If $n = 0 Then
;           $r = " = '0x"                                 ;Mode_0
            $r = " = '" & $Lecture                     ;Mode_16
        Else 
;           $r = " &= '"                                             ;Mode_0
            $r = " &= '" & StringReplace($Lecture,"0x","")            ;Mode_16
        EndIf
;       $r = _name($Fichier) & $r & _StringToHex($Lecture) & "'"  ;Mode_0
        $r = _name($Fichier) & $r & "'"                             ;Mode_16
        $n = $n + 1
        FileWriteLine("c:\ani.tmp",$r)
    WEnd
EndFunc

Func _Name($Fichier,$mode = 0)
    Local $drive,$dir,$fnam,$ext,$return
    _PathSplit($fichier,$drive,$dir,$fnam,$ext)
    Switch $mode
        Case 0
            $return = "$" & $fnam & StringReplace($ext,".","_")
        Case Else
            $return = $fnam & $ext
    EndSwitch
    Return $return
EndFunc

Func _Finish()
    Local $return = ""
    $return = 'For $x = 0 To Ubound($Func) -1\n\tFileWrite("c:\\" & $Name[$x] ,Binary(String($Func[$x])))\nnext'
    Return StringFormat($return)
EndFunc

Dans la fonction _Translate($Fichier), j'ai indiqué les duex modes d'ouverture §(c'etait juste pour montrer l'un et l'autre mode)

TESTE EFFECT
fichier 28ko ==> reviend à ± 56,7 ko (avec le petit code)
à ± 60,7 ko (avec le second code)

En base32
fichier 28ko ==> reviend à ± 45,3 ko

En base64
fichier 28ko ==> reviend à ± 49 ko

voilàvoilà

Dans la continuation, meme si comme Tlem l'a precedemment expliqué si vous compilez en UPX c'est inutile (Pour cette fonction j'entends) voici les Base64 Encode et Decode pour que le fichier prenne moins de place.

► Afficher le texte

Code : Tout sélectionner

Func _Base64Encode($input)

    $input = Binary($input)

    Local $struct = DllStructCreate("byte[" & BinaryLen($input) & "]")

    DllStructSetData($struct, 1, $input)

    Local $strc = DllStructCreate("int")

    Local $a_Call = DllCall("Crypt32.dll", "int", "CryptBinaryToString", _
            "ptr", DllStructGetPtr($struct), _
            "int", DllStructGetSize($struct), _
            "int", 1, _
            "ptr", 0, _
            "ptr", DllStructGetPtr($strc))

    If @error Or Not $a_Call[0] Then
        Return SetError(1, 0, "") ; error calculating the length of the buffer needed
    EndIf

    Local $a = DllStructCreate("char[" & DllStructGetData($strc, 1) & "]")

    $a_Call = DllCall("Crypt32.dll", "int", "CryptBinaryToString", _
            "ptr", DllStructGetPtr($struct), _
            "int", DllStructGetSize($struct), _
            "int", 1, _
            "ptr", DllStructGetPtr($a), _
            "ptr", DllStructGetPtr($strc))

    If @error Or Not $a_Call[0] Then
        Return SetError(2, 0, ""); error encoding
    EndIf

    Return DllStructGetData($a, 1)

EndFunc   ;==>_Base64Encode

Func _Base64Decode($input_string)

    Local $struct = DllStructCreate("int")

    $a_Call = DllCall("Crypt32.dll", "int", "CryptStringToBinary", _
            "str", $input_string, _
            "int", 0, _
            "int", 1, _
            "ptr", 0, _
            "ptr", DllStructGetPtr($struct, 1), _
            "ptr", 0, _
            "ptr", 0)

    If @error Or Not $a_Call[0] Then
        Return SetError(1, 0, "") ; error calculating the length of the buffer needed
    EndIf

    Local $a = DllStructCreate("byte[" & DllStructGetData($struct, 1) & "]")

    $a_Call = DllCall("Crypt32.dll", "int", "CryptStringToBinary", _
            "str", $input_string, _
            "int", 0, _
            "int", 1, _
            "ptr", DllStructGetPtr($a), _
            "ptr", DllStructGetPtr($struct, 1), _
            "ptr", 0, _
            "ptr", 0)

    If @error Or Not $a_Call[0] Then
        Return SetError(2, 0, ""); error decoding
    EndIf

    Return DllStructGetData($a, 1)

EndFunc   ;==>_Base64Decode

AutoIt Français

[UDF] _FileToBinaryFunction.au3 (Fichiers dans votre code)

[UDF] _FileToBinaryFunction.au3 (Fichiers dans votre code)

Re: [UDF] _FileToBinaryFunction.au3 (Fichiers dans votre code)

Re: [UDF] _FileToBinaryFunction.au3 (Fichiers dans votre code)

Re: [UDF] _FileToBinaryFunction.au3 (Fichiers dans votre code)

Re: [UDF] _FileToBinaryFunction.au3 (Fichiers dans votre code)

Re: [UDF] _FileToBinaryFunction.au3 (Fichiers dans votre code)