AutoIt Français

Suite à ce sujet qui m'a bien intéressé, voici quelques fonctions qui vont permettre de :
- récupérer des infos sur les fichier PDF
- convertir un fichier PDF en fichier texte
- recherche une chaîne de caractères dans un fichier PDF

Ces fonctions se basent sur l'utilisation de deux programmes de XPDF, qui sont pdfinfo et pdftotext.
Vous pouvez télécharger les outils XPDF ici

Je n'ai pas mis d'exemple, je pense que les fonctions sont simples à appréhender.

► Afficher le texteXPDF.au3

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name...........: _XFDF_Info
; Description....: Retrives informations from a PDF file
; Syntax.........: _XFDF_Info ( "File" [, "Info"] )
; Parameters.....: File    - PDF File.
;                  Info    - The information to retrieve
; Return values..: Success - If the Info parameter is not empty, returns the desired information for the specified Info parameter
;                          - If the Info parameter is empty, returns an array with all available informations
;                  Failure - 0, and sets @error to :
;                   1 - PDF File not found
;                   2 - Unable to find the external programm
; Remarks........: The array returned is two-dimensional and is made up as follows:
;                   $array[1][0] = Label of the first information (title, author, pages...)
;                   $array[1][1] = value of the first information 
;                   ...
; ===============================================================================================================================
Func _XFDF_Info($sPDFFile, $sInfo = "")
    Local $sXPDFInfo = @ScriptDir & "\pdfinfo.exe"

    If NOT FileExists($sPDFFile) Then Return SetError(1, 0, 0)
    If NOT FileExists($sXPDFInfo) Then Return SetError(2, 0, 0)
    
    Local $iPid = Run(@ComSpec & ' /c "' &  $sXPDFInfo & ' "' & $sPDFFile & '"', @ScriptDir, @SW_HIDE, 2)

    Local $sResult
    While 1
        $sResult &= StdoutRead($iPid)
        If @error Then ExitLoop
    WEnd
    
    Local $aInfos = StringRegExp($sResult, "(?m)^(.*?): +(.*)$", 3)
    If Mod( UBound($aInfos, 1), 2) = 1 Then Return SetError(3, 0, 0)
    
    Local $aResult [ UBound($aInfos, 1) / 2][2]
    
    For $i = 0 To UBound($aInfos) - 1 Step 2
        If $sInfo <> "" AND $aInfos[$i] = $sInfo Then Return $aInfos[$i + 1]
        $aResult[$i / 2][0] = $aInfos[$i]
        $aResult[$i / 2][1] = $aInfos[$i + 1]
    Next
    
    If $sInfo <> "" Then Return ""

    Return $aResult
EndFunc ; ---> _XFDF_Info



; #FUNCTION# ====================================================================================================================
; Name...........: _XPDF_Search
; Description....: Retrives informations from a PDF file
; Syntax.........: _XFDF_Info ( "File" [, "String" [, Case = 0 [, Flag = 0 [, FirstPage = 1 [, LastPage = 0]]]]] )
; Parameters.....: File    - PDF File.
;                  String    - String to search for
;                  Case      - If set to 1, search is case sensitive (default is 0)
;                  Flag      - A number to indicate how the function behaves. See below for details. The default is 0.
;                  FirstPage  - First page to convert (default is 1)
;                  LastPage   - Last page to convert (default is 0 = last page of the document)
; Return values..: Success - 
;                   Flag = 0 - Returns 1 if the search string was found, or 0 if not
;                   Flag = 1 - Returns the number of occcurrences found in the whole PDF File
;                   Flag = 2 - Returns an array containing the number of occurrences found for each page
;                              (only pages containing the search string are returned)
;                              $array[0][0] - Number of matching pages
;                              $array[0][1] - Number of occcurrences found in the whole PDF File
;                              $array[n][0] - Page number
;                              $array[n][1] - Number of occcurrences found for the page
;                  Failure - 0, and sets @error to :
;                   1 - PDF File not found
;                   2 - Unable to find the external programm
; ===============================================================================================================================
Func _XPDF_Search($sPDFFile, $sSearch, $iCase = 0, $iFlag = 0, $iStart = 1, $iEnd = 0)
    Local $sXPDFToText = @ScriptDir & "\pdftotext.exe"
    Local $sOptions = " -layout -f " & $iStart
    Local $iCount = 0, $aResult[1][2] = [[0, 0]], $aSearch, $sContent, $iPageOccCount
    
    If NOT FileExists($sPDFFile) Then Return SetError(1, 0, 0)
    If NOT FileExists($sXPDFToText) Then Return SetError(2, 0, 0)
    
    If $iEnd > 0 Then $sOptions &= " -l " & $iEnd
    
    Local $iPid = Run($sXPDFToText & $sOptions & ' "' & $sPDFFile & '" -', @ScriptDir, @SW_HIDE, 2)
    While 1
        $sContent &= StdoutRead($iPid)
        If @error Then ExitLoop
    WEnd
    
    
    Local $aPages = StringSplit($sContent, chr(12) )
    
    For $i = 1 To $aPages[0]
        $iPageOccCount = 0
        While StringInStr($aPages[$i], $sSearch, $iCase, $iPageOccCount + 1)
            If $iFlag <> 1 AND $iFlag <> 2 Then
                $aResult[0][1] = 1
                ExitLoop
            EndIf
            $iPageOccCount += 1
        WEnd

        If $iPageOccCount Then
            Redim $aResult[ UBound($aResult, 1) + 1][2]
            $aResult[0][1] += $iPageOccCount
            $aResult[0][0] = UBound($aResult) - 1
            $aResult[ UBound($aResult, 1) - 1 ][0] = $i + $iStart - 1
            $aResult[ UBound($aResult, 1) - 1 ][1] = $iPageOccCount
        EndIf
    Next
    
    If $iFlag = 2 Then Return $aResult
    Return $aResult[0][1]
    
EndFunc ; ---> _XPDF_Search



; #FUNCTION# ====================================================================================================================
; Name...........: _XPDF_ToText
; Description....: Converts a PDF file to plain  text.
; Syntax.........: _XPDF_ToText ( "PDFFile" , "TxtFile" [ , FirstPage [, LastPage [, Layout ]]] )
; Parameters.....: PDFFile    - PDF Input File.
;                  TxtFile    - Plain text file to convert to
;                  FirstPage  - First page to convert (default is 1)
;                  LastPage   - Last page to convert (default is last page of the document)
;                  Layout     - If true, maintains (as  best as possible) the original physical layout of the text
;                               If false, the behavior is to 'undo'  physical  layout  (columns, hyphenation, etc.)
;                                 and output the text in reading order.
;                               Default is True
; Return values..: Success - 1
;                  Failure - 0, and sets @error to :
;                   1 - PDF File not found
;                   2 - Unable to find the external program
; ===============================================================================================================================
Func _XPDF_ToText($sPDFFile, $sTXTFile, $iFirstPage = 1, $iLastPage = 0, $bLayout = True)
    Local $sXPDFToText = @ScriptDir & "\pdftotext.exe"
    Local $sOptions 
    
    If NOT FileExists($sPDFFile) Then Return SetError(1, 0, 0)
    If NOT FileExists($sXPDFToText) Then Return SetError(2, 0, 0)
    
    If $iFirstPage <> 1 Then $sOptions &= " -f " & $iFirstPage
    If $iLastPage <> 0 Then $sOptions &= " -l " & $iLastPage
    If $bLayout = True Then $sOptions &= " -layout"
    
    Local $iReturn = ShellExecuteWait ( $sXPDFToText , $sOptions & ' "' & $sPDFFile & '" "' & $sTXTFile & '"', @ScriptDir, "", @SW_HIDE)
    If $iReturn = 0 Then Return 1
    
    Return 0
    
EndFunc ; ---> _XPDF_ToText

Super...

Rapport au sujet évoqué, en cas de dysfonctionnement la première chose à vérifier est que le nom du fichier PDF ne contient pas de caractères spéciaux

euuh, j'ai pas compris l'histoire des caractères spéciaux...

aulus a écrit :Je pense que les dysfonctionnements provenaient du nom de fichier long du pdf qui me servait de test.

N'ayant pas testé je ne peux que conjecturer que le nom de son fichier contenait peut-être des caractères susceptibles de perturber la commande

Merci beaucoup, très utile cet UDF !

Voici un exemple de script qui recherche le texte contenu dans un fichier Excel dans un fichier PDF et écrit des choses dans le fichier Excel en fonction de s'il l'a trouvé ou non :

Code : Tout sélectionner


#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.10.2
 Author:         Neutro
 Date: 5 mars 2014

 Script Function:
    Recherche d'une chaine de caractères dans un fichier PDF à partir d'un fichier Excel

#ce ----------------------------------------------------------------------------

; Script Start - Add your code below here

#requireadmin

#include <xpdf.au3>
#Include <Excel Rewrite.au3>
#include <File.au3>
#include <String.au3>

$organigramme = ""

$prog_excel = ""

$prog_excel = _Excel_Open(False)

$workbook = _Excel_BookOpen($prog_excel, "D:\Informatique\liste.xlsx)

_XPDF_ToText(@scriptdir & "\Organigramme.pdf", @scriptdir & "\Organigramme.txt")

$organigramme = Fileread(@scriptdir & "\Organigramme.txt")

SplashTextOn("Recherche dans l'Organigramme","Traitement du login : " & @CRLF & @CRLF ,300,90,-1,-1, 16)

for $i = 2 to 270 step 1 ;pour chaque cellule dans la colonne A

    $cellule = _Excel_RangeRead($workbook, $workbook.Activesheet, "A" & $i) ; récupération du contenu de la cellule

    controlsettext("Recherche dans l'Organigramme", "Traitement du login : ", "Static1", "Traitement du login : " & @CRLF & @CRLF & $cellule)

    $recherche_PDF = StringInStr($organigramme, stringleft($cellule,1) & ". " & StringMid($cellule, 2))

    if $recherche_PDF <> 0 Then

        _Excel_RangeWrite($workbook, $workbook.Activesheet, "OUI", "D" & $i) ;si on trouve le nom dans l'organigramme, on écrit "OUI" dans la colonne correspondante du fichier Excel

        $prog_excel.Activesheet.range("D" & $i).Font.ColorIndex = 10

        $prog_excel.Activesheet.range("D" & $i).Font.Bold = True

        $prog_excel.Activesheet.range("D" & $i).HorizontalAlignment = -4108 ; center

    else

        ;sinon on essaye de voir si le prénom de la personne est un nom composé du style "J.C. Deschamps"

        $recherche_PDF = StringInStr($organigramme, stringleft($cellule,1) & "." & Stringmid($cellule, 2, 1) & ". " & StringMid($cellule, 3))

        if $recherche_PDF <> 0 Then

            _Excel_RangeWrite($workbook, $workbook.Activesheet, "OUI", "D" & $i) ;si on trouve le nom dans l'organigramme, on écrit "OUI" dans la colonne correspondante du fichier Excel

            $prog_excel.Activesheet.range("D" & $i).Font.ColorIndex = 10

            $prog_excel.Activesheet.range("D" & $i).Font.Bold = True

            $prog_excel.Activesheet.range("D" & $i).HorizontalAlignment = -4108 ; center

        else

            _Excel_RangeWrite($workbook, $workbook.Activesheet, "NON", "D" & $i) ;si on trouve le nom dans l'organigramme, on écrit "NON" dans la colonne correspondante du fichier Excel

            $prog_excel.Activesheet.range("D" & $i).Font.ColorIndex = 3

            $prog_excel.Activesheet.range("D" & $i).Font.Bold = True

            $prog_excel.Activesheet.range("D" & $i).HorizontalAlignment = -4108 ; center

        EndIf


    EndIf

next

_Excel_Close($prog_excel)

AutoIt Français

[UDF] Infos et recherche dans les PDF avec XPDF

[UDF] Infos et recherche dans les PDF avec XPDF

Re: [UDF] Infos et recherche dans les PDF avec XPDF

Re: [UDF] Infos et recherche dans les PDF avec XPDF

Re: [UDF] Infos et recherche dans les PDF avec XPDF

Re: [UDF] Infos et recherche dans les PDF avec XPDF