AutoIt Français

Code : Tout sélectionner

#include <Date.au3>

; Exemple 1, on récupère juste la date de démarrage de Windows
$text = "Windows a démarré le " & _upTime()
MsgBox (0, "_uptime(0)", $text )

; Exemple 2, on récupère la date de démarrage de Windows et le temps écoulé depuis
$upTimeInfo = _upTime(1)
$fromTxt = StringRegExpReplace($upTimeInfo[8], "(\d*) (\d{2}):(\d{2}):(\d{2})", "$1 jours(s), $2 heures, $3 minutes et $4 secondes")

$text  = "Windows a démarré le " & $upTimeInfo[0] & @CR & _
" - depuis " & $fromTxt & @CR & _
" - soit : " & $upTimeInfo[1] & " année(s)" & @CR & _
" - soit : " & $upTimeInfo[2] & " mois" & @CR & _
" - soit : " & $upTimeInfo[3] & " jour(s)" & @CR & _
" - soit : " & $upTimeInfo[4] & " semaine(s)" & @CR & _
" - soit : " & $upTimeInfo[5] & " heure(s)" & @CR & _
" - soit : " & $upTimeInfo[6] & " minute(s)" & @CR & _
" - soit : " & $upTimeInfo[7] & " secondes"

MsgBox(0, "_uptime(1)", $text )


; ==== _upTime() ============================================================================================
; Description : Returns informations about Windows last boot time
; Syntax      : _upTime( [$extend] )
; Parameters  : $extend = 0 (default) or 1
; Return      : $extend = 0
;                  Returns a string with the Windows last boot time using YYYY/MM/DD HH:MM:SS format
;               $extend = 1
;                  Returns an array containing the elapsed time (days, hours, minutes and seconds)
;                  from Windows last boot time :
;                      $array[0] Windows last boot time
;                      $array[1] total of elapsed time from Windows last boot time (in Years)
;                      $array[2] total of elapsed time from Windows last boot time (in Months)
;                      $array[3] total of elapsed time from Windows last boot time (in Days)
;                      $array[4] total of elapsed time from Windows last boot time (in Weeks)
;                      $array[5] total of elapsed time from Windows last boot time (in Hours)
;                      $array[6] total of elapsed time from Windows last boot time (in Minutes)
;                      $array[7] total of elapsed time from Windows last boot time (in Seconds)
;                      $array[8] elapsed time from Windows last boot time using DD HH:MM:SS format
;               Returns 0 if the function fails to get information
; Required    : <Date.au3>
; ===========================================================================================================

Func _upTime($ext = 0)
    Local $aReturn[9]
   
    ; WMI Method (proper method)
    Local $objWMIService = ObjGet("winmgmts:\\.\root\CIMV2")
    If IsObj($objWMIService) Then
        Local $colItems = $objWMIService.ExecQuery("Select * From Win32_OperatingSystem", "WQL", 0x10 + 0x20)
        If IsObj($colItems) Then
            For $objItem In $colItems
                $aReturn[0] = StringRegExpReplace($objItem.LastBootUpTime, "\A(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2}).*", "$1/$2/$3 $4:$5:$6")
            Next
        EndIf
    EndIf
      
    ; Returns 0 if each method fails
    If $aReturn[0] == "" Then Return 0
   
    $now = _NowCalc()

    ; Calculates the difference of time since the last starup
    $aReturn[1] = _DateDiff( 'Y' , $aReturn[0], $now )   ; Difference in years
    $aReturn[2] = _DateDiff( 'M' , $aReturn[0], $now )   ; Difference in months
    $aReturn[3] = _DateDiff( 'D' , $aReturn[0], $now )   ; Difference in days
    $aReturn[4] = _DateDiff( 'w' , $aReturn[0], $now )   ; Difference in weeks
    $aReturn[5] = _DateDiff( 'h' , $aReturn[0], $now )   ; Difference in hours
    $aReturn[6] = _DateDiff( 'n' , $aReturn[0], $now )   ; Difference in minutes
    $aReturn[7] = _DateDiff( 's' , $aReturn[0], $now )   ; Difference in secondes
                           
    $d = Int( $aReturn[7] / 3600 / 24 )
    $secLeft = $aReturn[7] - ( $d * 3600 * 24 )
    $h = Int ($secLeft / 3600)
    $secLeft = $secLeft - ( $h * 3600 )
    $m = Int ( $secLeft / 60 )
    $s = $secLeft - ( $m * 60 )
   
    If $h < 10 Then $h = "0" & $h
    If $m < 10 Then $m = "0" & $m
    If $s < 10 Then $s = "0" & $s
   
    $aReturn[8] = $d & " " & $h & ":" & $m & ":" & $s
           
    If $ext = 0 Then
        Return $aReturn[0]
    ElseIf $ext = 1 Then
        Return $aReturn
    EndIf
   
    Return 0
   
   
EndFunc ; ---> _PowerOnComputer()

 

Code : Tout sélectionner

Local $OSs = _ComputerGetOSs()
Local $LastBootTime = InverserMoisJour($OSs[1])
Local $TotalSecUPTIME = GetSecByStringDate($LastBootTime)
Local $TotalSecACTUEL = GetSecByStringDate(@MDAY & "/" & @MON & "/" & @YEAR & " " & @HOUR & ":" & @MIN & ":" & @SEC)
$LastBootUpTime = TimeGetLongFormatBySec($TotalSecACTUEL - $TotalSecUPTIME)
ConsoleWrite($LastBootTime & @CRLF)
ConsoleWrite($LastBootUpTime & @CRLF)

Func _ComputerGetOSs()
    Local $colItems, $objWMIService, $objItem, $i = 1
    Local $aOSInfo[1]

    $objWMIService = ObjGet("winmgmts:\\" & @ComputerName & "\root\CIMV2")
    If(Not(IsObj($objWMIService))) Then Return $aOSInfo
    $colItems = $objWMIService.ExecQuery("SELECT Name, BuildNumber, LastBootUpTime, SerialNumber FROM Win32_OperatingSystem", "WQL", 0x10 + 0x20)

    If IsObj($colItems) Then
        For $objItem In $colItems
            ReDim $aOSInfo[UBound($aOSInfo) + 1]
            $aOSInfo[$i] = __StringToDate($objItem.LastBootUpTime)
            $i += 1
        Next
        $aOSInfo[0] = UBound($aOSInfo) - 1
        If $aOSInfo[0] < 1 Then
            SetError(1, 1, 0)
        EndIf
    Else
        SetError(1, 2, 0)
    EndIf
    Return $aOSInfo
EndFunc ;_ComputerGetOSs

Func __StringToDate($dtmDate)
    Return (StringMid($dtmDate, 5, 2) & "/" & _
            StringMid($dtmDate, 7, 2) & "/" & StringLeft($dtmDate, 4) _
            & " " & StringMid($dtmDate, 9, 2) & ":" & StringMid($dtmDate, 11, 2) & ":" & StringMid($dtmDate,13, 2))
EndFunc

Func InverserMoisJour($Texte)
    Return StringMid($Texte, 4, 2) & "/" & StringMid($Texte, 1, 2) & StringTrimLeft($Texte, 5)
EndFunc

Func TimeGetLongFormatBySec($Sec)
    Local $Retour = ""
    Local $Temp
    Local $Compare = 60*60*24
    If($Sec > $Compare Or $Retour <> "") Then
        $Temp = Floor($Sec/($Compare))
        $Retour &= $Temp & " jour"
        If($Temp > 1) Then
            $Retour &= "s"
        EndIf
        $Retour &= " "
        $Sec -= $Temp*$Compare
    EndIf
    $Compare = 60*60
    If($Sec > $Compare Or $Retour <> "") Then
        $Temp = Floor($Sec/($Compare))
        $Retour &= $Temp & " heure"
        If($Temp > 1) Then
            $Retour &= "s"
        EndIf
        $Retour &= " "
        $Sec -= $Temp*$Compare
    EndIf
    $Compare = 60
    If($Sec > $Compare Or $Retour <> "") Then
        $Temp = Floor($Sec/($Compare))
        $Retour &= $Temp & " minute"
        If($Temp > 1) Then
            $Retour &= "s"
        EndIf
        $Retour &= " "
        $Sec -= $Temp*$Compare
    EndIf
    $Compare = 1
    If($Sec > $Compare Or $Retour <> "") Then
        $Temp = Floor($Sec/($Compare))
        $Retour &= $Temp & " seconde"
        If($Temp > 1) Then
            $Retour &= "s"
        EndIf
        $Retour &= " "
        $Sec -= $Temp*$Compare
    EndIf
    Return $Retour
EndFunc

Func GetSecByStringDate($time)
    Return  Number(StringMid($time, 7, 4))*31536000 + _
            Number(StringLeft($time, 2))*86400 + _
            Number(StringMid($time, 4, 2))*2678400 + _
            Number(StringMid($time, 12, 2))*3600 + _
            Number(StringMid($time, 15, 2))*60 + _
            Number(StringRight($time, 2))
EndFunc

Code : Tout sélectionner

$txt = ""
Dim $objWMIService = ObjGet("winmgmts:\\.\root\CIMV2")
Dim $colItems = $objWMIService.ExecQuery("Select * From Win32_OperatingSystem", "WQL", 0x10 + 0x20)
   For $objItem In $colItems
      $txt &= "LastBootUpTime: " & WMIDateStringToDate($objItem.LastBootUpTime) 
   Next
Msgbox(0,"WMI Output", $txt )

Func WMIDateStringToDate($dtmDate)
     Return (StringMid($dtmDate, 7, 2) & "/" & _
        StringMid($dtmDate, 5, 2) & "/" & StringLeft($dtmDate, 4) & _
        " " & StringMid($dtmDate, 9, 2) & ":" & StringMid($dtmDate, 11, 2) & ":" & StringMid($dtmDate,13, 2))
EndFunc