UDF > Visa >

_viGTL

Passe l'instrument en mode local

#include <Visa.au3>
_viGTL ( $hSession )

Paramètre

$hSession Un descripteur de VISA (string) ou le handle de la session VISA (integer).
Voir les Remarques de la fonction _viExecCommand() pour plus d'info.

Valeur de retour

Succès: Retourne 0.
Échec: Retourne -1 si la dll VISA ne peut pas être ouverte
ou une valeur non nulle représentant le code d'erreur VISA (voir le guide du programmeur VISA).

Remarques

Comme pour toutes les fonctions VISA les bibliothèques visa doiventt être installéess (vous pouvez vérifier si visa32.dll est dans {WINDOWS}\system32) et une carte GPIB doit être installée (comme par exemple une carte PCI-GPIB National Instruments NI ou une carte GPIB Agilent 82350B PCI de haute performance)

* Pour une description détaillée des descripteurs VISA les plus courants regarder les Remarques de l'aide de la fonction _viExecCommand().

Les instruments qui acceptent cette commande quittent le mode "Contrôle distant" et passe en "mode local". Si l'instrument est déjà en mode "local" la commande est tout simplement ignorée. Normalement, si un instrument ne supporte pas cette commande, il reste tout simplement en mode "Contrôle distant".

En relation

_viClose, _viExecCommand, _viFindGpib, _viGpibBusReset, _viOpen

Exemple

; - Cet exemple suppose que vous avez installé l'instrument à l'adresse GPIB 3
; Si vous avez un instrument à une adresse différente, changez "GPIB::3::0" en un descripteur correspondant. Faites de même pour l'appel à _viOpen.
; Il montre comment utiliser la fonction _viExecCommand en mode autonome et combiné avec _viOpen et _viClose.
; Il montre également la fonction _viGTL

#include <MsgBoxConstants.au3>
#include <Visa.au3>

Local $h_Session = 0

; Interroge l'ID de l'instrument à l'address GPIB 3
MsgBox($MB_SYSTEMMODAL, "Étape 1", "Simple requête GPIB à l'aide d'un descripteur VISA")
Local $s_Answer = _viExecCommand("GPIB::3::0", "*IDN?", 10)
MsgBox($MB_SYSTEMMODAL, "Résultat de la requête GPIB", $s_Answer) ; Affiche la réponse

MsgBox($MB_SYSTEMMODAL, "Étape 2", "Va sur l'ordinateur LOCAL à l'aide d'un descripteur VISA")
_viGTL("GPIB::1::0") ; Va sur un local (quitte le mode contrôle distant)

MsgBox($MB_SYSTEMMODAL, "Étape 3", "Ouvre la connexion de l'instrument avec _viOpen")
Local $h_Instr = _viOpen(3)
MsgBox($MB_SYSTEMMODAL, "Handle de l'Instrument obtenu", "$h_Instr = " & $h_Instr) ; Affiche le handle de la session
; Interroge l'instrument

MsgBox($MB_SYSTEMMODAL, "Étape 4", "Interroge l'instrument à l'aide du handle de l'instrument VISA ")
$s_Answer = _viExecCommand($h_Instr, "*IDN?") ; $h_Instr n'est pas une chaîne!
MsgBox($MB_SYSTEMMODAL, "Résultats de la requête GPIB", $s_Answer) ; Affiche la réponse
; Query again. There is no need to OPEN the link again

MsgBox($MB_SYSTEMMODAL, "Étape 5", "Interroge de nouveau. Inutile d'ouvrir le lien de nouveau")
$s_Answer = _viExecCommand($h_Instr, "*IDN?")
MsgBox($MB_SYSTEMMODAL, "Résultats de la requête GPIB", $s_Answer) ; Affiche la réponse

MsgBox($MB_SYSTEMMODAL, "Étape 6", "Va sur l'ordinateur LOCAL à l'aide du handle de l'instrument VISA")
_viGTL($h_Instr) ; Va sur le local (ceci est optionnel)

MsgBox($MB_SYSTEMMODAL, "Étape 7", "Ferme la connexion de l'instrument à l'aide de _viClose")
_viClose($h_Instr) ; Ferme la connexion de l'instrument