UDF > Word >

_Word_Quit

Ferme tous les documents, l'application Word et supprime les références d'objet vers elle

#include <Word.au3>
_Word_Quit ( $oAppl [, $iSaveChanges = $WdDoNotSaveChanges [, $iOriginalFormat = $WdWordDocument [, $bForceClose = False]]] )

Paramètres

$oAppl Objet Word retourné par un précédent appel à _Word_Create()
$iSaveChanges [optionnel] Spécifie si les documents modifiés doivent être sauvegardés avant la fermeture.
Peut prendre toute valeur de l'énumération WdSaveOptions (par défaut = $wdDoNotSaveChanges)
$iOriginalFormat [optionnel] Spécifie la façon dont Word enregistre les documents dont le format d'origine n'était pas le format de document Word.
Peut prendre toute valeur de l'énumération WdOriginalFormat (par défaut = $WdWordDocument)
$bForceClose [optionnel] Si True, l'application Word est fermée même pendant l'exécution de _Word_Create() (par défaut = False)

Valeur de retour

Succès: Retourne 1.
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oAppl n'est pas un objet
2 - Erreur retournée par la méthode Application.Quit. @extended contient le code d'erreur COM

Remarque

Si Word n'est pas en cours d'exécution lors de l'appel de _Word_Create() alors _Word_Quit() ferme tous les documents de l'instance
spécifiée (même celles ouvertes manuellement par l'utilisateur après _Word_Create() ) ainsi que l'application Word.
Si Word est en cours d'exécution, vous devez définir $bForceClose à True pour faire la même chose.

En relation

_Word_Create

Exemple

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocQuit Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $bWordClose = @extended
; Ouvre le document test en lecture seule
_Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocQuit Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Si Word était en cours d'exécution quand ce script a démarré, seule les références à cet
; objet seront détruites.
; Si Word a été démarré par cet exemple tous les documents ainsi que Word seront fermés.
;
Local $iResult
If $bWordClose Then
    $iResult = MsgBox(BitOR($MB_OKCANCEL, $MB_SYSTEMMODAL), "Word UDF: _Word_Quit Example", _
            "If you click OK ALL unsaved changes in ALL open documents of this Word instance will be lost and the instance will be closed.")
Else
    $iResult = MsgBox(BitOR($MB_OKCANCEL, $MB_SYSTEMMODAL), "Word UDF: _Word_Quit Example", _
            "Word was already running when function _Word_Create was called. Hence only the reference to the object will be removed.")
EndIf
If $iResult = 2 Then Exit
_Word_Quit($oWord)
If @error Then MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_Quit Example", _
        "Error closing the Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)