UDF > Word >

_Word_DocTableRead

Lit un tableau Word et retourne le contenu dans une variable array à deux dimensions

#include <Word.au3>
_Word_DocTableRead ( $oDoc, $vTable [, $iIndexBase = Default [, $sDelimiter = Default]] )

Paramètres

$oDoc Objet document Word
$vTable Objet Table ou index de la table dans la collection de table
$iIndexBase [optionnel] Peut prendre la valeur 0 ou 1 et indique si le tableau commence avec la ligne 0 ou 1 (par défaut = 1)
$sDelimiter [optionnel] Spécifie le caractère utilisé pour séparer le texte dans les cellules (par défaut = @TAB)

Valeur de retour

Succès: Retourne un tableau à deux dimensions avec le contenu du tableau Word.
Échec: Retourne "" et définit @error <> 0.
@error: 1 - $oDoc n'est pas un objet
2 - Une erreur s'est produite lors de l'accès à l'index spécifié dans la collection de tableau. @extended contient le code d'erreur COM
3 - Une erreur s'est produite lors de l'accès au tableau spécifié. @extended contient le code d'erreur COM
4 - Une erreur s'est produite lors de la conversion du texte en tableau. @extended contient le code d'erreur COM

Remarque

Les tableaux imbriquées sont ignorés.
Si $iIndexBase est défini à 1, alors la ligne 0 du tableau contient le nombre de lignes et de colonnes.

En relation

_Word_DocTableWrite

Exemple

#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocTableRead Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre le document test
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocTableRead Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Crée un tableau Wors à partir d'un array
Local $asArray[3][3] = [[1, 2, 3], ["a", "b", "c"], ["x", "y", "z"]]
Local $oRange = _Word_DocRangeSet($oDoc, -2)
Local $oTable = _Word_DocTableWrite($oRange, $asArray, 0)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocTableRead Example", _
        "Error creating the table." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Lit le premier tableau du document et retourne le contenu
;
Local $asResult = _Word_DocTableRead($oDoc, 1, 1)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocTableRead Example", _
        "Error reading the table to an array." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
_ArrayDisplay($asResult, "Word UDF: _Word_DocTableRead Example")