UDF > Word >

_Word_DocPictureAdd

Ajoute une image dans le document

#include <Word.au3>
_Word_DocPictureAdd ( $oDoc, $sFilePath [, $bLinkToFile = False [, $bSaveWithDocument = False [, $oRange = 0]]] )

Paramètres

$oDoc Objet document Word
$sFilePath Le chemin et le nom du fichier de l'image
$bLinkToFile [optionnel] Spécifie s'il faut relier l'image au fichier à partir duquel elle a été créée.
    True - Relie l'image au fichier à partir duquel elle a été créée
    False - Copie l'image pour qu'elle soit indépendante du fichier (par défaut)
$bSaveWithDocument [optionnel] Spécifie si vous souhaitez enregistrer l'image reliée au document.
    True - Enregistrer l'image liée avec le document
    False - N'enregistre pas l'image liée avec le document (par défaut)
$oRange [optionnel] L'emplacement où l'image sera placée dans le texte.
Peut être 0 (la photo est automatiquement positionnée) ou tout autre objet plage (par défaut = 0)

Valeur de retour

Succès: Retourne une variable pointant sur l'objet Forme
Échec: Retourne 0 et définit @error <> 0.
@error: 1 - $oDoc n'est pas un objet
2 - L'image spécifiée n'existe pas
3 - Une erreur s'est produite lors de l'ajout de l'image spécifiée. @extended contient le code d'erreur COM
4 - $oRange n'est pas 0 mais n'est pas un objet plage

Exemples

Exemple 1

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre le document de test
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Insére une image après le quatrième mot du document
;
; Définit la plage comme marqueur d'insertion après le 4ème mot
Local $oRange = _Word_DocRangeSet($oDoc, -1, Default, 4, Default, 4)
_Word_DocPictureAdd($oDoc, @ScriptDir & "\Extras\Screenshot.png", Default, Default, $oRange)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error adding the picture to the document" & @CRLF & " @error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Picture has successfully been added after word 4 in the document.")

Exemple 2

#include <MsgBoxConstants.au3>
#include <Word.au3>

; Crée un objet application
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Ouvre le document test
Local $oDoc = _Word_DocOpen($oWord, @ScriptDir & "\Extras\Test.doc", Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error opening '.\Extras\Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

;
; Ajoute une image à la fin du document
;
; Définit la plage comme marqueur d'insertion à la fin du document
Local $oRange = _Word_DocRangeSet($oDoc, -2)
_Word_DocPictureAdd($oDoc, @ScriptDir & "\Extras\Screenshot.png", Default, Default, $oRange)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Error adding the picture to the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocPictureAdd Example", _
        "Picture has successfully been added at the end of the document.")